sp_describe_cursor_tables (Transact-SQL)

Sintaxe

sp_describe_cursor_tables 
     [ @cursor_return = ] output_cursor_variable OUTPUT 
     { [ , [ @cursor_source = ] N'local'
          , [ @cursor_identity = ] N'local_cursor_name' ] 
   | [ , [ @cursor_source = ] N'global'
          , [ @cursor_identity = ] N'global_cursor_name' ] 
   | [ , [ @cursor_source = ] N'variable'
          , [ @cursor_identity = ] N'input_cursor_variable' ] 
     } 
[;]

Argumentos

• [ @cursor_return = ] output_cursor_variableOUTPUT
  É o nome de uma variável de cursor declarada para receber a saída do cursor. output_cursor_variable é cursor, sem padrão, e não deve estar associado a nenhum cursor, no momento em que sp_describe_cursor_tables é chamado. O cursor retornado é um cursor rolável, dinâmico, somente leitura.

• [ @cursor_source = ] { N'local' | N'global' | N'variable' }
  Especifica se o cursor que está sendo relatado foi especificado usando o nome de um cursor local, de um cursor global ou de uma variável de cursor. O parâmetro é nvarchar(30).

• [ @cursor_identity = ] N'local_cursor_name'
  É o nome de um cursor criado por uma instrução DECLARE CURSOR que tem a palavra-chave LOCAL, ou que adotou o padrão LOCAL. local_cursor_name é nvarchar(128).

• [ @cursor_identity = ] N'global_cursor_name'
  É o nome de um cursor criado por uma instrução DECLARE CURSOR que tem a palavra-chave GLOBAL, ou que adotou GLOBAL como padrão. global_cursor_name também podem ser o nome de um cursor de servidor de API aberto por um aplicativo de ODBC, que então nomeou o cursor chamando SQLSetCursorName.global_cursor_name é nvarchar(128).

• [ @cursor_identity = ] N'input_cursor_variable'
  É o nome de uma variável de cursor associada a um cursor aberto. input_cursor_variable é nvarchar(128).

Valores de código de retorno

Nenhum

Cursores retornados

sp_describe_cursor_tables encapsula seu relatório como um parâmetro de saída Transact-SQLcursor. Isso permite que lotes Transact-SQL, procedimentos armazenados e gatilhos trabalhem com a saída uma linha de cada vez. Isso também significa que o procedimento não pode ser chamado diretamente de funções API. O parâmetro de saída cursor deve ser associado a uma variável de programa, mas as APIs não oferecem suporte para associar parâmetros ou variáveis cursor.

A tabela a seguir exibe o formato do cursor retornado por sp_describe_cursor_tables.

Comentários

sp_describe_cursor_tables descreve tabelas base referenciadas por um cursor de servidor. Para uma descrição dos atributos do conjunto de resultados retornado pelo cursor, use sp_describe_cursor_columns. Para uma descrição das características globais do cursor, como sua habilidade para rolagem e atualização, use sp_describe_cursor. Para obter um relatório dos cursores de servidor Transact-SQL que estão visíveis na conexão, use sp_cursor_list.

Permissões

Requer associação na função public.

Exemplos

O exemplo a seguir abre um cursor global e usa sp_describe_cursor_tables para informar as tabelas referenciadas pelo cursor.

USE AdventureWorks2008R2;
GO
-- Declare and open a global cursor.
DECLARE abc CURSOR KEYSET FOR
SELECT LastName
FROM Person.Person
WHERE LastName LIKE 'S%';

OPEN abc;
GO
-- Declare a cursor variable to hold the cursor output variable
-- from sp_describe_cursor_tables.
DECLARE @Report CURSOR;

-- Execute sp_describe_cursor_tables into the cursor variable.
EXEC master.dbo.sp_describe_cursor_tables
      @cursor_return = @Report OUTPUT,
      @cursor_source = N'global', @cursor_identity = N'abc';

-- Fetch all the rows from the sp_describe_cursor_tables output cursor.
FETCH NEXT from @Report;
WHILE (@@FETCH_STATUS <> -1)
BEGIN
   FETCH NEXT from @Report;
END

-- Close and deallocate the cursor from sp_describe_cursor_tables.
CLOSE @Report;
DEALLOCATE @Report;
GO

-- Close and deallocate the original cursor.
CLOSE abc;
DEALLOCATE abc;
GO

Consulte também

Referência

Conceitos