Exemplo de consultas do Azure Resource Graph para acessar dados de operações do Gerenciador de Atualizações do Azure

  • Artigo

Veja a seguir algumas consultas de exemplo para ajudá-lo a começar a consultar as informações de avaliação e implantação de atualização coletadas de seus computadores gerenciados. Para obter mais informações sobre logs criados a partir de operações como avaliações de atualização e instalações, consulte a visão geral dos logs de consulta.

Listar atualizações de sistema operacional disponíveis para todos os seus computadores agrupados por categoria de atualização

A consulta a seguir retorna uma lista de atualizações pendentes para seu computador com a hora em que a avaliação foi realizada, a ID do recurso para a avaliação, o tipo de sistema operacional no computador e as atualizações do sistema operacional disponíveis com base na classificação de atualização.

patchassessmentresources
| where type !has "softwarepatches"
| extend prop = parse_json(properties)
| extend lastTime = properties.lastModifiedDateTime
| extend updateRollupCount = prop.availablePatchCountByClassification.updateRollup, featurePackCount = prop.availablePatchCountByClassification.featurePack, servicePackCount = prop.availablePatchCountByClassification.servicePack, definitionCount = prop.availablePatchCountByClassification.definition, securityCount = prop.availablePatchCountByClassification.security, criticalCount = prop.availablePatchCountByClassification.critical, updatesCount = prop.availablePatchCountByClassification.updates, toolsCount = prop.availablePatchCountByClassification.tools, otherCount = prop.availablePatchCountByClassification.other, OS = prop.osType
| project lastTime, id, OS, updateRollupCount, featurePackCount, servicePackCount, definitionCount, securityCount, criticalCount, updatesCount, toolsCount, otherCount

Contagem de instalações de atualização

A consulta a seguir retorna uma lista de instalações de atualização com seu status para seus computadores dos últimos sete dias. Os resultados incluem a hora em que a implantação de atualização foi executada, a ID do recurso da instalação, os detalhes do computador e a contagem de atualizações do sistema operacional instaladas com base no status e na seleção.

patchinstallationresources
| where type !has "softwarepatches"
| extend machineName = tostring(split(id, "/", 8)), resourceType = tostring(split(type, "/", 0)), tostring(rgName = split(id, "/", 4))
| extend prop = parse_json(properties)
| extend lTime = todatetime(prop.lastModifiedDateTime), OS = tostring(prop.osType), installedPatchCount = tostring(prop.installedPatchCount), failedPatchCount = tostring(prop.failedPatchCount), pendingPatchCount = tostring(prop.pendingPatchCount), excludedPatchCount = tostring(prop.excludedPatchCount), notSelectedPatchCount = tostring(prop.notSelectedPatchCount)
| where lTime > ago(7d)
| project lTime, RunID=name,machineName, rgName, resourceType, OS, installedPatchCount, failedPatchCount, pendingPatchCount, excludedPatchCount, notSelectedPatchCount

Lista de instalações de atualização do sistema operacional Windows Server

A consulta a seguir retorna uma lista de instalações de atualização do Windows Server com seu status para seus computadores dos últimos sete dias. Os resultados incluem a hora em que a implantação de atualização foi executada, a ID do recurso da instalação, os detalhes do computador e outros detalhes de implantação relacionados.

patchinstallationresources
| where type has "softwarepatches" and isnull(properties.version)
| extend machineName = tostring(split(id, "/", 8)), resourceType = tostring(split(type, "/", 0)), tostring(rgName = split(id, "/", 4)), tostring(RunID = split(id, "/", 10))
| extend prop = parse_json(properties)
| extend lTime = todatetime(prop.lastModifiedDateTime), patchName = tostring(prop.patchName), kbId = tostring(prop.kbId), installationState = tostring(prop.installationState), classifications = tostring(prop.classifications)
| where lTime > ago(7d)
| project lTime, RunID, machineName, rgName, resourceType, patchName, kbId, classifications, installationState
| sort by RunID

Lista de instalações de atualização do sistema operacional Linux

A consulta a seguir retorna uma lista de instalações de atualização no Linux com seu status para seus computadores dos últimos sete dias. Os resultados incluem a hora em que a implantação de atualização foi executada, a ID do recurso da instalação, os detalhes do computador e outros detalhes de implantação relacionados.

patchinstallationresources
| where type has "softwarepatches" and isnotnull(properties.version) and isnull(properties.kbId)
| extend machineName = tostring(split(id, "/", 8)), resourceType = tostring(split(type, "/", 0)), tostring(rgName = split(id, "/", 4)), tostring(RunID = split(id, "/", 10))
| extend prop = parse_json(properties)
| extend lTime = todatetime(prop.lastModifiedDateTime), patchName = tostring(prop.patchName), version = tostring(prop.version), installationState = tostring(prop.installationState), classifications = tostring(prop.classifications)
| where lTime > ago(7d)
| project lTime, RunID, machineName, rgName, resourceType, patchName, version, classifications, installationState
| sort by RunID

Lista de registros de execução de manutenção no nível da VM

A consulta a seguir retorna uma lista de todos os registros de execução de manutenção de uma VM

maintenanceresources 
| where ['id'] contains "/subscriptions/<subscription-id>/resourcegroups/<resource-group>/providers/microsoft.compute/virtualmachines/<vm-name>" //VM Id here
| where ['type'] == "microsoft.maintenance/applyupdates" 
| where properties.maintenanceScope == "InGuestPatch"

Próximas etapas

  • Examine os logs e os resultados da pesquisa do Gerenciador de Atualizações no Azure usando o Azure Resource Graph.
  • Para solucionar problemas no Gerenciador de Atualizações, confira a solução de problemas.