ResourceLocator オブジェクト

リソースへのパスを提供する オブジェクト。 Session.Get、Session.Put、Session.Enumerate などの Session オブジェクト操作では、リソース URI の代わりに ResourceLocator オブジェクトを使用できます。

このオブジェクトを使用すると、次のことが可能になります。

• リソースの特定 のインスタンスを 識別するセレクターを 1 つ以上追加します。 これは、キーを使用するリソースのリソース URI にキー値を指定するのと同じです。 詳細については、「 ResourceLocator.AddSelector」を参照してください。 Session.Enumerate の呼び出しで filter パラメーターを使用して、同様の操作を実行できます。
• フラグメント パスと言語を指定して、リソースのプロパティを 1 つだけ取得します。 配列インデックスを指定して、配列プロパティの 1 つまたはすべての要素を指定することもできます。 詳細については、「 ResourceLocator.FragmentPath」を参照してください。
• データ ソースが要求を処理するために必要な オプション を 1 つ以上追加します。 詳細については、「 ResourceLocator.AddOption」を参照してください。

詳細については、「 リソースの特定のインスタンスのクエリ」を参照してください。

メンバー

ResourceLocator オブジェクトには、次の種類のメンバーがあります。

• メソッド
• プロパティ

メソッド

ResourceLocator オブジェクトには、これらのメソッドがあります。

プロパティ

ResourceLocator オブジェクトには、これらのプロパティがあります。

解説

ResourceLocator オブジェクトは、IWSManResourceLocator インターフェイスに対応します。

例

次の VBScript コード例では、Win32_Processorの特定のインスタンスから NumberOfLogicalProcessors プロパティと NumberOfCores プロパティを取得します。

Option Explicit
Dim strUri
strUri = "http://schemas.microsoft.com/wbem/wsman/1/" _
    & "wmi/root/cimv2/Win32_Processor"
Const FragmentDialect = _
    "https://www.w3.org/TR/1999/REC-xpath-19991116"

Dim WSMan
Set WSMan = CreateObject("WSMan.Automation")

Dim Session
Set Session = WSMan.CreateSession

Dim Locator
Set Locator = WSMan.CreateResourceLocator(strUri)

Locator.AddSelector "DeviceID", "CPU0"

Dim NumberOfCores_XML
Locator.FragmentPath = "NumberOfCores"
Locator.FragmentDialect = FragmentDialect
NumberOfCores_XML = Session.Get(Locator)
DisplayOutput NumberOfCores_XML

Dim NumberOfLogicalProcessors_XML
Locator.FragmentPath = "NumberOfLogicalProcessors"
Locator.FragmentDialect = FragmentDialect
NumberOfLogicalProcessors_XML = Session.Get(Locator)

DisplayOutput NumberOfLogicalProcessors_XML

'****************************************************
' Displays WinRM XML message using built-in XSL
'****************************************************

Sub DisplayOutput( strWinRMXml )
    Dim xmlFile, xslFile
    Set xmlFile = CreateObject( "MSXml2.DOMDocument.3.0" )    
    Set xslFile = CreateObject( "MSXml2.DOMDocument.3.0" )
    xmlFile.LoadXml( strWinRMXml )
    xslFile.Load( "WsmTxt.xsl" )
    Wscript.Echo xmlFile.TransformNode( xslFile )           
End Sub

要件

関連項目

WinRM スクリプト API