Cadeias de caracteres interpoladas (Referência do Visual Basic)

  • Artigo

Usado para construir cadeias de caracteres. Uma cadeia de caracteres interpolada é semelhante a uma cadeia de caracteres de modelo que contém expressões interpoladas. Uma cadeia de caracteres interpolada retorna uma cadeia de caracteres que substitui as expressões interpoladas que ela contém por suas representações de cadeia de caracteres. Esse recurso está disponível no Visual Basic 14 e versões posteriores.

Os argumentos de uma cadeia de caracteres interpolada são mais fáceis de entender do que uma cadeia de caracteres de formato composto. Por exemplo, a cadeia de caracteres interpolada

Console.WriteLine($"Name = {name}, hours = {hours:hh}")

contém duas expressões interpoladas, "{name}" e "{hours:hh}". A cadeia de caracteres de formato composto equivalente é:

Console.WriteLine("Name = {0}, hours = {1:hh}", name, hours)

A estrutura de uma cadeia de caracteres interpolada é:

$"<text> {<interpolated-expression> [,<field-width>] [:<format-string>] } <text> ..."

em que:

  • field-width é um inteiro com sinal que indica o número de caracteres no campo. Se ele for positivo, o campo será alinhado à direita. Se for negativo, será alinhado à esquerda.

  • format-string é uma cadeia de caracteres de formato apropriada para o tipo do objeto que está sendo formatado. Por exemplo, para um valor DateTime, pode ser uma cadeia de caracteres de formato de data e hora padrão, como "D" ou "d".

Importante

Você não pode ter nenhum espaço em branco entre o $ e " que iniciam a cadeia de caracteres. Isso causa um erro do compilador.

Você pode usar uma cadeia de caracteres interpolada em qualquer lugar em que pode usar um literal de cadeia de caracteres. A cadeia de caracteres interpolada é avaliada sempre que o código com a cadeia de caracteres interpolada for executado. Isso permite que você separe a definição e a avaliação de uma cadeia de caracteres interpolada.

Para incluir uma chave ("{" ou "}") em uma cadeia de caracteres interpolada, use duas chaves, "{{" ou "}}". Consulte a seção sobre Conversões implícitas para obter mais detalhes.

