Exercício – adicionar parâmetros e decoradores

• 8 minutos

Como parte da migração de aplicativos de RH, você está criando um modelo de Bicep para implantar recursos do Azure. Neste exercício, você criará um Plano do Serviço de Aplicativo do Azure e um aplicativo do Serviço de Aplicativo. Você aplicará decoradores a cada parâmetro para garantir que eles sempre contenham os valores esperados.

Durante o processo, você executará as seguintes tarefas:

Este exercício usa a extensão Bicep para Visual Studio Code. É necessário que você instale essa extensão no Visual Studio Code.

Criar um modelo de Bicep com parâmetros

1. Abra o Visual Studio Code.

2. Crie um arquivo chamado main.bicep.

3. Salve o arquivo vazio para que Visual Studio Code carregue as ferramentas Bicep.

   Você pode selecionar Arquivo>Salvar Como ou Ctrl+S no Windows (⌘+S no macOS). Lembre-se de onde você salvou o arquivo. Por exemplo, você pode criar uma pasta scripts para salvá-lo.

4. Adicione o conteúdo a seguir ao arquivo. Você implantará o modelo em breve. Insira o conteúdo por conta própria em vez de copiar e colar para que você possa ver como o conjunto de ferramentas ajuda a criar arquivos Bicep.

   param environmentName string = 'dev'
   param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'
   param appServicePlanInstanceCount int = 1
   param appServicePlanSku object = {
     name: 'F1'
     tier: 'Free'
   }
   param location string = 'eastus'
   
   var appServicePlanName = '${environmentName}-${solutionName}-plan'
   var appServiceAppName = '${environmentName}-${solutionName}-app'
   

   Aqui você está criando vários parâmetros que usam diversos tipos. Você vai definir valores padrão para cada parâmetro. Alguns dos valores padrão incluem interpolação de cadeia de caracteres, a função uniqueString().

   Dica

   A função uniqueString() é útil para criar nomes de recursos globalmente exclusivos. Ela retorna uma cadeia de caracteres que é a mesma em cada implantação para o mesmo grupo de recursos, mas diferente quando você implanta em diferentes grupos de recursos ou assinaturas.

   Você também vai definir variáveis que constroem os nomes do plano do Serviço de Aplicativo do Azure e do aplicativo do Serviço de Aplicativo. Seus valores incluem alguns dos parâmetros que você especificou. Os valores de parâmetro podem ser substituídos pelo usuário que executa a implantação, mas os valores das variáveis não podem ser substituídos.

   Dica

   Você está especificando que o parâmetro location deve ser definido como westus3. Normalmente, você criaria recursos no mesmo local que o grupo de recursos usando a propriedade resourceGroup().location. Mas, ao trabalhar com a área restrita do Microsoft Learn, você precisa usar determinadas regiões do Azure que não correspondem ao local do grupo de recursos.

5. No arquivo main.bicep no Visual Studio Code, adicione o seguinte código ao final do arquivo:

   resource appServicePlan 'Microsoft.Web/serverfarms@2023-12-01' = {
     name: appServicePlanName
     location: location
     sku: {
       name: appServicePlanSku.name
       tier: appServicePlanSku.tier
       capacity: appServicePlanInstanceCount
     }
   }
   
   resource appServiceApp 'Microsoft.Web/sites@2023-12-01' = {
     name: appServiceAppName
     location: location
     properties: {
       serverFarmId: appServicePlan.id
       httpsOnly: true
     }
   }
   

   Observe que os recursos usam os valores dos parâmetros que você definiu.

6. Salve as alterações no arquivo.

Adicionar descrições de parâmetros

1. No arquivo main.bicep no Visual Studio Code, adicione o decorador @description diretamente acima de cada parâmetro que você criou na tarefa anterior. Os parâmetros devem semelhantes a este exemplo:

   @description('The name of the environment. This must be dev, test, or prod.')
   param environmentName string = 'dev'
   
   @description('The unique name of the solution. This is used to ensure that resource names are unique.')
   param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'
   
   @description('The number of App Service plan instances.')
   param appServicePlanInstanceCount int = 1
   
   @description('The name and tier of the App Service plan SKU.')
   param appServicePlanSku object = {
     name: 'F1'
     tier: 'Free'
   }
   
   @description('The Azure region into which the resources should be deployed.')
   param location string = 'eastus'
   

2. Salve as alterações no arquivo.

Limitar os valores de entrada

Sua empresa de brinquedos implantará o aplicativo de RH a três ambientes: dev, test e prod. Você limitará o parâmetro environmentName para permitir apenas esses três valores.

