Session.Timeout プロパティ

クライアント アプリケーションがリモート管理の操作を完了するまでWindows待機する最大時間 (ミリ秒単位) を設定して取得します。

このプロパティは読み取り/書き込み可能です。

構文

Session.Timeout As long

プロパティ値

タイムアウト値 (ミリ秒単位)。 タイムアウト値を超えると、実行時エラーが発生します。

解説

タイムアウト値は、エージェントによって実行される各操作の前に設定できます。 タイムアウト値が指定されていない場合、エージェントはタイムアウト値を設定します。

列挙操作中は、リソースの列挙中にタイムアウト値をリセットできません。

例

次の VBScript コード例では、WMI Win32_Process クラスの Create メソッドを使用して 、Calc.exe プロセスを 開始します。 strInputParameters パラメーターには、XML 形式の入力パラメーターが含まれています。 このスクリプトでは、セッションのタイムアウトを指定します。

Set objWsman = CreateObject( "WSMan.Automation" )
If objWsman is Nothing Then
    WScript.Echo "Failed to create WSMAN Automation object"
    WScript.Quit
End If 

Set objSession = objWsman.CreateSession
If objSession is Nothing Then
    WScript.Echo "Failed to create WSMAN Session object"
    WScript.Quit
End If 

strResource = "http://schemas.microsoft.com/wbem/wsman/1/" & _
    "wmi/root/cimv2/Win32_Process"

'Reset timeout to 10,000 milliseconds
objSession.Timeout = 10000     

strInputParameters = "<p:Create_INPUT " & _
    "xmlns:p=""http://schemas.microsoft.com/wbem/wsman/1/wmi/root/cimv2/Win32_Process"">" & _
    "<p:CommandLine>" & "calc.exe" & _
    "</p:CommandLine>" & _
    "</p:Create_INPUT>"

strOutputParameters = objSession.Invoke( "Create", _
    strResource, strInputParameters )

DisplayOutput( strOutputParameters )

'****************************************************
' Displays WinRM XML message using built-in XSL
'****************************************************
Sub DisplayOutput( strWinRMXml )
    Dim xmlFile, xslFile
    Set xmlFile = CreateObject( "MSXml2.DOMDocument.3.0" ) 
    Set xslFile = CreateObject( "MSXml2.DOMDocument.3.0" )
    xmlFile.LoadXml( strWinRMXml )
    xslFile.Load( "WsmTxt.xsl" )
    Wscript.Echo xmlFile.TransformNode( xslFile ) 
End Sub

要件

関連項目

Session