• Artigo

sp_posttracertoken (Transact-SQL)

Esse procedimento envia um token de rastreamento para um log de transações no Publicador e inicia o processo de rastreamento de estatística de latência. As informações são registradas quando o token de rastreamento é gravado no log de transações, quando é captado pelo Log Reader Agent e quando é aplicado pelo Distribution Agent. Esse procedimento armazenado é executado no Publicador, no banco de dados de publicação. Para obter mais informações, consulte Medindo a latência e validando as conexões para a replicação de transação.

Ícone de vínculo de tópicoConvenções de sintaxe Transact-SQL

Sintaxe

sp_posttracertoken [ @publication = ] 'publication' 
    [ , [ @tracer_token_id = ] tracer_token_id OUTPUT
    [ , [ @publisher = ] 'publisher'

Argumentos

  • [ @publication = ] 'publication'
    É o nome da publicação para a qual a latência está sendo medida. publication é sysname, sem padrão.

  • [ @tracer_token_id= ] tracer_token_idOUTPUT
    É a ID do token de rastreamento a ser inserido. tracer_token_id é int com um padrão de NULL, e é um parâmetro OUTPUT. Esse valor pode ser usado para executar sp_helptracertokenhistory (Transact-SQL) ou sp_deletetracertokenhistory (Transact-SQL) sem executar sp_helptracertokens (Transact-SQL) primeiro.

  • [ @publisher= ] 'publisher'
    Especifica um Publicador não-Microsoft SQL Server. publisher é sysname, com um padrão de NULL e não deve ser especificado para um Editor SQL Server.

Valores de código de retorno

0 (êxito) ou 1 (falha)

Comentários

sp_posttracertoken é usado em replicação transacional.

Exemplo

DECLARE @publication AS sysname;
DECLARE @tokenID AS int;
SET @publication = N'AdvWorksProductTran'; 

USE [AdventureWorks2008R2]

-- Insert a new tracer token in the publication database.
EXEC sys.sp_posttracertoken 
  @publication = @publication,
  @tracer_token_id = @tokenID OUTPUT;
SELECT 'The ID of the new tracer token is ''' + 
    CONVERT(varchar,@tokenID) + '''.'
GO

-- Wait 10 seconds for the token to make it to the Subscriber.
WAITFOR DELAY '00:00:10';
GO

-- Get latency information for the last inserted token.
DECLARE @publication AS sysname;
DECLARE @tokenID AS int;
SET @publication = N'AdvWorksProductTran'; 

CREATE TABLE #tokens (tracer_id int, publisher_commit datetime)

-- Return tracer token information to a temp table.
INSERT #tokens (tracer_id, publisher_commit)
EXEC sys.sp_helptracertokens @publication = @publication;
SET @tokenID = (SELECT TOP 1 tracer_id FROM #tokens
ORDER BY publisher_commit DESC)
DROP TABLE #tokens

-- Get history for the tracer token.
EXEC sys.sp_helptracertokenhistory 
  @publication = @publication, 
  @tracer_id = @tokenID;
GO

Permissões

Somente membros da função de servidor fixa sysadmin ou da função de banco de dados fixa db_owner podem executar sp_posttracertoken.