propriedade Application.Name (Visio)

  • Artigo

Especifica o nome de um objeto. Somente leitura.

Sintaxe

expressão. Nome

expressão Uma variável que representa um Aplicativo objeto.

Valor de retorno

Cadeia de caracteres

Comentários

Você pode obter, mas não definir, a propriedade Name de um objeto Document. Se o documento ainda não estiver nomeado, essa propriedade retornará o nome temporário do documento - por exemplo, Drawing1 or Stencil1.

É possível obter, mas não definir, a propriedade Name de um objeto Addon ou um objeto Font.

Você pode obter, mas não definir, a propriedade Name de um objeto Cell. Algumas células estão em linhas nomeadas; você pode obter e definir o nome de uma linha nomeada usando a propriedade RowName.

É possível definir a propriedade Name de um objeto Style que representa um estilo que não é o estilo padrão do Microsoft Office Visio. Se você tentar definir a propriedade Name de um estilo padrão do Visio, um erro será gerado.

Uma célula possui um nome local e um universal. O nome local difere dependendo do local no qual a versão em execução do Microsoft Windows está instalada. O nome universal é o mesmo, independentemente do local no qual ele está instalado. Para obter o nome universal de uma célula, use a propriedade Name. Para obter o nome local, use a propriedade LocalName.

Observação

A partir do Microsoft Visio 2000, você pode usar nomes locais e universais para se referir a formas, mestres, documentos, páginas, linhas, complementos, células, hiperlinks, estilos, fontes, atalhos mestre, objetos UI e camadas do Visio. Quando um usuário nomeia uma forma, por exemplo, o usuário está especificando um nome local. A partir do Visio 2003, a planilha ShapeSheet exibe apenas nomes universais em fórmulas e valores de células. (Em versões anteriores, os nomes universais não eram visíveis na interface do usuário.).

Como desenvolvedor, você poderá usar nomes universais em um programa quando não quiser alterar um nome a cada vez que uma solução for localizada. Use a propriedade Name para obter ou definir o nome local de um objeto Hyperlink, Layer, Master, MasterShortcut, Page, Shape, Style ou Row. Use a propriedade NameU para obter ou definir seu nome universal.

Exemplo

Esta macro do VBA (Microsoft Visual Basic for Applications) mostra como usar a propriedade Name para exibir nomes de camadas. Adicionalmente, ela usa a propriedade Layer para obter uma referência a uma camada específica e a propriedade LayerCount para determinar o número de camadas às quais uma forma foi atribuída.

 
Public Sub Name_Example() 
 
 Dim vsoPage As Visio.Page 
 Dim vsoShape As Visio.Shape 
 Dim vsoLayers As Visio.Layers 
 Dim vsoLayer As Visio.Layer 
 
 If ActiveDocument Is Nothing Then 
 Documents.Add ("") 
 End If 
 
 Set vsoPage = ActivePage 
 If vsoPage Is Nothing Then 
 Set vsoPage = ActiveDocument.Pages(1) 
 End If 
 
 'Draw a rectangle. 
 Set vsoShape = vsoPage.DrawRectangle(1, 5, 5, 1) 
 
 'Get the Layers collection. 
 Set vsoLayers = vsoPage.Layers 
 
 'Create a layer named ExampleLayer1 and add the shape to it. 
 Set vsoLayer = vsoLayers.Add("ExampleLayer1") 
 vsoLayer.Add vsoShape, 1 
 
 'Create a layer named ExampleLayer2 and add the shape to it. 
 Set vsoLayer = vsoLayers.Add("ExampleLayer2") 
 vsoLayer.Add vsoShape, 1 
 
 'Verify that the shape has been assigned to 2 layers. 
 Debug.Print "The page has " & vsoShape.LayerCount & " layers." 
 
 'Get a reference to the first layer. 
 Set vsoLayer = vsoShape.Layer(1) 
 
 'Verify by using the Name property. 
 Debug.Print "Current vsoLayer name is """ & vsoLayer.Name & ".""" 
 
End Sub

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.