Implantações condicionais no Bicep com a expressão if

  • Artigo

Para, opcionalmente, implantar um recurso ou módulo no Bicep, use a expressão if. Uma expressão if inclui uma condição que é resolvida como true ou false. Quando a condição if for verdadeira, o recurso será implantado. Quando o valor for false, o recurso não será criado. O valor só pode ser aplicado para o recurso ou módulo inteiro.

Observação

A implantação condicional não é propagada para os recursos filhos. Para implantar condicionalmente um recurso e seus recursos filhos, aplique a mesma condição a cada tipo de recurso.

Recursos de treinamento

Se você preferir aprender sobre condições por meio de diretrizes passo a passo, confira Criar modelos Bicep flexíveis usando condições e loops.

Definir condição para implantação

No Bicep, você pode implantar condicionalmente um recurso ao passar um parâmetro que especifica se o recurso está implantado. Teste a condição com uma instrução if na declaração do recurso. O exemplo a seguir mostra a sintaxe de uma expressão if em um arquivo Bicep. Ele implanta condicionalmente uma zona DNS. Quando deployZone é true, ele implanta a zona DNS. Quando deployZone é false, ele ignora a implantação da zona DNS.

param deployZone bool

resource dnsZone 'Microsoft.Network/dnsZones@2023-07-01-preview' = if (deployZone) {
  name: 'myZone'
  location: 'global'
}

O próximo exemplo implanta condicionalmente um módulo.

param deployZone bool

module dnsZone 'dnszones.bicep' = if (deployZone) {
  name: 'myZoneModule'
}

As condições podem ser usadas com declarações de dependência. Para dependências explícitas, o Azure Resource Manager o remove automaticamente das dependências obrigatórias quando o recurso não é implantado. Para dependências implícitas, fazer referência a uma propriedade de um recurso condicional é permitido, mas pode produzir um erro de implantação.

Recurso novo ou existente

Você pode usar a implantação condicional para criar um recurso novo ou usar um existente. O exemplo a seguir mostra como implantar uma nova conta de armazenamento ou usar uma existente.

param storageAccountName string
param location string = resourceGroup().location

@allowed([
  'new'
  'existing'
])
param newOrExisting string = 'new'

resource saNew 'Microsoft.Storage/storageAccounts@2023-04-01' = if (newOrExisting == 'new') {
  name: storageAccountName
  location: location
  sku: {
    name: 'Standard_LRS'
  }
  kind: 'StorageV2'
}

resource saExisting 'Microsoft.Storage/storageAccounts@2023-04-01' existing = if (newOrExisting == 'existing') {
  name: storageAccountName
}

output storageAccountId string = ((newOrExisting == 'new') ? saNew.id : saExisting.id)

Quando o parâmetro newOrExisting é definido como novo, a condição é avaliada como true. A conta de armazenamento é implantada. Fora isso, a conta de armazenamento existente será usada.

Aviso

Se fizer referência a um recurso implantado condicionalmente que não esteja implantado. Você receberá um erro informando que o recurso não está definido no modelo.

Funções de runtime

Ao usar uma função de referência ou de lista com um recurso implantado condicionalmente, a função é avaliada mesmo quando o recurso não é implantado. Você receberá um erro se a função se referir a um recurso que não existe.

Use o operador expressão condicional ?: para garantir que a função só seja avaliada quanto às condições quando o recurso estiver implantado. O modelo de exemplo a seguir mostra como usar essa função com expressões que só são válidas condicionalmente.

param vmName string
param location string
param logAnalytics string = ''

resource vmName_omsOnboarding 'Microsoft.Compute/virtualMachines/extensions@2024-03-01' = if (!empty(logAnalytics)) {
  name: '${vmName}/omsOnboarding'
  location: location
  properties: {
    publisher: 'Microsoft.EnterpriseCloud.Monitoring'
    type: 'MicrosoftMonitoringAgent'
    typeHandlerVersion: '1.0'
    autoUpgradeMinorVersion: true
    settings: {
      workspaceId: ((!empty(logAnalytics)) ? reference(logAnalytics, '2022-10-01').customerId : null)
    }
    protectedSettings: {
      workspaceKey: ((!empty(logAnalytics)) ? listKeys(logAnalytics, '2022-10-01').primarySharedKey : null)
    }
  }
}

output mgmtStatus string = ((!empty(logAnalytics)) ? 'Enabled monitoring for VM!' : 'Nothing to enable')

Próximas etapas