sp_addextendedproperty (Transact-SQL)

Sintaxe

sp_addextendedproperty
    [ @name = ] { 'property_name' }
    [ , [ @value = ] { 'value' } 
        [ , [ @level0type = ] { 'level0_object_type' } 
                    , [ @level0name = ] { 'level0_object_name' } 
                [ , [ @level1type = ] { 'level1_object_type' } 
                                    , [ @level1name = ] { 'level1_object_name' } 
                        [ , [ @level2type = ] { 'level2_object_type' } 
                                                    , [ @level2name = ] { 'level2_object_name' } 
                        ] 
                ]
        ] 
    ] 

Argumentos

• [ @name ] = { 'property_name' }
  É o nome da propriedade a ser adicionada. property_name é sysname e não pode ser NULL. Os nomes também podem incluir espaço em branco ou cadeias de caracteres não alfanuméricos e valores binários.

• [ @value= ] { 'value' }
  É o valor a ser associado à propriedade. value é sql_variant, com um padrão NULL. O tamanho de value não pode ser maior que 7.500 bytes.

• [ @level0type= ] { 'level0_object_type' }
  É o tipo de objeto de nível 0. level0_object_type é varchar(128), com um padrão NULL.

  As entradas válidas são ASSEMBLY, CONTRACT, EVENT NOTIFICATION, FILEGROUP, MESSAGE TYPE, PARTITION FUNCTION, PARTITION SCHEME, REMOTE SERVICE BINDING, ROUTE, SCHEMA, SERVICE, USER, TRIGGER, TYPE e NULL.

  Importante
  USER e TYPE como tipos de nível 0 serão removidos em uma versão futura do SQL Server. Evite usar esses recursos em novo trabalho de desenvolvimento e planeje modificar os aplicativos que atualmente os utilizam. Use SCHEMA como o tipo de nível 0 em vez de USER. Para TYPE, use SCHEMA como o tipo de nível 0 e TYP como o tipo de nível 1.

• [ @level0name= ] { 'level0_object_name' }
  É o nome do tipo de objeto de nível 0 especificado. level0_object_name é sysname com um padrão NULL.

• [ @level1type = ] { 'level1_object_type' }
  É o tipo de objeto de nível 1. level1_object_type é varchar(128), com um padrão NULL. As entradas válidas são AGGREGATE, DEFAULT, FUNCTION, LOGICAL FILE NAME, PROCEDURE, QUEUE, RULE, SYNONYM, TABLE, TABLE_TYPE, TYPE, VIEW, XML SCHEMA COLLECTION e NULL.

• [ @level1name= ] { 'level1_object_name' }
  É o nome do tipo de objeto de nível 1 especificado. level1_object_name é sysname, com um padrão NULL.

• [ @level2type= ] { 'level2_object_type' }
  É o tipo de objeto de nível 2. level2_object_type é varchar(128), com um padrão NULL. As entradas válidas são COLUMN, CONSTRAINT, EVENT NOTIFICATION, INDEX, PARAMETER, TRIGGER e NULL.

• [ @level2name= ] { 'level2_object_name' }
  É o nome do tipo de objeto de nível 2 especificado. level2_object_name é sysname, com um padrão NULL.

Valores de código de retorno

0 (êxito) ou 1 (falha)

Comentários

Para especificar as propriedades estendidas, os objetos em um banco de dados do SQL Server são classificados em três níveis: 0, 1 e 2. O nível 0 é o nível mais alto e está definido como objetos que estão contidos no escopo do banco de dados. Objetos de nível 1 estão contidos em um esquema ou escopo do usuário, e os objetos de nível 2 estão contido pelos objetos de nível 1. As propriedades estendidas podem ser definidas para os objetos em qualquer um desses níveis.

As referências a um objeto de um nível precisam ser qualificadas com nomes de objetos de um nível superior que as possua ou contenha. Por exemplo, ao adicionar uma propriedade estendida à coluna de uma tabela (nível 2), é necessário também especificar o nome da tabela (nível 1) que contém a coluna e o esquema (nível 0) que contém a tabela.

Para obter uma lista completa de objetos e seus tipos válidos de nível 0, 1 e 2, consulte Usando propriedades estendidas em objetos de banco de dados.

Se todos os tipos e nomes de objeto forem nulos, a propriedade pertencerá ao próprio banco de dados atual.

Propriedades estendidas não são permitidas em objetos de sistema, objetos fora do escopo de um banco de dados definido pelo usuário ou objetos não listados em Argumentos como entradas válidas.

Replicando propriedades estendidas

Esquema versus usuário

Permissões

Os membros das funções de banco de dados fixa db_owner e db_ddladmin podem adicionar propriedades estendidas a qualquer objeto com a seguinte exceção: db_ddladmin não pode adicionar propriedades ao banco de dados em si ou a usuários ou funções.

Os usuários podem adicionar propriedades estendidas a objetos que possuam ou para os quais tenham permissões ALTER ou CONTROL. Para obter uma lista completa das permissões necessárias, consulte Usando propriedades estendidas em objetos de banco de dados.

Exemplos

A. Adicionando uma propriedade estendida a um banco de dados

USE AdventureWorks;
GO
--Add a caption to the AdventureWorks Database object itself.
EXEC sp_addextendedproperty 
@name = N'Caption', @value = 'AdventureWorks Sample OLTP Database';

B. Adicionando uma propriedade estendida a uma coluna em uma tabela

USE AdventureWorks;
GO
EXEC sp_addextendedproperty 
@name = N'Caption', @value = 'Postal code is a required column.',
@level0type = N'Schema', @level0name = Person,
@level1type = N'Table',  @level1name = Address,
@level2type = N'Column', @level2name = PostalCode;
GO

C. Adicionando uma propriedade de máscara de entrada a uma coluna

USE AdventureWorks;
GO
EXEC sp_addextendedproperty 
@name = N'Input Mask ', @value = '99999 or 99999-9999 or # ',
@level0type = N'Schema', @level0name = Person,
@level1type = N'Table', @level1name = Address, 
@level2type = N'Column',@level2name = PostalCode;
GO

D. Adicionando uma propriedade estendida a um grupo de arquivos

USE AdventureWorks;
GO
EXEC sys.sp_addextendedproperty 
@name = N'MS_DescriptionExample', 
@value = N'Primary filegroup for the AdventureWorks sample database.', 
@level0type = N'FILEGROUP', @level0name = [PRIMARY];
GO

Consulte também

Referência

Conceitos