Async.StartChild <'T>. Método (F#)

Inicia uma computação filho dentro de um fluxo de trabalho assíncrono. Isso permite que vários computações assíncronas a ser executadas simultaneamente.

Caminho do namespace/módulo: Microsoft.FSharp.Control

Assembly: FSharp.Core (em FSharp.Core.dll)

// Signature:
static member StartChild : Async<'T> * ?int -> Async<Async<'T>>

// Usage:
Async.StartChild (computation)
Async.StartChild (computation, millisecondsTimeout = millisecondsTimeout)

Parâmetros

• computation
  Tipo: Async<'T>

  A computação filho.

• millisecondsTimeout
  Tipo: int

  O valor de tempo limite em milissegundos. Se não for fornecido, em seguida, o valor padrão é -1, que corresponde a Infinite.

Valor de retorno

Uma nova computação que aguarda a computação de entrada concluir.

Comentários

Este método normalmente deve ser usado como o imediato direita-hand-lado de um let! de vinculação em um F# de fluxo de trabalho assíncrono, isto é:

 async { 
    ...
    let! completor1 = childComputation1
    |> Async.StartChild
    let! completor2 = childComputation2
    |> Async.StartChild
    ... 
    let! result1 = completor1
    let! result2 = completor2
     ... }

Quando usado dessa maneira, cada um use de StartChild inicia uma instância do childComputation e retorna um completor objeto representando um cálculo de aguardar a conclusão da operação. Quando executado, o completor aguarda a conclusão de childComputation.

Exemplo

O exemplo de código a seguir ilustra o uso do Async.StartChild.

open System.Windows.Forms

let bufferData = Array.zeroCreate<byte> 100000000

let asyncChild filename =
        async {
            printfn "Child job start: %s" filename
            use outputFile = System.IO.File.Create(filename)
            do! outputFile.AsyncWrite(bufferData)
            printfn "Child job end: %s " filename
        }

let asyncParent =
        async {
            printfn "Parent job start."
            let! childAsync1 = Async.StartChild(asyncChild "longoutput1.dat")
            let! childAsync2 = Async.StartChild(asyncChild "longoutput2.dat")
            let! result1 = childAsync1
            let! result2 = childAsync2
            printfn "Parent job end."
        }


let form = new Form(Text = "Test Form")
let button = new Button(Text = "Start")
form.Controls.Add(button)
button.Click.Add(fun args -> Async.Start(asyncParent)
                             printfn "Completed execution." )
Application.Run(form)

Saída de exemplo

A saída é intercalada porque os trabalhos são executados simultaneamente.

Plataformas

O Windows 7, SP2 do Windows Vista, Windows XP SP3, Windows XP Professional x64 SP2, Windows Server 2008 R2, Windows Server 2008 SP2, Windows Server 2003 SP2

Informações sobre versão

O tempo de execução F#

Compatível com: 2.0, 4.0

Silverlight

Compatível com: 3

Consulte também

Referência

Classe Control.Async (F#)

Microsoft.FSharp.Control Namespace (F#)

Histórico de alterações