Porady: definiowanie operatora konwersji (Visual Basic)

  • Artykuł

Jeśli zdefiniowano klasę lub strukturę, można zdefiniować operator konwersji typów między typem klasy lub struktury a innym typem danych (takim jak Integer, Doublelub String).

Zdefiniuj konwersję typu jako procedurę funkcji CType w klasie lub strukturze. Wszystkie procedury konwersji muszą mieć Public Sharedwartość , a każdy z nich musi określać rozszerzenie lub zawężenie.

Definiowanie operatora w klasie lub strukturze jest również nazywane przeciążeniem operatora.

Przykład

Poniższy przykład definiuje operatory konwersji między strukturą Byteo nazwie digit i .

Public Structure digit
Private dig As Byte
    Public Sub New(ByVal b As Byte)
        If (b < 0 OrElse b > 9) Then Throw New System.ArgumentException(
            "Argument outside range for Byte")
        Me.dig = b
    End Sub
    Public Shared Widening Operator CType(ByVal d As digit) As Byte
        Return d.dig
    End Operator
    Public Shared Narrowing Operator CType(ByVal b As Byte) As digit
        Return New digit(b)
    End Operator
End Structure

Możesz przetestować strukturę digit przy użyciu następującego kodu.

Public Sub consumeDigit()
    Dim d1 As New digit(4)
    Dim d2 As New digit(7)
    Dim d3 As digit = CType(CByte(3), digit)
    Dim s As String = "Initial 4 generates " & CStr(CType(d1, Byte)) &
          vbCrLf & "Initial 7 generates " & CStr(CType(d2, Byte)) &
          vbCrLf & "Converted 3 generates " & CStr(CType(d3, Byte))
    Try
        Dim d4 As digit
        d4 = CType(CType(d1, Byte) + CType(d2, Byte), digit)
    Catch e4 As System.Exception
        s &= vbCrLf & "4 + 7 generates " & """" & e4.Message & """"
    End Try
    Try
        Dim d5 As digit = CType(CByte(10), digit)
    Catch e5 As System.Exception
        s &= vbCrLf & "Initial 10 generates " & """" & e5.Message & """"
    End Try
    MsgBox(s)
End Sub

Zobacz też