1. No arquivo main.bicep no Visual Studio Code, localize o parâmetro environmentName. Insira um decorador @allowed abaixo do decorador @description. Depois que você terminar, o parâmetro deverá ser semelhante a este exemplo:

   @description('The name of the environment. This must be dev, test, or prod.')
   @allowed([
     'dev'
     'test'
     'prod'
   ])
   param environmentName string = 'dev'
   

   Observe que você está limitando o valor do parâmetro environmentName somente para dev, test e prod. Se mais ambientes forem adicionados no futuro, você precisará atualizar essa lista.

2. Salve as alterações no arquivo.

Limitar comprimentos de entrada

O parâmetro solutionName é usado para gerar os nomes de recursos. Você deseja impor um comprimento mínimo de 5 caracteres e um comprimento máximo de 30 caracteres.

1. No arquivo main.bicep no Visual Studio Code, localize o parâmetro solutionName. Adicione os decoradores @minLength e @maxLength abaixo do decorador @description. Depois que você terminar, o parâmetro deverá ser semelhante a este exemplo:

   @description('The unique name of the solution. This is used to ensure that resource names are unique.')
   @minLength(5)
   @maxLength(30)
   param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'
   

2. Salve as alterações no arquivo.

Limitar valores numéricos

Em seguida, você garantirá que o parâmetro appServicePlanInstanceCount só permita valores entre 1 e 10.

1. No arquivo main.bicep no Visual Studio Code, localize o parâmetro appServicePlanInstanceCount. Adicione os decoradores @minValue e @maxValue abaixo do decorador @description. Depois que você terminar, o parâmetro deverá ser semelhante a este exemplo:

   @description('The number of App Service plan instances.')
   @minValue(1)
   @maxValue(10)
   param appServicePlanInstanceCount int = 1
   

2. Salve as alterações no arquivo.

Verificar o arquivo Bicep

Depois de concluir todas as alterações anteriores, o arquivo Bicep deverá ser semelhante a este exemplo:

@description('The name of the environment. This must be dev, test, or prod.')
@allowed([
  'dev'
  'test'
  'prod'
])
param environmentName string = 'dev'

@description('The unique name of the solution. This is used to ensure that resource names are unique.')
@minLength(5)
@maxLength(30)
param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'

@description('The number of App Service plan instances.')
@minValue(1)
@maxValue(10)
param appServicePlanInstanceCount int = 1

@description('The name and tier of the App Service plan SKU.')
param appServicePlanSku object = {
  name: 'F1'
  tier: 'Free'
}

@description('The Azure region into which the resources should be deployed.')
param location string = 'eastus'

var appServicePlanName = '${environmentName}-${solutionName}-plan'
var appServiceAppName = '${environmentName}-${solutionName}-app'

resource appServicePlan 'Microsoft.Web/serverfarms@2023-12-01' = {
  name: appServicePlanName
  location: location
  sku: {
    name: appServicePlanSku.name
    tier: appServicePlanSku.tier
    capacity: appServicePlanInstanceCount
  }
}

resource appServiceApp 'Microsoft.Web/sites@2023-12-01' = {
  name: appServiceAppName
  location: location
  properties: {
    serverFarmId: appServicePlan.id
    httpsOnly: true
  }
}

Caso contrário, copie-o ou ajuste o modelo para corresponder ao exemplo.

Implantar o modelo Bicep no Azure

az bicep install && az bicep upgrade

az configure --defaults group="<rgn>[sandbox resource group name]</rgn>"

az deployment group create --template-file main.bicep

Set-AzDefault -ResourceGroupName <rgn>[sandbox resource group name]</rgn>

New-AzResourceGroupDeployment -TemplateFile main.bicep

Verificar a implantação

1. Vá para o portal do Azure e verifique se você está na assinatura da área restrita:

   1. Selecione seu avatar no canto superior direito da página.
   2. Selecione Mudar diretório. Na lista, escolha o diretório Área restrita do Microsoft Learn.

2. No painel do lado esquerdo, selecione Grupos de recursos.

3. Selecione [nome do grupo de recursos de área restrita].

4. Na Visão Geral, você pode ver que a implantação foi bem-sucedida.

   

5. Selecione 1 Êxito para ver os detalhes da implantação.

   

6. Selecione a implantação chamada principal para ver quais recursos foram implantados e selecione Detalhes da implantação para expandi-la. Nesse caso, há um Plano do Serviço de Aplicativo e um aplicativo.

   

7. No menu à esquerda, selecione Entradas.

   

8. Observe que os parâmetros e os valores estão listados.

   

9. Deixe a página aberta no navegador. Você verificará as implantações novamente mais tarde.