Propriedade Application.TemplatePaths (Visio)

Obtém ou define os caminhos nos quais o Microsoft Visio procura por modelos. Leitura/gravação.

Sintaxe

expressão. TemplatePaths

expressão Uma variável que representa um Aplicativo objeto.

Valor de retorno

String

Comentários

Por padrão, a propriedade TemplatePaths é definida em uma sequência de caracteres vazia ("").

A cadeia de caracteres passada e recebida da propriedade TemplatePaths é a mesma mostrada na caixa de diálogo Localizações de Arquivo. (Clique na guia Arquivo , clique em Opções, clique em Avançado e, em Geral, clique em Locais de Arquivo.) Essa cadeia de caracteres é armazenada na subchaveHKEY_CURRENT_USER\Software\Microsoft\Office\14.0\Visio\Application\TemplatePath .

Quando o Visio procura por modelos, ele procura em todos os caminhos nomeados na propriedade TemplatePaths e todas as subpastas desses caminhos. Se você passar a propriedade TemplatePaths para o método EnumDirectories, ela retorna uma lista completa de caminhos totalmente qualificados nas pastas passadas.

Definir a propriedade TemplatePaths substitui os valores existentes para Modelos na caixa de diálogo Locais do Arquivo . Para reter valores existentes, obtenha a sequência de caracteres existentes e anexe o novo caminho de arquivo para a sequência de caracteres, como exibido no seguinte código:

Application.TemplatePaths = Application.TemplatePaths & ";" & "newpath".

Exemplo

Esta macro do Microsoft Visual Basic for Applications (VBA) macro mostra como utilizar a propriedade TemplatePaths para adicionar um caminho à caixa de caminhos Templates.

 
Public Sub TemplatePaths_Example()  
 
    Dim strMessage As String 
    Dim strNewPath As String 
    Dim strTemplatePath As String 
    Dim strTitle As String 
     
    'Get the path we want to add.  
    strTemplatePath = Application.TemplatePaths  
    strTitle = "TemplatePaths"  
    strMessage = "The current content of the Visio Templates path box is:"  
    strMessage = strMessage & vbCrLf & strTemplatePath  
    MsgBox strMessage, vbInformation + vbOKOnly, strTitle  
    strMessage = "Type in an additional path for Visio to look for templates."  
    strNewPath = InputBox$(strMessage, strTitle)  
 
    'Make sure the folder exists and that it's not 
    'already in the Templates path box.  
    strMessage = ""  
    If strNewPath = ""  Then 
        strMessage = "You did not enter a path." 
        ElseIf InStr(strTemplatePath, strNewPath)  Then 
            strMessage = "The path you specified is already in the Templates path box."  
        ElseIf Len(Dir$(strNewPath, vbDirectory)) = 0 And _  
                Len(Dir$(Application.Path & strNewPath, _  
                vbDirectory)) = 0 Then 
            strMessage = "The folder you typed does not exist (or is blank)."  
        Else 
            Application.TemplatePaths = strTemplatePath & ";" & strNewPath  
            strMessage = "We just added " & strNewPath & _  
                " to the Templates path box."  
    End If 
   
    If strMessage <> ""  Then 
        MsgBox strMessage, vbExclamation + vbOKOnly, strTitle  
    End If  
  
End Sub

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.