WMI タスク: サービス

[アーティクル]
06/29/2023

サービス関連の WMI タスクでは、依存サービスや継続元サービスなど、サービスに関する情報を取得できます。その他の例については、https://www.microsoft.com/technet の TechNet ScriptCenter を参照してください。

このトピックに示したスクリプト例では、ローカルコンピューターからのみデータを取得します。スクリプトを使用してリモートコンピューターからデータを取得する方法の詳細については、「リモートコンピューター上の WMI への接続」を参照してください。

以下の手順では、スクリプトの実行方法を説明します。

スクリプトを実行するには

コードをコピーし、拡張子 .vbs を付けたファイル (filename.vbs など) に保存します。テキストエディターによってファイルに .txt 拡張子が追加されていないことを確認します。
コマンドプロンプトウィンドウを開き、ファイルを保存したディレクトリに移動します。
コマンドプロンプトで「cscript filename.vbs」と入力します。
イベントログにアクセスできない場合は、管理者特権でのコマンドプロンプトから実行しているかどうかを確認します。セキュリティイベントログなどの一部のイベントログは、ユーザーアクセス制御 (UAC) によって保護されている場合があります。

注意

既定では、cscript により、コマンドプロンプトウィンドウにスクリプトの出力が表示されます。 WMI スクリプトでは大量の出力が生成される可能性があるため、出力をファイルにリダイレクトすることが必要になる場合があります。コマンドプロンプトで「cscript filename.vbs > outfile.txt」と入力し、filename.vbs スクリプトの出力を outfile.txt にリダイレクトします。

次の表に、ローカルコンピューターからさまざまな種類のデータを取得するために使用できるスクリプトの例の一覧を示します。

操作方法 WMI のクラスまたはメソッド

実行されているサービスと実行されていないサービスを確認する

Win32_Service クラスを使用して、すべてのサービスの状態をチェックします。 state プロパティを使用すると、サービスが停止しているか実行中であるかを確認できます。

strComputer = "." 
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2") 
Set colItems = objWMIService.ExecQuery("SELECT * FROM Win32_Service",,48) 
For Each objItem in colItems 
    Wscript.Echo "Service Name: " & objItem.Name & VBNewLine & "State: " & objItem.State
Next

PowerShell
`Get-WmiObject -Class win32_service -computer "." -Namespace "root\cimv2" \| format-list Name, State`

Power Users による特定のサービスの開始を停止する

Win32_Service クラスと ChangeStartMode メソッドを使用して、StartMode プロパティを Disabled に設定します。無効なサービスを開始することはできません。また、既定では、Power Users はサービスの開始モードを変更できません。

strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colServiceList = objWMIService.ExecQuery ("Select * from Win32_Service where StartMode = 'Manual'")
For Each objService in colServiceList
    errReturnCode = objService.Change( , , , , "Disabled")
    WScript.Echo "Changed manual service to disabled: " & objService.Name   
Next

PowerShell
Get-WmiObject -Class win32_service -computer "." -Namespace "root\cimv2" \| where {$_.startMode -eq "Manual"} \| ` foreach-object { [void]$_.changeStartMode('Disabled') }

サービスを開始および停止する

Win32_Service クラスと、StopService および StartService メソッドを使用します。

strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colListOfServices = objWMIService.ExecQuery ("Select * from Win32_Service Where Name ='Alerter'")
For Each objService in colListOfServices
    objService.StartService()
    Wscript.Echo "Started Alerter service"
Next

PowerShell
Get-WmiObject -Class win32_service -computer "." -Namespace "root\cimv2" \| where {$_.Name -eq "Alerter"} \| ` foreach-object { [void]$_.StartService() }

スクリプトを使用してサービスアカウントのパスワードを変更する

Win32_Service クラスと Change メソッドを使用します。

strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colServiceList = objWMIService.ExecQuery ("Select * from Win32_Service")
For Each objservice in colServiceList
    If objService.StartName = ".\netsvc" Then
        errReturn = objService.Change( , , , , , , , "password")  
    End If 
Next

停止できるサービスを確認する

Win32_Service クラスを使用し、AcceptStop プロパティの値をチェックします。

strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colServices = objWMIService.ExecQuery ("Select * from Win32_Service Where AcceptStop = True")
For Each objService in colServices
    Wscript.Echo objService.DisplayName 
Next

PowerShell
Get-WmiObject -Class win32_service -computer "." -Namespace "root\cimv2" \| where {$_.AcceptStop -eq "True"} \| ` format-list DisplayName

DHCP サービスを開始する前に実行する必要があるサービスを確認する

Win32_DependentService クラスにあり、Role プロパティに "Dependent" を持つ "DHCP" という名前の Win32_Service クラスの ASSOCIATORS OF を照会します。 Role は DHCP サービスのロールを意味します。この場合、これは開始される他のサービスに依存します。

strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colServiceList = objWMIService.ExecQuery("Associators Of " _ 
    & "{Win32_Service.Name='dhcp'} Where " _
    & "AssocClass=Win32_DependentService " _
    & "Role=Dependent") 
For Each objService in colServiceList
Wscript.Echo objService.DisplayName 
Next

PowerShell
`$query = "Associators Of {Win32_Service.Name='dhcp'} Where AssocClass=Win32_DependentService Role=Dependent" Get-WmiObject -Query $query -Namespace "root\cimv2" \| format-list DisplayName`

開始する前に WMI サービス (Winmgmt) が実行されている必要があるサービスを確認する

Win32_DependentService クラス内にあり、Role プロパティに "Antecendent" を持つ "DHCP" という名前の Win32_Service クラスの ASSOCIATORS OF を照会します。 Role は、rasman サービスのロールを意味します。この場合、これは依存サービスの前に開始されている必要があります。

strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\ & strComputer & "\root\cimv2")
Set colServiceList = _
    objWMIService.ExecQuery("Associators of " _
    & "{Win32_Service.Name='winmgmt'} Where " _
    & "AssocClass=Win32_DependentService " _
    & "Role=Antecedent" )
For Each objService in colServiceList
Wscript.Echo "Name: " & objService.Name & VBTab & "Display Name: " & objService.DisplayName 
Next

PowerShell
`$query = "Associators of {Win32_Service.Name='winmgmt'} Where AssocClass=Win32_DependentService Role=Antecedent" Get-WmiObject -Query $query -Namespace "root\cimv2" \| format-list Name, DisplayName`

スクリプトおよびアプリケーション用の WMI タスク
WMI C++ アプリケーションの例
TechNet ScriptCenter

次の方法で共有

WMI タスク: サービス

フィードバック

その他のリソース

次の方法で共有

WMI タスク: サービス

関連トピック

フィードバック

その他のリソース