MailboxProcessor.Start <'Msg > Método (F#)

Cria e inicia um agente.

Caminho do namespace/módulo: Microsoft.FSharp.Control

Assembly: FSharp.Core (em FSharp.Core.dll)

// Signature:
static member Start : (MailboxProcessor<'Msg> -> Async<unit>) * ?CancellationToken -> MailboxProcessor<'Msg>

// Usage:
MailboxProcessor.Start (body)
MailboxProcessor.Start (body, cancellationToken = cancellationToken)

Parâmetros

• body
  Tipo: MailboxProcessor<'Msg> -> Async<unidade>

  A função para produzir uma computação assíncrona, será executada como o loop de leitura para o MailboxProcessor quando Start é chamado.

• cancellationToken
  Tipo: CancellationToken

  Um símbolo de cancelamento opcional para o body. O padrão é Async.DefaultCancellationToken.

Valor de retorno

Criaram MailboxProcessor.

Comentários

O body função é usada para gerar a computação assíncrona executada pelo agente.

Exemplo

O exemplo de código a seguir mostra como iniciar um agente de processador de caixa de correio. Neste exemplo, cada linha de entrada do console é lançada para uma fila de mensagens. O programa lê cada mensagem e responde por meio de um canal de resposta. Quando a mensagem "Stop" o especial. é recebida, a resposta de interrupção é enviada e sai do programa.

open System

type Message = string * AsyncReplyChannel<string>

let formatString = "Message number {0} was received. Message contents: {1}"

let printThreadId note =

    // Append the thread ID.
    printfn "%d : %s" System.Threading.Thread.CurrentThread.ManagedThreadId note


let agent = MailboxProcessor<Message>.Start(fun inbox ->
    let rec loop n =
        async {
                let! (message, replyChannel) = inbox.Receive();
                printThreadId "MailboxProcessor"
                if (message = "Stop") then
                    replyChannel.Reply("Stopping.")
                else
                    replyChannel.Reply(String.Format(formatString, n, message))
                do! loop (n + 1)
        }
    loop 0)

printfn "Mailbox Processor Test"
printfn "Type some text and press Enter to submit a message."
printfn "Type 'Stop' to close the program."

let rec loop() =
    printf "> "
    let input = Console.ReadLine()
    printThreadId("Console loop")
    let reply = agent.PostAndReply(fun replyChannel -> input, replyChannel)
    if (reply <> "Stopping.") then
        printfn "Reply: %s" reply
        loop()
    else
        ()
loop()

printfn "Press Enter to continue."
Console.ReadLine() |> ignore

A seguir é uma sessão de exemplo.

Plataformas

O Windows 7, SP2 do Windows Vista, Windows XP SP3, Windows XP Professional x64 SP2, Windows Server 2008 R2, Windows Server 2008 SP2, Windows Server 2003 SP2

Informações sobre versão

O tempo de execução F#

Compatível com: 2.0, 4.0

Silverlight

Compatível com: 3

Consulte também

Referência

Control.MailboxProcessor <'Msg > Classe (F#)

Microsoft.FSharp.Control Namespace (F#)

Histórico de alterações