Expressões Lambda
Uma expressão lambda é uma função sem um nome que calcula e retorna um único valor.Expressões lambda podem ser usadas em qualquer lugar que um tipo de representante for válido.
.gif "Observação") Observação: |
|---|
O RemoveHandler demonstrativo é uma exceção. Você não pode passar um expressão lambda para o parâmetro de representante RemoveHandler. |
O exemplo a seguir é um expressão lambda que aumenta seu argumento e retorna o valor.
Function (num As Integer) num + 1
Como uma expressão lambda é uma expressão, ela só pode ser usada como parte de uma instrução.
Por exemplo, você pode atribuir a função a um nome de variável, especialmente se você desejar usá-lo mais de uma vez.
Dim add1 = Function(num As Integer) num + 1
Para chamar a função, envie um valor para o parâmetro.
' The following line prints 6.
Console.WriteLine(add1(5))
Como alternativa, você pode declarar e executar a função ao mesmo tempo.
Console.WriteLine((Function(num As Integer) num + 1)(5))
Uma expressão lambda pode ser retornada como o valor de uma chamada de função (como é mostrado no exemplo na seção Contexto posteriormente neste tópico), ou passada como um argumento para um parâmetro delegate.No exemplo a seguir, expressões lambda booleanas são passados como um argumento para o método testResult.O método aplica o booliano teste para um argumento inteiro, valuee exibe "Sucesso", se retorna a expressão lambda True Quando aplicado a value, ou "Falha" se retorna a expressão lambda False.
Module Module2
Sub Main()
' The following line will print Success, because 4 is even.
testResult(4, Function(num) num Mod 2 = 0)
' The following line will print Failure, because 5 is not > 10.
testResult(5, Function(num) num > 10)
End Sub
' Sub testResult takes two arguments, an integer value and a
' Boolean function.
' If the function returns True for the integer argument, Success
' is displayed.
' If the function returns False for the integer argument, Failure
' is displayed.
Sub testResult(ByVal value As Integer, ByVal fun As Func(Of Integer, Boolean))
If fun(value) Then
Console.WriteLine("Success")
Else
Console.WriteLine("Failure")
End If
End Sub
End Module
Expressões Lambda em consultas
Em LINQ (consulta integrada à linguagem), expressões lambda são a base de muitos dos operadores de consulta padrão.O compilador cria expressões lambda para capturar os cálculos definidos nos métodos fundamentais de consulta como Where, Select, Order By, Take While, e outros.
Por exemplo, considere a consulta a seguir:
Dim londonCusts = From cust In db.Customers
Where cust.City = "London"
Select cust
Este exemplo é compilado para o código a seguir:
Dim londonCusts = db.Customers _
.Where(Function(cust) cust.City = "London") _
.Select(Function(cust) cust)
Para obter mais informações sobre métodos de consulta, consulte Consultas(Visual Basic).
Sintaxe de expressões lambda
A sintaxe de uma expressão lambda lembra a de uma função padrão.As diferenças são as seguintes:
Uma expressão lambda não tem um nome.
Expressões lambda não podem ter modificadores, como Overloads ou Overrides.
Expressões lambda não usam uma cláusula As para designar o tipo de retorno da função.Em vez disso, o tipo é inferido do valor que o corpo da expressão lambda avalia.Por exemplo, se o corpo da expressão lamba for Where cust.City = "London", seu tipo de retorno é Boolean.
O corpo da função deve ser uma expressão, não uma instrução.O corpo pode consistir de uma chamada para um procedimento de função, mas não uma chamada para um procedimento sub.
Não há nenhuma instrução Return.O valor retornado pela função é o valor da expressão no corpo da função.
Não há nenhuma instrução End Function.
Ou todos os parâmetros devem ter tipos de dados especificados ou todos devem ser inferidos.
Parâmetros opcionais e ParamArray não são permitidos.
Parâmetros genéricos não são permitidos.
Como resultado dessas restrições e das maneiras pelas quais as expressões lambda são usadas, elas geralmente são curtas e pouco complicadas.
Contexto
Uma expressão lambda compartilha seu contexto com o método no qual ela está definida.Ela tem os mesmos direitos de acesso que qualquer código escrito no método que a contém.Isso inclui acesso a variáveis de membro, funções e sub-rotinas, Me, e parâmetros e variáveis locais no método que a contém.
O acesso a variáveis e parâmetros locais no método que a contém pode se estender para além da vida útil do método.Desde que um representante que se refere a uma expressão lambda não esteja disponível para coleta de lixo, o acesso às variáveis no ambiente original é mantido.No exemplo a seguir, a variável target é local para makeTheGame, o método no qual a expressão lambda playTheGame está definida.Observe que a expressão lambda retornada, atribuída a takeAGuess em Main, ainda tem acesso à variável local target.
Module Module1
Sub Main()
' Variable takeAGuess is a Boolean function. It stores the target
' number that is set in makeTheGame.
Dim takeAGuess As gameDelegate = makeTheGame()
' Set up the loop to play the game.
Dim guess As Integer
Dim gameOver = False
While Not gameOver
guess = CInt(InputBox("Enter a number between 1 and 10 (0 to quit)", "Guessing Game", "0"))
' A guess of 0 means you want to give up.
If guess = 0 Then
gameOver = True
Else
' Tests your guess and announces whether you are correct. Method takeAGuess
' is called multiple times with different guesses. The target value is not
' accessible from Main and is not passed in.
gameOver = takeAGuess(guess)
Console.WriteLine("Guess of " & guess & " is " & gameOver)
End If
End While
End Sub
Delegate Function gameDelegate(ByVal aGuess As Integer) As Boolean
Public Function makeTheGame() As gameDelegate
' Generate the target number, between 1 and 10. Notice that
' target is a local variable. After you return from makeTheGame,
' it is not directly accessible.
Randomize()
Dim target As Integer = CInt(Int(10 * Rnd() + 1))
' Print the answer if you want to be sure the game is not cheating
' by changing the target at each guess.
Console.WriteLine("(Peeking at the answer) The target is " & target)
' The game is returned as a lambda expression. The lambda expression
' carries with it the environment in which it was created. This
' environment includes the target number. Note that only the current
' guess is a parameter to the returned lambda expression, not the target.
' Does the guess equal the target?
Dim playTheGame = Function(guess As Integer) guess = target
Return playTheGame
End Function
End Module
O exemplo a seguir demonstra a vasta gama de direitos de acesso da expressão lambda aninhada.Quando a expressão lambda retornado é executado de Main como aDel, ela acessa estes elementos:
Um campo da classe em que é definido: aField
Uma propriedade da classe em que é definido: aProp
Um parâmetro do método functionWithNestedLambda, em que é definido: level1
Uma variável local de functionWithNestedLambda: localVar
Um parâmetro da expressão lambda em que está aninhado: level2
Module Module3
Sub Main()
' Create an instance of the class, with 1 as the value of
' the property.
Dim lambdaScopeDemoInstance = New LambdaScopeDemoClass _
With {.Prop = 1}
' Variable aDel will be bound to the nested lambda expression
' returned by the call to functionWithNestedLambda.
' The value 2 is sent in for parameter level1.
Dim aDel As aDelegate = _
lambdaScopeDemoInstance.functionWithNestedLambda(2)
' Now the returned lambda expression is called, with 4 as the
' value of parameter level3.
Console.WriteLine("First value returned by aDel: " & aDel(4))
' Change a few values to verify that the lambda expression has
' access to the variables, not just their original values.
lambdaScopeDemoInstance.aField = 20
lambdaScopeDemoInstance.Prop = 30
Console.WriteLine("Second value returned by aDel: " & aDel(40))
End Sub
Delegate Function aDelegate(ByVal delParameter As Integer) _
As Integer
Public Class LambdaScopeDemoClass
Public aField As Integer = 6
Dim aProp As Integer
Property Prop() As Integer
Get
Return aProp
End Get
Set(ByVal value As Integer)
aProp = value
End Set
End Property
Public Function functionWithNestedLambda _
(ByVal level1 As Integer) As aDelegate
Dim localVar As Integer = 5
' When the nested lambda expression is executed the first
' time, as aDel from Main, the variables have these values:
' level1 = 2
' level2 = 3, after aLambda is called in the Return statement
' level3 = 4, after aDel is called in Main
' locarVar = 5
' aField = 6
' aProp = 1
' The second time it is executed, two values have changed:
' aField = 20
' aProp = 30
' level3 = 40
Dim aLambda = Function(level2 As Integer) _
Function(level3 As Integer) _
level1 + level2 + level3 + localVar _
+ aField + aProp
' The function returns the nested lambda, with 3 as the
' value of parameter level2.
Return aLambda(3)
End Function
End Class
End Module
Conversão para um tipo de representante
Uma expressão lambda pode ser convertida implicitamente para um tipo delegate compatível.Para obter mais informações sobre os requisitos gerais para compatibilidade, consulte Conversão de delegado reduzida.
Além disso, quando você atribui expressões lambda a delegates, você pode especificar os nomes dos parâmetros mas omitir seus tipos de dados, permitindo que os tipos sejam extraídos do delegate.No exemplo a seguir, uma expressão lambda é atribuída a uma variável chamada del do tipo ExampleDel, um representante que utiliza dois parâmetros, um número inteiro e uma sequência de caracteres.Observe que os tipos de dados dos parâmetros na expressão lambda não foram especificados.No entanto, del requer um argumento de número inteiro e um argumento de sequência de caracteres, conforme especificado na definição de ExampleDel.
' Definition of function delegate ExampleDel.
Delegate Function ExampleDel(ByVal arg1 As Integer, _
ByVal arg2 As String) As Integer
' Declaration of del as an instance of ExampleDel, with no data
' type specified for the parameters, m and s.
Dim del As ExampleDel = Function(m, s) m
' Valid call to del, sending in an integer and a string.
Console.WriteLine(del(7, "up"))
' Neither of these calls is valid. Function del requires an integer
' argument and a string argument.
' Not valid.
' Console.WriteLine(del(7, 3))
' Console.WriteLine(del("abc"))
Exemplos
O exemplo a seguir define uma expressão lambda que retorna True Se o argumento anulável tiver um valor atribuído, e False Se seu valor é Nothing.
Dim notNothing = Function(num? As Integer) _ num IsNot Nothing Dim arg As Integer = 14 Console.WriteLine("Does the argument have an assigned value?") Console.WriteLine(notNothing(arg))O exemplo a seguir define uma expressão lambda que retorna o índice do último elemento em uma matriz.
Dim numbers() As Integer = {0, 1, 2, 3, 4, 5, 6, 7, 8, 9} Dim lastIndex = Function(intArray() As Integer) _ intArray.Length - 1 For i = 0 To lastIndex(numbers) numbers(i) = numbers(i) + 1 Next
Consulte também
Tarefas
Como: PASS procedimentos como outro procedimento no Visual Basic
Como: Criar uma expressão lambda
Conceitos
Introdução ao LINQ no Visual Basic
Delegados e o operador AddressOf
Conversão de delegado reduzida