sp_addextendedproperty (Transact-SQL)

  • Artigo

Aplica-se a: SQL ServerBanco de Dados SQL do Azure Instância Gerenciada de SQL do Azure

Adiciona uma nova propriedade estendida a um objeto de banco de dados.

Convenções de sintaxe de Transact-SQL

Sintaxe

sp_addextendedproperty
    [ @name = ] N'name'
    [ , [ @value = ] value ]
    [ , [ @level0type = ] 'level0type' ]
    [ , [ @level0name = ] N'level0name' ]
    [ , [ @level1type = ] 'level1type' ]
    [ , [ @level1name = ] N'level1name' ]
    [ , [ @level2type = ] 'level2type' ]
    [ , [ @level2name = ] N'level2name' ]
[ ; ]

Argumentos

@name [ = ] N'nome'

O nome da propriedade a ser adicionada. @name é sysname, sem padrão, e não pode ser NULL. Os nomes podem incluir cadeias de caracteres em branco ou não alfanuméricas e valores binários.

[ @value = ] value

O valor a ser associado à propriedade. @value é sql_variant, com um padrão de NULL. O tamanho do @value não pode ser superior a 7.500 bytes.

@level0type [ = ] 'level0type'

O tipo de objeto de nível 0. @level0type é varchar(128), com um padrão de NULL.

As entradas válidas são:

  • ASSEMBLY
  • CONTRACT
  • EVENT NOTIFICATION
  • FILEGROUP
  • MESSAGE TYPE
  • PARTITION FUNCTION
  • PARTITION SCHEME
  • REMOTE SERVICE BINDING
  • ROUTE
  • SCHEMA
  • SERVICE
  • USER
  • TRIGGER
  • TYPE
  • PLAN GUIDE
  • NULL

Importante

A capacidade de especificar USER como um tipo de nível 0 em uma propriedade estendida de um objeto de tipo de nível 1 será removida em uma versão futura do SQL Server. Em vez disso, use SCHEMA como o tipo de nível 0. Por exemplo, ao definir uma propriedade estendida em uma tabela, especifique o esquema da tabela em vez de um nome de usuário. A capacidade de especificar TYPE como tipo de nível 0 será removida em uma versão futura do SQL Server. Para TYPE, use SCHEMA como o tipo de nível 0 e TYPE como o tipo de nível 1.

@level0name [ = ] N'nível0nome'

O nome do tipo de objeto de nível 0 especificado. @level0name é sysname, com um padrão de NULL.

@level1type [ = ] 'nível1tipo'

O tipo de objeto de nível 1. @level1type é varchar(128), com um padrão de NULL.

As entradas válidas são:

  • AGGREGATE
  • DEFAULT
  • FUNCTION
  • LOGICAL FILE NAME
  • PROCEDURE
  • QUEUE
  • RULE
  • SEQUENCE
  • SYNONYM
  • TABLE
  • TABLE_TYPE
  • TYPE
  • VIEW
  • XML SCHEMA COLLECTION
  • NULL

@level1name [ = ] N'nível1nome'

O nome do tipo de objeto de nível 1 especificado. @level1name é sysname, com um padrão de NULL.

@level2type [ = ] 'nível2tipo'

O tipo de objeto de nível 2. @level2type é varchar(128), com um padrão de NULL.

As entradas válidas são:

  • COLUMN
  • CONSTRAINT
  • EVENT NOTIFICATION
  • INDEX
  • PARAMETER
  • TRIGGER
  • NULL

@level2name [ = ] N'nível2nome'

O nome do tipo de objeto de nível 2 especificado. @level2name é sysname, com um padrão de NULL.

Valores do código de retorno

0 (sucesso) ou 1 (falha).

Comentários

Quando você especifica propriedades estendidas, os objetos em um banco de dados do SQL Server são classificados em três níveis: 0, 1 e 2. O nível 0 é o nível mais alto e está definido como objetos que estão contidos no escopo do banco de dados. Os objetos de nível 1 estão contidos em um esquema ou escopo de usuário e os objetos de nível 2 estão contidos pelos objetos de nível 1. As propriedades estendidas podem ser definidas para os objetos em qualquer um desses níveis.

As referências a um objeto de um nível precisam ser qualificadas com os nomes dos objetos de nível superior que as possua ou contenha. Por exemplo, ao adicionar uma propriedade estendida à coluna de uma tabela (nível 2), é necessário também especificar o nome da tabela (nível 1) que contém a coluna e o esquema (nível 0) que contém a tabela.

Se todos os tipos e nomes de objeto forem nulos, a propriedade pertencerá ao próprio banco de dados atual.

As propriedades estendidas não são permitidas em objetos do sistema, objetos fora do escopo de um banco de dados definido pelo usuário ou objetos não listados em Argumentos como entradas válidas.

Propriedades estendidas não são permitidas em tabelas com otimização de memória.

Replicar propriedades estendidas

As propriedades estendidas são replicadas apenas na sincronização inicial entre o Editor e o Assinante. Se você adicionar ou modificar uma propriedade estendida após a sincronização inicial, a alteração não será replicada. Para obter mais informações sobre como replicar objetos de banco de dados, consulte Publicar dados e objetos de banco de dados.

Esquema versus usuário

