Propriedade Application.StartupPaths (Visio)

Obtém ou define os caminhos onde o Microsoft Visio buscará complementos de terceiros e do usuário para serem executados quando o aplicativo for iniciado. Leitura/gravação.

Sintaxe

expressão. StartupPaths

expressão Uma variável que representa um Aplicativo objeto.

Valor de retorno

Cadeia de caracteres

Comentários

Por padrão, a propriedade StartupPaths é definida como uma sequência de caracteres vazia ("").

A cadeia de caracteres passada e recebida da propriedade StartupPaths é a mesma mostrada na caixa de diálogo Localizações de Arquivo. (Clique na guia Arquivo , clique em Opções, clique em Avançado e, em Geral, clique em Locais de Arquivo.) Essa cadeia de caracteres é armazenada na subchaveHKEY_CURRENT_USER\Software\Microsoft\Office\14.0\Visio\Application\StartupPath .

Quando o aplicativo procura arquivos de complemento de inicialização de terceiros e usuários, ele examina todos os caminhos nomeados na propriedade StartupPaths , bem como nos caminhos de quaisquer complementos de inicialização instalados na instalação e em todas as subpastas desses caminhos. Se você passar a propriedade StartupPaths para o método EnumDirectories, ela retorna uma lista completa de caminhos totalmente qualificados nas pastas procuradas.

Definir a propriedade StartupPaths substitui os valores existentes para StartupPaths na caixa de diálogo Locais do Arquivo . Para reter valores existentes, obtenha a sequência de caracteres existentes e anexe o novo caminho de arquivo para a sequência de caracteres, como exibido no seguinte código:

Application.StartupPaths = Application.StartupPaths & ";" & "newpath ".

Exemplo

Esta macro do Microsoft Visual Basic for Applications (VBA) macro mostra como utilizar a propriedade StartupPaths para adicionar um caminho à lista de caminhos Inicialização.

Public Sub StartupPaths_Example() 
  
    Dim strMessage As String 
    Dim strNewPath As String 
    Dim strStartupPath As String 
    Dim strTitle As String  
 
    'Get the path we want to add.  
    strStartupPath = Application.StartupPaths  
    strTitle = "StartupPaths"  
    strMessage = "The current content of the Visio Start-up paths box is:"  
    strMessage = strMessage & vbCrLf & strStartupPath  
    MsgBox strMessage, vbInformation + vbOKOnly, strTitle  
    strMessage = "Type in an additional path for Visio to look for add-ons. "  
         
    strNewPath = InputBox$(strMessage, strTitle)  
 
    'Make sure the folder exists and that it's not 
    'already in the Start-up paths box.  
    strMessage = ""  
 
    If strNewPath = ""  Then 
        strMessage = "You did not enter a path." 
    ElseIf InStr(strStartupPath, strNewPath)  Then 
        strMessage = "The path you specified is already in the Start-up paths box." 
    ElseIf Len(Dir$(strNewPath, vbDirectory)) = 0 And _  
                Len(Dir$(Application.Path & strNewPath, _  
                vbDirectory)) = 0 Then 
        strMessage = "The folder you typed does not exist (or is empty)." 
    Else 
        Application.StartupPaths = strStartupPath & ";" & strNewPath 
        strMessage = "We just added " & strNewPath & _  
                " to the startup paths." 
    End If 
       
    If strMessage <> ""  Then 
        MsgBox strMessage, vbExclamation + vbOKOnly, strTitle  
    End If 
  
End Sub

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.