sp_articlefilter (Transact-SQL)

Artigo
05/07/2013

Filtra dados que são publicados com base em um artigo de tabela. Esse procedimento armazenado é executado no Publicador, no banco de dados de publicação.

Ícone de vínculo de tópico Convenções da sintaxe Transact-SQL

Sintaxe

sp_articlefilter [ @publication = ] 'publication' 
        , [ @article = ] 'article'
    [ , [ @filter_name = ] 'filter_name' ]
    [ , [ @filter_clause = ] 'filter_clause' ]
    [ , [ @force_invalidate_snapshot = ] force_invalidate_snapshot ]
    [ , [ @force_reinit_subscription = ] force_reinit_subscription ]
    [ , [ @publisher = ] 'publisher' ]

Argumentos

[ @publication=] 'publication'
É o nome da publicação que contém o artigo. publication é sysname, sem padrão.
[ @article=] 'article'
É o nome do artigo. article é sysname, sem padrão.
[ @filter_name=] 'filter_name'
É o nome do procedimento armazenado de filtro a ser criado no filter_name. filter_name é nvarchar(386), com um padrão de NULL. Você deve especificar um nome exclusivo para o filtro de artigo.
[ @filter_clause=] 'filter_clause'
É uma cláusula de restrição (WHERE) que define um filtro horizontal. Ao inserir a cláusula de restrição, omita a palavra-chave WHERE. filter_clause é ntext, com um padrão de NULL.
[ @force_invalidate_snapshot = ] force_invalidate_snapshot
Confirma que a ação tomada por esse procedimento armazenado pode invalidar um instantâneo existente. force_invalidate_snapshot é um bit, com um padrão de 0.

0 especifica que as alterações no artigo não invalidam o instantâneo. Se o procedimento armazenado detectar que a alteração requer um novo instantâneo, ocorrerá um erro e nenhuma alteração será feita.

1 especifica que as alterações no artigo de mesclagem podem invalidar o instantâneo e se houver assinaturas existentes que exigem um novo instantâneo, dará permissão para que o instantâneo existente seja marcado como obsoleto e um novo instantâneo seja gerado.
[ @force_reinit_subscription = ] force_reinit_subscription
Confirma que a ação tomada por esse procedimento armazenado pode exigir que as assinaturas existentes sejam reinicializadas. force_reinit_subscription é um bit, com um padrão de 0.

0 especifica que alterações no artigo não fazem com que as assinaturas sejam reiniciadas. Se o procedimento armazenado detectar que a alteração irá requerer que as assinaturas existentes sejam reiniciadas, ocorrerá um erro e nenhuma alteração será feita.

1 especifica que alterações no artigo causam a reinicialização de assinaturas existentes e dão permissão para que ocorra a reinicialização da assinatura.
[ @publisher= ] 'publisher'
Especifica um Publicador que não é Microsoft SQL Server. publisher é sysname, com um padrão de NULL.

Observação

publisher não deve ser usado com um Editor SQL Server.

Observação
publisher não deve ser usado com um Editor SQL Server.

Valores de código de retorno

0 (êxito) ou 1 (falha)

Comentários

sp_articlefilter é usado em replicação de instantâneo e replicação transacional.

A execução de sp_articlefilter para um artigo com assinaturas existentes requer que essas assinaturas sejam reiniciadas.

sp_articlefilter cria o filtro, insere a ID do procedimento armazenado de filtro na coluna filter da tabela sysarticles (Transact-SQL) e, depois, insere o texto da cláusula de restrição na coluna filter_clause.

Para criar um artigo com um filtro horizontal, execute sp_addarticle (Transact-SQL) sem parâmetro filter. Execute sp_articlefilter, fornecendo todos os parâmetros incluindo filter_clause e, depois, execute sp_articleview (Transact-SQL), fornecendo todos os parâmetros incluindo o filter_clause idêntico. Se a coluna já existir e tipo em sysarticles for 1 (artigo com base em log), o filtro anterior será excluído e um novo filtro será criado.

Se filter_name e filter_clause não forem fornecidos, o filtro anterior será excluído e a ID do filtro será definida como 0.

Exemplo

DECLARE @publication    AS sysname;
DECLARE @table AS sysname;
DECLARE @filterclause AS nvarchar(500);
DECLARE @filtername AS nvarchar(386);
DECLARE @schemaowner AS sysname;
SET @publication = N'AdvWorksProductTran'; 
SET @table = N'Product';
SET @filterclause = N'[DiscontinuedDate] IS NULL'; 
SET @filtername = N'filter_out_discontinued';
SET @schemaowner = N'Production';

-- Add a horizontally and vertically filtered article for the Product table.
-- Manually set @schema_option to ensure that the Production schema 
-- is generated at the Subscriber (0x8000000).
EXEC sp_addarticle 
    @publication = @publication, 
    @article = @table, 
    @source_object = @table,
    @source_owner = @schemaowner, 
    @schema_option = 0x80030F3,
    @vertical_partition = N'true', 
    @type = N'logbased',
    @filter_clause = @filterclause;

-- (Optional) Manually call the stored procedure to create the 
-- horizontal filtering stored procedure. Since the type is 
-- 'logbased', this stored procedures is executed automatically.
EXEC sp_articlefilter 
    @publication = @publication, 
    @article = @table, 
    @filter_clause = @filterclause, 
    @filter_name = @filtername;

-- Add all columns to the article.
EXEC sp_articlecolumn 
    @publication = @publication, 
    @article = @table;

-- Remove the DaysToManufacture column from the article
EXEC sp_articlecolumn 
    @publication = @publication, 
    @article = @table, 
    @column = N'DaysToManufacture', 
    @operation = N'drop';

-- (Optional) Manually call the stored procedure to create the 
-- vertical filtering view. Since the type is 'logbased', 
-- this stored procedures is executed automatically.
EXEC sp_articleview 
    @publication = @publication, 
    @article = @table,
    @filter_clause = @filterclause;
GO