Não recomendamos especificar USER como um tipo de nível 0 ao aplicar uma propriedade estendida a um objeto de banco de dados, pois isso pode causar ambiguidade na resolução de nomes. Por exemplo, suponha que o usuário Mary possua dois esquemas (Mary e MySchema), e esses esquemas contenham uma tabela chamada MyTable. Se Mary adicionar uma propriedade estendida à tabela MyTable e especificar @level0type = 'USER', @level0name = N'Mary', não está claro a qual tabela a propriedade estendida é aplicada. Para manter a compatibilidade com versões anteriores, o SQL Server aplica a propriedade à tabela contida no esquema chamado Mary.

Permissões

Os membros das funções de banco de dados fixas db_owner e db_ddladmin podem adicionar propriedades estendidas a qualquer objeto com a seguinte exceção: db_ddladmin não podem adicionar propriedades ao próprio banco de dados ou a usuários ou funções.

Os usuários podem adicionar propriedades estendidas a objetos que possuam ou para os quais tenham permissões ALTER ou CONTROL.

Exemplos

R. Adicionar uma propriedade estendida a um banco de dados

O exemplo a seguir adiciona o nome da propriedade Caption com um valor de AdventureWorks2022 Sample OLTP Database ao banco de dados de exemplo AdventureWorks2022 .

USE AdventureWorks2022;
GO

--Add a caption to the AdventureWorks2022 Database object itself.
EXEC sp_addextendedproperty @name = N'Caption',
    @value = 'AdventureWorks2022 Sample OLTP Database';

B. Adicionar uma propriedade estendida a uma coluna em uma tabela

O exemplo a seguir adiciona uma propriedade de legenda à coluna PostalCode na tabela Address.

USE AdventureWorks2022;
GO

EXEC sp_addextendedproperty @name = N'Caption',
    @value = 'Postal code is a required column.',
    @level0type = 'SCHEMA', @level0name = N'Person',
    @level1type = 'TABLE', @level1name = N'Address',
    @level2type = 'COLUMN', @level2name = N'PostalCode';
GO

C. Adicionar uma propriedade de máscara de entrada a uma coluna

O exemplo a seguir adiciona uma propriedade 99999 or 99999-9999 or #### ### de máscara de entrada à coluna PostalCode na tabela Address.

USE AdventureWorks2022;
GO

EXEC sp_addextendedproperty @name = N'Input Mask ',
    @value = '99999 or 99999-9999 or #### ###',
    @level0type = 'SCHEMA', @level0name = N'Person',
    @level1type = 'TABLE', @level1name = N'Address',
    @level2type = 'COLUMN', @level2name = N'PostalCode';
GO

D. Adicionar uma propriedade estendida a um grupo de arquivos

O exemplo a seguir adiciona uma propriedade estendida ao grupo de arquivos PRIMARY .

USE AdventureWorks2022;
GO

EXEC sys.sp_addextendedproperty @name = N'MS_DescriptionExample',
    @value = N'Primary filegroup for the AdventureWorks2022 sample database.',
    @level0type = 'FILEGROUP', @level0name = N'PRIMARY';
GO

E. Adicionar uma propriedade estendida a um esquema

O exemplo a seguir adiciona uma propriedade estendida ao esquema HumanResources .

USE AdventureWorks2022;
GO

EXEC sys.sp_addextendedproperty @name = N'MS_DescriptionExample',
    @value = N'Contains objects related to employees and departments.',
    @level0type = 'SCHEMA', @level0name = N'HumanResources';

F. Adicionar uma propriedade estendida a uma tabela

O exemplo a seguir adiciona uma propriedade estendida à tabela Address no esquema Person .

USE AdventureWorks2022;
GO

EXEC sys.sp_addextendedproperty @name = N'MS_DescriptionExample',
    @value = N'Street address information for customers, employees, and vendors.',
    @level0type = 'SCHEMA', @level0name = N'Person',
    @level1type = 'TABLE', @level1name = N'Address';
GO

G. Adicionar uma propriedade estendida a uma função

O exemplo a seguir cria uma função de aplicativo e adiciona uma propriedade estendida à função.

USE AdventureWorks2022;
GO

CREATE APPLICATION ROLE Buyers
    WITH Password = '987G^bv876sPY)Y5m23';
GO

EXEC sys.sp_addextendedproperty @name = N'MS_Description',
    @value = N'Application Role for the Purchasing Department.',
    @level0type = 'USER', @level0name = N'Buyers';

H. Adicionar uma propriedade estendida a um tipo

O exemplo a seguir adiciona uma propriedade estendida a um tipo.

USE AdventureWorks2022;
GO

EXEC sys.sp_addextendedproperty @name = N'MS_Description',
    @value = N'Data type (alias) to use for any column that represents an order number. For example a sales order number or purchase order number.',
    @level0type = 'SCHEMA', @level0name = N'dbo',
    @level1type = 'TYPE', @level1name = N'OrderNumber';

I. Adicionar uma propriedade estendida a um usuário

O exemplo a seguir cria um usuário e adiciona uma propriedade estendida ao usuário.

USE AdventureWorks2022;
GO

CREATE USER CustomApp WITHOUT LOGIN;
GO

EXEC sys.sp_addextendedproperty @name = N'MS_Description',
    @value = N'User for an application.',
    @level0type = 'USER', @level0name = N'CustomApp';

Conteúdo relacionado