Operadores do acessador de Bicep

Os operadores de acessador são usados para acessar recursos filhos, propriedades em objetos e elementos em uma matriz. Com o acessador de propriedade, você também pode usar algumas funções.

Acessador de índice

array[integerIndex]

object['stringIndex']

Use o acessador de índice para obter um elemento de uma matriz ou de uma propriedade de um objeto.

Para uma matriz, forneça o índice como um inteiro. O inteiro corresponde à posição de base zero do elemento a ser recuperado.

Para um objeto, forneça o índice como uma cadeia de caracteres. A cadeia de caracteres corresponde ao nome do objeto a ser recuperado.

O exemplo a seguir obtém um elemento de uma matriz.

var arrayVar = [
  'Coho'
  'Contoso'
  'Fabrikan'
]

output accessorResult string = arrayVar[1]

Saída do exemplo:

O próximo exemplo obtém uma propriedade em um objeto.

var environmentSettings = {
  dev: {
    name: 'Development'
  }
  prod: {
    name: 'Production'
  }
}

output accessorResult string = environmentSettings['dev'].name

Saída do exemplo:

Acessador de função

resourceName.functionName()

Duas funções – getsecret e list * – dão suporte à chamada do operador do acessador. Essas duas funções são as únicas que dão suporte a esse operador do acessador.

Exemplo

O exemplo a seguir faz referência a um Key Vault existente e, em seguida, usa getSecret para transmitir um segredo a um módulo.

resource kv 'Microsoft.KeyVault/vaults@2023-07-01' existing = {
  name: kvName
  scope: resourceGroup(subscriptionId, kvResourceGroup )
}

module sql './sql.bicep' = {
  name: 'deploySQL'
  params: {
    sqlServerName: sqlServerName
    adminLogin: adminLogin
    adminPassword: kv.getSecret('vmAdminPassword')
  }
}

Acessador de recurso aninhado

parentResource::nestedResource

O recurso aninhado é declarado dentro de outro recurso. Com o acessador de recurso aninhado ::, você acessa recursos aninhados de fora do recurso pai.

No recurso pai, você faz referência ao recurso aninhado apenas com o nome simbólico. Você só precisa usar o acessador de recurso aninhado ao referenciar o recurso aninhado fora do recurso pai.

Exemplo

O exemplo a seguir mostra como fazer referência a um recurso aninhado de dentro e de fora do recurso pai.

resource demoParent 'demo.Rp/parentType@2024-01-01' = {
  name: 'demoParent'
  location: 'West US'

  // Declare a nested resource within 'demoParent'
  resource demoNested 'childType' = {
    name: 'demoNested'
    properties: {
      displayName: 'The nested instance.'
    }
  }

  // Declare another nested resource
  resource demoSibling 'childType' = {
    name: 'demoSibling'
    properties: {
      // Use symbolic name to reference because this line is within demoParent
      displayName: 'Sibling of ${demoNested.properties.displayName}'
    }
  }
}

// Use nested accessor to reference because this line is outside of demoParent
output displayName string = demoParent::demoNested.properties.displayName

Acessador de propriedade

objectName.propertyName

Com os acessadores de propriedade, você acessa as propriedades de um objeto. Esse tipo de acessador pode ser usado com qualquer objeto, como parâmetros e variáveis que consistem em objetos. Você recebe um erro quando usa o acesso à propriedade em uma expressão que não é um objeto.

Exemplo

O exemplo a seguir mostra uma variável de objeto e como acessar as propriedades.

var x = {
  y: {
    z: 'Hello'
    a: true
  }
  q: 42
}

output outputZ string = x.y.z
output outputQ int = x.q

Saída do exemplo:

Normalmente, você usa o acessador de propriedade com um recurso implantado no arquivo Bicep. O exemplo a seguir cria um endereço IP público e usa acessadores de propriedade para retornar um valor do recurso implantado.

resource publicIp 'Microsoft.Network/publicIPAddresses@2023-11-01' = {
  name: publicIpResourceName
  location: location
  properties: {
    publicIPAllocationMethod: dynamicAllocation ? 'Dynamic' : 'Static'
    dnsSettings: {
      domainNameLabel: publicIpDnsLabel
    }
  }
}

// Use property accessor to get value
output ipFqdn string = publicIp.properties.dnsSettings.fqdn

Próximas etapas

• Para executar os exemplos, use o CLI do Azure ou o Azure PowerShell para implantar um arquivo Bicep.
• Para criar um arquivo Bicep, consulte Início rápido: criar arquivos Bicep com o Visual Studio Code.
• Para obter informações sobre como resolver erros de tipo Bicep, confira Qualquer função para Bicep.