Importa instrução (.NET espaço para nome e tipo)

Permite digitar os nomes a ser referenciado sem qualificação do espaço para nome.

Imports [ aliasname = ] namespace
-or-
Imports [ aliasname = ] namespace.element

Partes

Comentários

O Imports instrução permite que os tipos contidos em um determinado namespace para ser referenciado diretamente.

Você pode fornecer um único nome de namespace ou uma cadeia de caracteres de namespaces aninhados.Cada namespace aninhado é separado do namespace do nível imediatamente mais alto por um ponto final (.), como o exemplo a seguir ilustra.

Imports System.Collections.Generic

Cada arquivo-fonte pode conter qualquer número de declarações Imports.Estas deve seguir qualquer declaração de opção, como a declaração Option Strict, e eles devem preceder qualquer declaração de elemento de programação, como declarações Module ou Class.

Você pode usar Imports apenas em nível de arquivo.Isso significa que o contexto da declaração para importação deve ser um arquivo-fonte, e não um namespace, estrutura, módulo, interface, procedimento ou bloco.

Observe que a declaração Imports não cria elementos a partir de outros projetos e assemblies disponíveis para seu projeto.Importar não toma o lugar de configurar uma referência.Isso apenas remove a necessidade de se qualificar nome já estão disponíveis para seu projeto.Para mais informação veja "Importing Containing Elements" in Referências aos elementos declarados (Visual Basic).

Observação
Você pode definir implícito Imports instruções usando a Referências de página, Designer de projeto (Visual Basic).Para mais informações, consulte Como: Adicionar ou remover Namespaces (Visual Basic) importados.

Aliases de importação

Um Importar alias define o alias para um namespace ou tipo.Pseudônimos Import são úteis quando você necessita usar itens como o mesmo nome que está declarado em um ou mais namespaces.Para obter mais informações e um exemplo, consulte "Qualificação de um nome de elemento" em Referências aos elementos declarados (Visual Basic).

Você não deve declarar um membro no nível de módulo com o mesmo nome de aliasname.Se você o fizer, o compilador do Visual Basic utiliza aliasname apenas para o membro declarado e não o reconhece mais como um pseudônimo import.

Embora a sintaxe usada para se declarar um pseudimo Import é como aquela usada para importar um prefixo de namespace XML, os resultados são diferente.Um pseudônimo Import pode ser usado como uma expressão no seu código, ao passo que um prefixo de namespace XML pode ser usado apenas em literais XML ou propriedades de eixo XML como o prefixo para um nome habilitado ou nome de atributo.

Nomes de elementos

Se você fornecer element, ele deve representar uma elemento contêiner, ou seja, um elemento de programação que pode conter outros elementos.Elementos contêiner incluem classes, estruturas, módulos, interfaces e enumerações.

O escopo dos elementos disponibilizados por um Imports instrução depende se você especificar element.Se você especificar apenas namespace, todos os membros nomeados univocamente daquele namespace e os elementos contêiner dentro daquele namespace estão disponíveis sem habilitação.Se você especificar ambos namespace e element, apenas os membros daquele elemento estão disponíveis sem habilitação.

Exemplo

O exemplo a seguir retorna todas as pastas no diretório C:\ usando o DirectoryInfo classe.

O código tem não Imports instruções na parte superior do arquivo.Portanto, o DirectoryInfo, StringBuilder, e CrLf as referências são inteiramente qualificadas com os espaços para nome.

Public Function GetFolders() As String
    ' Create a new StringBuilder, which is used
    ' to efficiently build strings.
    Dim sb As New System.Text.StringBuilder

    Dim dInfo As New System.IO.DirectoryInfo("c:\")

    ' Obtain an array of directories, and iterate through
    ' the array.
    For Each dir As System.IO.DirectoryInfo In dInfo.GetDirectories()
        sb.Append(dir.Name)
        sb.Append(Microsoft.VisualBasic.ControlChars.CrLf)
    Next

    Return sb.ToString
End Function

O exemplo a seguir inclui Imports instruções para namespaces referenciados.Portanto, os tipos precisam ser totalmente qualificados com os espaços para nome.

' Place Imports statements at the top of your program.
Imports System.Text
Imports System.IO
Imports Microsoft.VisualBasic.ControlChars

Public Function GetFolders() As String
    Dim sb As New StringBuilder

    Dim dInfo As New DirectoryInfo("c:\")
    For Each dir As DirectoryInfo In dInfo.GetDirectories()
        sb.Append(dir.Name)
        sb.Append(CrLf)
    Next

    Return sb.ToString
End Function

O exemplo a seguir inclui Imports instruções que criam aliases para os espaços para nome referenciados.Os tipos são qualificados com os aliases.

Imports systxt = System.Text
Imports sysio = System.IO
Imports ch = Microsoft.VisualBasic.ControlChars

Public Function GetFolders() As String
    Dim sb As New systxt.StringBuilder

    Dim dInfo As New sysio.DirectoryInfo("c:\")
    For Each dir As sysio.DirectoryInfo In dInfo.GetDirectories()
        sb.Append(dir.Name)
        sb.Append(ch.CrLf)
    Next

    Return sb.ToString
End Function

O exemplo a seguir inclui Imports instruções que criam aliases para os tipos de referência.Os aliases são usados para especificar os tipos.

Imports strbld = System.Text.StringBuilder
Imports dirinf = System.IO.DirectoryInfo

Public Function GetFolders() As String
    Dim sb As New strbld

    Dim dInfo As New dirinf("c:\")
    For Each dir As dirinf In dInfo.GetDirectories()
        sb.Append(dir.Name)
        sb.Append(ControlChars.CrLf)
    Next

    Return sb.ToString
End Function

Consulte também

Referência

Declaração de namespace

Declaração Imports (Namespace XML)

Conceitos

Namespaces no Visual Basic

Referências e a declaração Imports (Visual Basic)

Referências aos elementos declarados (Visual Basic)