• Artigo

@@ERROR (Transact-SQL)

Retorna o número de erro da última instrução Transact-SQL executada.

Ícone de vínculo de tópicoConvenções de sintaxe Transact-SQL

Sintaxe

@@ERROR

Tipos de retorno

integer

Comentários

Retornará 0 se a instrução Transact-SQL anterior não encontrar nenhum erro.

Retornará um número de erro se a instrução anterior encontrar um erro. Se o erro for um dos encontrados na exibição do catálogo sys.messages, @@ERROR terá o valor da coluna sys.messages.message_id para esse erro. É possível exibir o texto associado a um número de erro @@ERROR em sys.messages.

Como @@ERROR é apagado e redefinido em cada instrução executada, consulte-o imediatamente após a instrução ser verificada ou salve-o em uma variável local que possa ser verificada mais tarde.

Use a construção TRY...CATCH para manipular erros. A construção TRY...CATCH também oferece suporte a funções de sistema adicionais (ERROR_LINE, ERROR_MESSAGE, ERROR_PROCEDURE, ERROR_SEVERITY e ERROR_STATE) que retornam mais informações de erro que @@ERROR. TRY...CATCH também oferece suporte a uma função ERROR_NUMBER não limitada a retornar o número de erro na instrução imediatamente após a instrução que gerou um erro. Para obter mais informações, consulte TRY...CATCH (Transact-SQL).

Exemplos

A. Use @@ERROR para detectar um erro específico

Este exemplo usa @@ERROR para verificar uma violação de restrição de verificação (erro #547) em uma instrução UPDATE.

USE AdventureWorks;
GO
UPDATE HumanResources.EmployeePayHistory
    SET PayFrequency = 4
    WHERE EmployeeID = 1;
IF @@ERROR = 547
    PRINT N'A check constraint violation occurred.';
GO

B. Use @@ERROR para sair condicionalmente de um procedimento

As instruções IF...ELSE neste exemplo testam @@ERROR depois de uma instrução INSERT em um procedimento armazenado. O valor da variável @@ERROR determina o código de retorno enviado ao programa de chamada, indicando êxito ou falha do procedimento.

USE AdventureWorks;
GO
-- Drop the procedure if it already exists.
IF OBJECT_ID(N'HumanResources.usp_DeleteCandidate', N'P') IS NOT NULL
    DROP PROCEDURE HumanResources.usp_DeleteCandidate;
GO
-- Create the procedure.
CREATE PROCEDURE HumanResources.usp_DeleteCandidate 
    (
    @CandidateID INT
    )
AS
-- Execute the DELETE statement.
DELETE FROM HumanResources.JobCandidate
    WHERE JobCandidateID = @CandidateID;
-- Test the error value.
IF @@ERROR <> 0 
    BEGIN
        -- Return 99 to the calling program to indicate failure.
        PRINT N'An error occurred deleting the candidate information.';
        RETURN 99;
    END
ELSE
    BEGIN
        -- Return 0 to the calling program to indicate success.
        PRINT N'The job candidate has been deleted.';
        RETURN 0;
    END;
GO

C. Use @@ERROR com @@ROWCOUNT

Este exemplo usa @@ERROR com @@ ROWCOUNT para validar a operação de uma instrução UPDATE. O valor de @@ERROR é verificado quanto à indicação de um erro, e @@ROWCOUNT é usado para garantir que a atualização foi aplicada com êxito a uma linha na tabela.

USE AdventureWorks;
GO
IF OBJECT_ID(N'Purchasing.usp_ChangePurchaseOrderHeader',N'P')IS NOT NULL
    DROP PROCEDURE Purchasing.usp_ChangePurchaseOrderHeader;
GO
CREATE PROCEDURE Purchasing.usp_ChangePurchaseOrderHeader
    (
    @PurchaseOrderID INT
    ,@EmployeeID INT
   )
AS
-- Declare variables used in error checking.
DECLARE @ErrorVar INT;
DECLARE @RowCountVar INT;

-- Execute the UPDATE statement.
UPDATE PurchaseOrderHeader 
    SET EmployeeID = @EmployeeID 
    WHERE PurchaseOrderID = @PurchaseOrderID;

-- Save the @@ERROR and @@ROWCOUNT values in local 
-- variables before they are cleared.
SELECT @ErrorVar = @@ERROR
    ,@RowCountVar = @@ROWCOUNT;

-- Check for errors. If an invalid @EmployeeID was specified
-- the UPDATE statement returns a foreign-key violation error #547.
IF @ErrorVar <> 0
    BEGIN
        IF @ErrorVar = 547
            BEGIN
                PRINT N'ERROR: Invalid ID specified for new employee.';
                 RETURN 1;
            END
        ELSE
            BEGIN
                PRINT N'ERROR: error '
                    + RTRIM(CAST(@ErrorVar AS NVARCHAR(10)))
                    + N' occurred.';
                RETURN 2;
            END
    END

-- Check the row count. @RowCountVar is set to 0 
-- if an invalid @PurchaseOrderID was specified.
IF @RowCountVar = 0
    BEGIN
        PRINT 'Warning: The EmployeeID specified is not valid';
        RETURN 1;
    END
ELSE
    BEGIN
        PRINT 'Purchase order updated with the new employee';
        RETURN 0;
    END;
GO