Se a cadeia de caracteres interpolada contiver outros caracteres com significado especial em uma cadeia de caracteres interpolada, como aspas ("), dois-pontos (:) ou vírgulas (,), eles devem ser substituídos se ocorrerem no texto literal ou devem ser incluídos em uma expressão delimitada por parênteses se forem elementos de linguagem incluídos em uma expressão interpolada. O exemplo a seguir escapa as aspas para incluí-las na cadeia de caracteres de resultado:

Public Module Example
   Public Sub Main()
      Dim name = "Horace"
      Dim age = 34
      Dim s1 = $"He asked, ""Is your name {name}?"", but didn't wait for a reply."
      Console.WriteLine(s1)
      
      Dim s2 = $"{name} is {age:D3} year{If(age = 1, "", "s")} old."
      Console.WriteLine(s2) 
   End Sub
End Module
' The example displays the following output:
'       He asked, "Is your name Horace?", but didn't wait for a reply.
'       Horace is 034 years old.

Conversões implícitas

Há três conversões de tipo implícitas de uma cadeia de caracteres interpolada:

  1. Conversão de uma cadeia de caracteres interpolada em um String. O exemplo a seguir retorna uma cadeia de caracteres cujas expressões de cadeia de caracteres interpolada foram substituídas por suas representações de cadeia de caracteres. Por exemplo:

    Public Module Example
   Public Sub Main()
      Dim name = "Bartholomew"
      Dim s1 = $"Hello, {name}!"  
      Console.WriteLine(s1)
   End Sub
End Module
' The example displays the following output:
'      Hello, Bartholomew!
' </Snippet1>

    Esse é o resultado final de uma interpretação de cadeia de caracteres. Todas as ocorrências de chaves duplas ("{{" e "}}") serão convertidas em uma chave única.

  2. Conversão de uma cadeia de caracteres interpolada em uma variável IFormattable que permite criar várias cadeias de caracteres de resultado com conteúdo específico da cultura de uma única instância IFormattable. Isso é útil para incluir itens como os formatos de número e data corretos para culturas individuais. Todas as ocorrências de chaves duplas ("{{" e "}}") permanecem como chaves duplas até que você formate a cadeia de caracteres explícita ou implicitamente chamando o método ToString(). Todas as expressões de interpolação contidas são convertidas em {0}, {1} e assim por diante.

    O exemplo a seguir usa reflexão para exibir os membros, bem como os valores de campo e propriedade de uma variável IFormattable criada de uma cadeia de caracteres interpolada. Ele também passa a variável IFormattable para o método Console.WriteLine(String).

    Imports System.Globalization
Imports System.Reflection

Public Module Example
   Public Sub Main()
      Dim price = 1000
      Dim s2 As IFormattable = $"The cost of this item is {price:C}."  
      ShowInfo(s2)
      CultureInfo.CurrentCulture = New CultureInfo("en-US")
      Console.WriteLine(s2)
      CultureInfo.CurrentCulture = New CultureInfo("fr-FR")
      Console.WriteLine(s2)      
   End Sub

   Private Sub ShowInfo(obj As Object)
      Console.WriteLine($"Displaying member information:{vbCrLf}")
      Dim t = obj.GetType()
      Dim flags = BindingFlags.Public Or BindingFlags.Instance Or BindingFlags.Static Or BindingFlags.NonPublic
      For Each m In t.GetMembers(flags) 
         Console.Write($"   {m.Name} {m.MemberType}")   
         If m.MemberType = MemberTypes.Property Then
            Dim p = t.GetProperty(m.Name, flags)
            Console.Write($"   Value: {p.GetValue(obj)}")         
         End If
         If m.MemberType = MemberTypes.Field Then
            Dim f = t.GetField(m.Name, flags)
            Console.Write($"   Value: {f.GetValue(obj)}")
         End If
         Console.WriteLine()
      Next
      Console.WriteLine($"-------{vbCrLf}")
   End Sub
End Module
' The example displays the following output:
Displaying member information:

'       get_Format Method
'       GetArguments Method
'       get_ArgumentCount Method
'       GetArgument Method
'       ToString Method
'       System.IFormattable.ToString Method
'       ToString Method
'       Equals Method
'       GetHashCode Method
'       GetType Method
'       Finalize Method
'       MemberwiseClone Method
'       .ctor Constructor
'       Format Property   Value: The cost of this item is {0:C}.
'       ArgumentCount Property   Value: 1
'       _format Field   Value: The cost of this item is {0:C}.
'       _arguments Field   Value: System.Object[]
'       -------
'
'       The cost of this item is $1,000.00.
'       The cost of this item is 1 000,00 €.
' </Snippet1>

    Observe que a cadeia de caracteres interpolada pode ser inspecionada somente usando a reflexão. Se ela for passada para um método de formatação de cadeia de caracteres, como WriteLine(String), seus itens de formato serão resolvidos e a cadeia de caracteres de resultado será retornada.

  3. Conversão de uma cadeia de caracteres interpolada em uma variável FormattableString que representa uma cadeia de caracteres de formato composto. Inspecionar a cadeia de caracteres de formato composto e como ela é renderizada como uma cadeia de caracteres de resultado pode, por exemplo, ajudar a proteger contra um ataque de injeção se você estiver criando uma consulta. Um FormattableString também inclui:

    Todas as ocorrências de chaves duplas ("{{" e "}}") permanecem como chaves duplas, até você formatar. Todas as expressões de interpolação contidas são convertidas em {0}, {1} e assim por diante.

    Imports System.Globalization

Public Module Example
   Public Sub Main()
      Dim name = "Bartholomew"
      Dim s3 As FormattableString = $"Hello, {name}!"  
      Console.WriteLine($"String: '{s3.Format}'")
      Console.WriteLine($"Arguments: {s3.ArgumentCount}")
      Console.WriteLine($"Result string: {s3}")
   End Sub
End Module
' The example displays the following output:
'       String: 'Hello, {0}!'
'       Arguments: 1
'       Result string: Hello, Bartholomew!

Confira também