Bibliotecas do .NET Core no Visual Basic de teste de unidade usando dotnet test e xUnit

Artigo
05/10/2023

Este tutorial mostra como criar uma solução que contém um projeto de teste de unidade e um projeto de biblioteca. Se você preferir acompanhar o tutorial usando uma solução interna, veja ou baixe o exemplo de código. Para obter instruções de download, consulte Exemplos e tutoriais.

Criar a solução

Nesta seção, é criada uma solução que contém os projetos de origem e teste. A solução concluída tem a seguinte estrutura de diretório:

/unit-testing-using-dotnet-test
    unit-testing-using-dotnet-test.sln
    /PrimeService
        PrimeService.vb
        PrimeService.vbproj
    /PrimeService.Tests
        PrimeService_IsPrimeShould.vb
        PrimeServiceTests.vbproj

As instruções a seguir fornecem as etapas para criar a solução de teste. Confira Comandos para criar uma solução de teste para obter instruções para criar a solução de teste em uma etapa.

Abra uma janela do shell.
Execute o comando a seguir:
```
dotnet new sln -o unit-testing-using-dotnet-test
```
O comando dotnet new sln cria uma nova solução no diretório unit-testing-using-dotnet-test.
Altere o diretório para a pasta unit-testing-using-dotnet-test.
Execute o comando a seguir:
```
dotnet new classlib -o PrimeService --lang VB
```
O comando dotnet new classlib cria um novo projeto de biblioteca de classes na pasta PrimeService. A nova biblioteca de classes conterá o código a ser testado.
Renomeie Class1.VB para PrimeService.VB.

Substitua o código em PrimeService.vb pelo código a seguir:

Imports System

Namespace Prime.Services
    Public Class PrimeService
        Public Function IsPrime(candidate As Integer) As Boolean
            Throw New NotImplementedException("Not implemented.")
        End Function
    End Class
End Namespace

O código anterior:
- Gera um NotImplementedException com uma mensagem indicando que ele não foi implementado.
- É atualizado posteriormente no tutorial.

No diretório unit-testing-using-dotnet-test, execute o seguinte comando para adicionar o projeto da biblioteca de classes à solução:
```
dotnet sln add ./PrimeService/PrimeService.vbproj
```
Crie o projeto PrimeService.Tests executando o seguinte comando:
```
dotnet new xunit -o PrimeService.Tests
```
O comando anterior:
- Cria o projeto PrimeService.Tests no diretório PrimeService.Tests. O projeto de teste usa xUnit como a biblioteca de teste.
- Configura o executor de teste adicionando os seguintes <PackageReference />elementos ao arquivo de projeto:
  - "Microsoft.NET.Test.Sdk"
  - "xunit"
  - "xunit.runner.visualstudio"
Adicione o projeto de teste ao arquivo de solução executando o seguinte comando:
```
dotnet sln add ./PrimeService.Tests/PrimeService.Tests.vbproj
```

Adicione a biblioteca de classes PrimeService como uma dependência ao projeto PrimeService.Tests:

dotnet add ./PrimeService.Tests/PrimeService.Tests.vbproj reference ./PrimeService/PrimeService.vbproj

Comandos para criar a solução

Esta seção resume todos os comandos na seção anterior. Ignore esta seção se você concluiu as etapas na seção anterior.

Os comandos a seguir criam a solução de teste em um computador Windows. Para macOS e Unix, atualize o comando ren para a versão do sistema operacional de ren para renomear um arquivo:

dotnet new sln -o unit-testing-using-dotnet-test
cd unit-testing-using-dotnet-test
dotnet new classlib -o PrimeService
ren .\PrimeService\Class1.vb PrimeService.vb
dotnet sln add ./PrimeService/PrimeService.vbproj
dotnet new xunit -o PrimeService.Tests
dotnet add ./PrimeService.Tests/PrimeService.Tests.vbproj reference ./PrimeService/PrimeService.vbproj
dotnet sln add ./PrimeService.Tests/PrimeService.Tests.vbproj

