Consultas para a tabela AzureMetrics

  • Artigo

Para obter informações sobre como usar essas consultas no portal do Azure, consulte o tutorial do Log Analytics. Para a API REST, consulte Consulta.

Gráfico de pizza de códigos de resposta HTTP

Detalhamento dos códigos de resposta para cada métrica, nas últimas 12 horas.

AzureMetrics 
| where TimeGenerated > ago(12h)  
| where MetricName in ("Http2xx", "Http3xx", "Http4xx", "Http5xx") 
| summarize sum(Total) by MetricName  
| render piechart

Gráfico de linhas de tempos de resposta

Séries temporais do tempo médio de resposta (em intervalos de 5 minutos).

AzureMetrics 
| extend timeBin = bin(TimeGenerated, 5m) 
| summarize ResponseTime = sumif(Average, MetricName=="AverageResponseTime") by timeBin, bin(TimeGenerated, 1h) 
| sort by TimeGenerated desc 
| render timechart

[Clássico] Localizar no AzureMetrics

[Clássico] Localizar em AzureMetrics para pesquisar um valor específico na tabela AzureMetrics./nObserve que essa consulta requer a atualização do <parâmetro SeachValue> para produzir resultados

// This query requires a parameter to run. Enter value in SearchValue to find in table.
let SearchValue =  "<SearchValue>";//Please update term you would like to find in the table.
AzureMetrics
| where * contains tostring(SearchValue)
| take 1000

Métricas mais recentes

Mostre os relatórios de métricas mais recentes para cada métrica relatada.

AzureMetrics 
| summarize arg_max(TimeGenerated, UnitName, Total, Count, Maximum, Minimum, Average) by MetricName

Localizar no AzureMetrics

Localizar em AzureMetrics para pesquisar um valor específico na tabela AzureMetrics./nObserve que essa consulta requer a atualização do <parâmetro SeachValue> para produzir resultados

// This query requires a parameter to run. Enter value in SearchValue to find in table.
let SearchValue =  "<SearchValue>";//Please update term you would like to find in the table.
AzureMetrics
| where * contains tostring(SearchValue)
| take 1000

Grafo de tráfego BitsInPerSecond do circuito do ExpressRoute

Gráfico de tráfego BitsInPerSecond (última hora).

AzureMetrics
| where MetricName == "BitsInPerSecond"
| summarize by Average, bin(TimeGenerated, 1h), Resource
| render timechart

Grafo de tráfego BitsOutPerSecond do circuito do ExpressRoute

Gráfico de tráfego BitsOutPerSecond (última hora).

AzureMetrics
| where MetricName == "BitsOutPerSecond"
| summarize by Average, bin(TimeGenerated, 1h), Resource
| render timechart

Grafo de ArpAvailablility do Circuito do ExpressRoute

Gráfico de tráfego para ArpAvailability (5 minutos).

AzureMetrics
| where MetricName == "ArpAvailability"
| summarize by Average, bin(TimeGenerated, 5m), Resource
| render timechart

Disponibilidade do BGP do Circuito do ExpressRoute

Gráfico de tráfego para BgpAvailability (5 minutos).

AzureMetrics
| where MetricName == "BgpAvailability"
| summarize by Average, bin(TimeGenerated, 5m), Resource
| render timechart

Média de uso da CPU

Média de uso da CPU na última hora por nome do recurso.

//consistently high averages could indicate a customer needs to move to a larger SKU
AzureMetrics
| where ResourceProvider == "MICROSOFT.SQL" // /DATABASES
| where TimeGenerated >= ago(60min)
| where MetricName in ('cpu_percent') 
| parse _ResourceId with * "/microsoft.sql/servers/" Resource  // subtract Resource name for _ResourceId
| summarize CPU_Maximum_last15mins = max(Maximum), CPU_Minimum_last15mins = min(Minimum), CPU_Average_last15mins = avg(Average) by Resource , MetricName

Solucionar problemas de desempenho

Potencialmente consulta ou deadlock no sistema que pode levar a um desempenho ruim.

//potentially a query or deadlock on the system that could lead to poor performance
AzureMetrics
| where ResourceProvider == "MICROSOFT.SQL"
| where TimeGenerated >=ago(60min)
| where MetricName in ('deadlock')
| parse _ResourceId with * "/microsoft.sql/servers/" Resource // subtract Resource name for _ResourceId
| summarize Deadlock_max_60Mins = max(Maximum) by Resource, MetricName

Carregamento de dados

Monitore o carregamento de dados na última hora.

AzureMetrics
| where ResourceProvider == "MICROSOFT.SQL"
| where TimeGenerated >= ago(60min)
| where MetricName in ('log_write_percent')
| parse _ResourceId with * "/microsoft.sql/servers/" Resource// subtract Resource name for _ResourceId
| summarize Log_Maximum_last60mins = max(Maximum), Log_Minimum_last60mins = min(Minimum), Log_Average_last60mins = avg(Average) by Resource, MetricName

Contagem de conexões P2S

Contagem de conexões P2S ativas nos últimos 30 dias.

AzureMetrics 
| where TimeGenerated > ago(30d)
| where MetricName == "P2SConnectionCount"
| summarize by Maximum, bin(TimeGenerated,1h), Resource
| render timechart

Utilização da largura de banda P2S

Utilização média da largura de banda P2S durante as últimas 12 horas em bits/segundo.

AzureMetrics
| where TimeGenerated > ago(24h)
| where MetricName == "P2SBandwidth" 
| summarize by Average, bin(TimeGenerated, 1h), Resource
| render timechart

Taxa de transferência do gateway

Taxa de transferência agregada do gateway em bytes/s.

AzureMetrics 
| where TimeGenerated > ago(24h)
| where MetricName == "AverageBandwidth"
| summarize by Average, bin(TimeGenerated, 1h), Resource
| render timechart

Mostrar logs da tabela AzureMetrics

Lista os logs mais recentes na tabela AzureMetrics, classificados por hora (mais recente primeiro).

AzureMetrics
| top 10 by TimeGenerated

Mostrar logs da tabela AzureMetrics

Lista os logs mais recentes na tabela AzureMetrics, classificados por hora (mais recente primeiro).

AzureMetrics
| top 10 by TimeGenerated

Disponibilidade do cluster (KeepAlive)

Exiba a disponibilidade do cluster durante a última hora.

// To create an alert for this query, click '+ New alert rule'
AzureMetrics 
| where ResourceProvider == "MICROSOFT.KUSTO"
| where TimeGenerated > ago(1d)
| where MetricName == "KeepAlive"
| parse _ResourceId with * "providers/microsoft.kusto/clusters/" cluster_name // Get the cluster name from the ResourceId string
| summarize heartbeat_count = count() by bin(TimeGenerated, 30m), cluster_name // bin is used to set the time grain to 30 minutes
| extend alive=iff(heartbeat_count > 0, true, false)
| sort by TimeGenerated asc // sort the results by time (ascending order)