주석이 추가된 x64 디스어셈블리
다음 매우 간단한 함수는 x64 호출 규칙을 보여 줍니다.
int Simple(int i, int j)
{
return i*5 + j + 3;
}
다음과 같은 코드로 컴파일됩니다.
01001080 lea eax,[rdx+rcx*4] ; eax = rdx+rcx*4
01001083 lea eax,[rcx+rax+0x3] ; eax = rcx+rax+3
01001087 ret
i 및 j 매개 변수는 각각 ecx 및 edx 레지스터에 전달됩니다. 매개 변수가 두 개뿐이므로 루틴은 스택을 전혀 사용하지 않습니다.
생성된 특정 코드는 세 가지 요령을 악용하며, 그 중 하나는 x64와 관련이 있습니다.
lea 연산을 사용하여 일련의 간단한 산술 연산을 단일 연산으로 수행할 수 있습니다. 첫 번째 명령은 eax에 j+i*4를 저장하고 두 번째 명령은 결과에 i+3을 추가하여 총 j+i*5+3을 추가합니다.
추가 및 곱하기와 같은 많은 연산은 정밀도를 더한 다음 올바른 정밀도로 잘릴 수 있습니다. 이 instance 코드는 64비트 추가 및 곱셈을 사용합니다. 결과를 32비트로 안전하게 잘라낼 수 있습니다.
x64에서 32비트 레지스터로 출력되는 모든 작업은 결과를 자동으로 0으로 확장합니다. 이 경우 eax 에 출력하면 결과를 32비트로 잘리는 효과가 있습니다.
반환 값은 rax 레지스터에 전달됩니다. 이 경우 결과는 이미 rax 레지스터에 있으므로 함수가 반환됩니다.
다음으로 일반적인 x64 디스어셈블리를 보여 주는 더 복잡한 함수를 고려합니다.
HRESULT Meaningless(IDispatch *pdisp, DISPID dispid, BOOL fUnique, LPCWSTR pszExe)
{
IQueryAssociations *pqa;
HRESULT hr = AssocCreate(CLSID_QueryAssociations, IID_IQueryAssociations, (void**)&pqa);
if (SUCCEEDED(hr)) {
hr = pqa->Init(ASSOCF_INIT_BYEXENAME, pszExe, NULL, NULL);
if (SUCCEEDED(hr)) {
WCHAR wszName[MAX_PATH];
DWORD cchName = MAX_PATH;
hr = pqa->GetString(0, ASSOCSTR_FRIENDLYAPPNAME, NULL, wszName, &cchName);
if (SUCCEEDED(hr)) {
VARIANTARG rgvarg[2] = { 0 };
V_VT(&rgvarg[0]) = VT_BSTR;
V_BSTR(&rgvarg[0]) = SysAllocString(wszName);
if (V_BSTR(&rgvarg[0])) {
DISPPARAMS dp;
LONG lUnique = InterlockedIncrement(&lCounter);
V_VT(&rgvarg[1]) = VT_I4;
V_I4(&rgvarg[1]) = fUnique ? lUnique : 0;
dp.rgvarg = rgvarg;
dp.cArgs = 2;
dp.rgdispidNamedArgs = NULL;
dp.cNamedArgs = 0;
hr = pdisp->Invoke(dispid, IID_NULL, 0, DISPATCH_METHOD, &dp, NULL, NULL, NULL);
VariantClear(&rgvarg[0]);
VariantClear(&rgvarg[1]);
} else {
hr = E_OUTOFMEMORY;
}
}
}
pqa->Release();
}
return hr;
}
이 함수와 해당하는 어셈블리 줄을 한 줄씩 살펴보겠습니다.
입력하면 함수의 매개 변수는 다음과 같이 저장됩니다.
Rcx = pdisp.
Rdx = dispid.
r8 = fUnique.
r9 = pszExe.
처음 네 개의 매개 변수는 레지스터에 전달됩니다. 이 함수에는 매개 변수가 4개뿐이므로 스택에 전달되는 매개 변수가 없습니다.
어셈블리는 다음과 같이 시작됩니다.
Meaningless:
010010e0 push rbx ; save
010010e1 push rsi ; save
010010e2 push rdi ; save
010010e3 push r12d ; save
010010e5 push r13d ; save
010010e7 push r14d ; save
010010e9 push r15d ; save
010010eb sub rsp,0x2c0 ; reserve stack
010010f2 mov rbx,r9 ; rbx = pszExe
010010f5 mov r12d,r8d ; r12 = fUnique (zero-extend)
010010f8 mov r13d,edx ; r13 = dispid (zero-extend)
010010fb mov rsi,rcx ; rsi = pdisp
함수는 비휘발성 레지스터를 저장한 다음, 지역 변수에 대한 스택 공간을 예약하는 것으로 시작합니다. 그런 다음 비휘발성 레지스터에 매개 변수를 저장합니다. 중간 두 mov 명령의 대상은 32비트 레지스터이므로 암시적으로 64비트까지 0으로 확장됩니다.
IQueryAssociations *pqa;
HRESULT hr = AssocCreate(CLSID_QueryAssociations, IID_IQueryAssociations, (void**)&pqa);
AssocCreate에 대한 첫 번째 매개 변수는 값으로 전달된 128비트 CLSID입니다. 64비트 레지스터에 맞지 않으므로 CLSID가 스택에 복사되고 스택 위치에 대한 포인터가 대신 전달됩니다.
010010fe movdqu xmm0,oword ptr [CLSID_QueryAssociations (01001060)]
01001106 movdqu oword ptr [rsp+0x60],xmm0 ; temp buffer for first parameter
0100110c lea r8,[rsp+0x58] ; arg3 = &pqa
01001111 lea rdx,[IID_IQueryAssociations (01001070)] ; arg2 = &IID_IQueryAssociations
01001118 lea rcx,[rsp+0x60] ; arg1 = &temporary
0100111d call qword ptr [_imp_AssocCreate (01001028)] ; call
movdqu 명령은 xmmn 레지스터에서 128비트 값을 전송합니다. 이 instance 어셈블리 코드는 이를 사용하여 CLSID를 스택에 복사합니다. CLSID에 대한 포인터는 r8로 전달됩니다. 다른 두 인수는 rcx 및 rdx로 전달됩니다.
if (SUCCEEDED(hr)) {
01001123 test eax,eax
01001125 jl ReturnEAX (01001281)
코드는 반환 값이 성공인지 확인합니다.
hr = pqa->Init(ASSOCF_INIT_BYEXENAME, pszExe, NULL, NULL);
0100112b mov rcx,[rsp+0x58] ; arg1 = pqa
01001130 mov rax,[rcx] ; rax = pqa.vtbl
01001133 xor r14d,r14d ; r14 = 0
01001136 mov [rsp+0x20],r14 ; arg5 = 0
0100113b xor r9d,r9d ; arg4 = 0
0100113e mov r8,rbx ; arg3 = pszExe
01001141 mov r15d,0x2 ; r15 = 2 (for later)
01001147 mov edx,r15d ; arg2 = 2 (ASSOCF_INIT_BY_EXENAME)
0100114a call qword ptr [rax+0x18] ; call Init method
C++ vtable을 사용하는 간접 함수 호출입니다. 이 포인터는 첫 번째 매개 변수로 rcx로 전달됩니다. 처음 세 개의 매개 변수는 레지스터에 전달되고 최종 매개 변수는 스택에 전달됩니다. 함수는 레지스터에 전달된 매개 변수에 대해 16바이트를 예약하므로 다섯 번째 매개 변수는 rsp+0x20 시작합니다.
if (SUCCEEDED(hr)) {
0100114d mov ebx,eax ; ebx = hr
0100114f test ebx,ebx ; FAILED?
01001151 jl ReleasePQA (01001274) ; jump if so
어셈블리 언어 코드는 결과를 ebx로 저장하고 성공 코드인지 확인합니다.
WCHAR wszName[MAX_PATH];
DWORD cchName = MAX_PATH;
hr = pqa->GetString(0, ASSOCSTR_FRIENDLYAPPNAME, NULL, wszName, &cchName);
if (SUCCEEDED(hr)) {
01001157 mov dword ptr [rsp+0x50],0x104 ; cchName = MAX_PATH
0100115f mov rcx,[rsp+0x58] ; arg1 = pqa
01001164 mov rax,[rcx] ; rax = pqa.vtbl
01001167 lea rdx,[rsp+0x50] ; rdx = &cchName
0100116c mov [rsp+0x28],rdx ; arg6 = cchName
01001171 lea rdx,[rsp+0xb0] ; rdx = &wszName[0]
01001179 mov [rsp+0x20],rdx ; arg5 = &wszName[0]
0100117e xor r9d,r9d ; arg4 = 0
01001181 mov r8d,0x4 ; arg3 = 4 (ASSOCSTR_FRIENDLYNAME)
01001187 xor edx,edx ; arg2 = 0
01001189 call qword ptr [rax+0x20] ; call GetString method
0100118c mov ebx,eax ; ebx = hr
0100118e test ebx,ebx ; FAILED?
01001190 jl ReleasePQA (01001274) ; jump if so
다시 한 번 매개 변수를 설정하고 함수를 호출한 다음, 성공에 대한 반환 값을 테스트합니다.
VARIANTARG rgvarg[2] = { 0 };
01001196 lea rdi,[rsp+0x82] ; rdi = &rgvarg
0100119e xor eax,eax ; rax = 0
010011a0 mov ecx,0x2e ; rcx = sizeof(rgvarg)
010011a5 rep stosb ; Zero it out
x64에서 버퍼를 0으로 0으로 설정하기 위한 idiomatic 메서드는 x86과 동일합니다.
V_VT(&rgvarg[0]) = VT_BSTR;
V_BSTR(&rgvarg[0]) = SysAllocString(wszName);
if (V_BSTR(&rgvarg[0])) {
010011a7 mov word ptr [rsp+0x80],0x8 ; V_VT(&rgvarg[0]) = VT_BSTR
010011b1 lea rcx,[rsp+0xb0] ; arg1 = &wszName[0]
010011b9 call qword ptr [_imp_SysAllocString (01001010)] ; call
010011bf mov [rsp+0x88],rax ; V_BSTR(&rgvarg[0]) = result
010011c7 test rax,rax ; anything allocated?
010011ca je OutOfMemory (0100126f) ; jump if failed
DISPPARAMS dp;
LONG lUnique = InterlockedIncrement(&lCounter);
010011d0 lea rax,[lCounter (01002000)]
010011d7 mov ecx,0x1
010011dc lock xadd [rax],ecx ; interlocked exchange and add
010011e0 add ecx,0x1
InterlockedIncrement 는 컴퓨터 코드로 직접 컴파일됩니다. 잠금 xadd 명령은 원자성 교환을 수행하고 추가합니다. 최종 결과는 ecx에 저장됩니다.
V_VT(&rgvarg[1]) = VT_I4;
V_I4(&rgvarg[1]) = fUnique ? lUnique : 0;
010011e3 mov word ptr [rsp+0x98],0x3 ; V_VT(&rgvarg[1]) = VT_I4;
010011ed mov eax,r14d ; rax = 0 (r14d is still zero)
010011f0 test r12d,r12d ; fUnique set?
010011f3 cmovne eax,ecx ; if so, then set rax=lCounter
010011f6 mov [rsp+0xa0],eax ; V_I4(&rgvarg[1]) = ...
x64는 cmov 명령을 지원하므로 ?: 구문은 점프를 사용하지 않고 컴파일할 수 있습니다.
dp.rgvarg = rgvarg;
dp.cArgs = 2;
dp.rgdispidNamedArgs = NULL;
dp.cNamedArgs = 0;
010011fd lea rax,[rsp+0x80] ; rax = &rgvarg[0]
01001205 mov [rsp+0x60],rax ; dp.rgvarg = rgvarg
0100120a mov [rsp+0x70],r15d ; dp.cArgs = 2 (r15 is still 2)
0100120f mov [rsp+0x68],r14 ; dp.rgdispidNamedArgs = NULL
01001214 mov [rsp+0x74],r14d ; dp.cNamedArgs = 0
이 코드는 DISPPARAMS의 나머지 멤버를 초기화합니다. 컴파일러는 CLSID에서 이전에 사용한 스택의 공간을 다시 사용합니다.
hr = pdisp->Invoke(dispid, IID_NULL, 0, DISPATCH_METHOD, &dp, NULL, NULL, NULL);
01001219 mov rax,[rsi] ; rax = pdisp.vtbl
0100121c mov [rsp+0x40],r14 ; arg9 = 0
01001221 mov [rsp+0x38],r14 ; arg8 = 0
01001226 mov [rsp+0x30],r14 ; arg7 = 0
0100122b lea rcx,[rsp+0x60] ; rcx = &dp
01001230 mov [rsp+0x28],rcx ; arg6 = &dp
01001235 mov word ptr [rsp+0x20],0x1 ; arg5 = 1 (DISPATCH_METHOD)
0100123c xor r9d,r9d ; arg4 = 0
0100123f lea r8,[GUID_NULL (01001080)] ; arg3 = &IID_NULL
01001246 mov edx,r13d ; arg2 = dispid
01001249 mov rcx,rsi ; arg1 = pdisp
0100124c call qword ptr [rax+0x30] ; call Invoke method
0100124f mov ebx,eax ; hr = result
그런 다음, 코드는 매개 변수를 설정하고 Invoke 메서드를 호출합니다.
VariantClear(&rgvarg[0]);
VariantClear(&rgvarg[1]);
01001251 lea rcx,[rsp+0x80] ; arg1 = &rgvarg[0]
01001259 call qword ptr [_imp_VariantClear (01001018)]
0100125f lea rcx,[rsp+0x98] ; arg1 = &rgvarg[1]
01001267 call qword ptr [_imp_VariantClear (01001018)]
0100126d jmp ReleasePQA (01001274)
코드는 조건부의 현재 분기를 완료하고 다른 분기를 건너뜁니다.
} else {
hr = E_OUTOFMEMORY;
}
}
OutOfMemory:
0100126f mov ebx,0x8007000e ; hr = E_OUTOFMEMORY
pqa->Release();
ReleasePQA:
01001274 mov rcx,[rsp+0x58] ; arg1 = pqa
01001279 mov rax,[rcx] ; rax = pqa.vtbl
0100127c call qword ptr [rax+0x10] ; release
else 분기입니다.
return hr;
}
0100127f mov eax,ebx ; rax = hr (for return value)
ReturnEAX:
01001281 add rsp,0x2c0 ; clean up the stack
01001288 pop r15d ; restore
0100128a pop r14d ; restore
0100128c pop r13d ; restore
0100128e pop r12d ; restore
01001290 pop rdi ; restore
01001291 pop rsi ; restore
01001292 pop rbx ; restore
01001293 ret ; return (do not pop arguments)
반환 값은 rax에 저장되고 반환하기 전에 비휘발성 레지스터가 복원됩니다.