Siga as instruções para "Substituir o código no arquivo PrimeService.vb pelo código a seguir" na seção anterior.

Criar um teste

Uma abordagem popular no TDD (desenvolvimento controlado por teste) é escrever um teste antes de implementar o código de destino. Este tutorial usa a abordagem TDD. O método IsPrime pode ser chamado, mas não implementado. Uma chamada de teste para IsPrime falha. Com o TDD, é escrito um teste conhecido por falhar. O código de destino é atualizado para fazer o teste passar. Você continua repetindo essa abordagem, escrevendo um teste com falha e atualizando o código de destino para que ele seja aprovado.

Atualize o projeto PrimeService.Tests:

Exclua PrimeService.Tests/UnitTest1.vb.
Crie um arquivo PrimeService.Tests/PrimeService_IsPrimeShould.vb.
Substitua o código em PrimeService_IsPrimeShould.vb pelo código a seguir:

Imports Xunit

Namespace PrimeService.Tests
    Public Class PrimeService_IsPrimeShould
        Private ReadOnly _primeService As Prime.Services.PrimeService

        Public Sub New()
            _primeService = New Prime.Services.PrimeService()
        End Sub


        <Fact>
        Sub IsPrime_InputIs1_ReturnFalse()
            Dim result As Boolean = _primeService.IsPrime(1)

            Assert.False(result, "1 should not be prime")
        End Sub

    End Class
End Namespace

O atributo [Fact] indica um método de teste que é executado pelo executor de teste. Na pasta PrimeService.Tests, execute dotnet test. O comando de teste dotnet compila os dois projetos e executa os testes. O executor de teste do xUnit contém o ponto de entrada do programa para executar os testes. dotnet test inicia o executor de teste usando o projeto de teste de unidade.

O teste falha porque IsPrime não foi implementado. Usando a abordagem TDD, escreva apenas código suficiente para que esse teste passe. Atualize IsPrime com o seguinte código:

Public Function IsPrime(candidate As Integer) As Boolean
    If candidate = 1 Then
        Return False
    End If
    Throw New NotImplementedException("Not implemented.")
End Function

Execute dotnet test. O teste é aprovado.

Adicionar mais testes

Adicione testes de número primo para 0 e -1. Você pode copiar o teste anterior e alterar o seguinte código para usar 0 e -1:

Dim result As Boolean = _primeService.IsPrime(1)

Assert.False(result, "1 should not be prime")

Copiar o código de teste quando há apenas uma alteração de parâmetro resulta em duplicação de código e sobrecarga no teste. Os atributos xUnit a seguir permitem gravar um conjunto de testes semelhantes:

O [Theory] representa um pacote de testes que executa o mesmo código, mas têm diferentes argumentos de entrada.
O atributo [InlineData] especifica valores para essas entradas.

Em vez de criar testes, aplique os atributos xUnit anteriores para criar uma única teoria. Substitua o código a seguir:

<Fact>
Sub IsPrime_InputIs1_ReturnFalse()
    Dim result As Boolean = _primeService.IsPrime(1)

    Assert.False(result, "1 should not be prime")
End Sub

pelo código a seguir:

<Theory>
<InlineData(-1)>
<InlineData(0)>
<InlineData(1)>
Sub IsPrime_ValuesLessThan2_ReturnFalse(ByVal value As Integer)
    Dim result As Boolean = _primeService.IsPrime(value)

    Assert.False(result, $"{value} should not be prime")
End Sub

No código anterior, [Theory] e [InlineData] habilitam o teste de vários valores menores que dois. Dois é o menor número primo.

Execute dotnet test, dois dos testes falham. Para que todos os testes passem, atualize o método IsPrime com o seguinte código:

Public Function IsPrime(candidate As Integer) As Boolean
    If candidate < 2 Then
        Return False
    End If
    Throw New NotImplementedException("Not fully implemented.")
End Function

Após a abordagem TDD, adicione mais testes com falha e atualize o código de destino. Confira a versão concluída dos testes e a implementação completa da biblioteca.

O método concluído IsPrime não é um algoritmo eficiente para testar a primalidade.

Compartilhar via