Redefinição/recuperação bare-metal: permitir que os usuários criem mídia de recuperação

  • Artigo

A mídia de recuperação (recuperação bare-metal) ajuda a restaurar um dispositivo Windows para o estado de fábrica, mesmo que o usuário precise substituir o disco rígido ou apagar a unidade completamente.

O Windows usa os arquivos internos do Windows, incluindo atualizações recentes do Windows e do driver, além de personalizações incluídas no pacote de provisionamento OEM, para criar a mídia de recuperação.

Se você implantar o Windows usando o layout de partição padrão, os usuários poderão criar mídia de recuperação bare-metal por padrão.

Se você estiver implantando o Windows com um layout de partição personalizado, precisará adicionar alguns arquivos de configuração para permitir que os usuários criem mídia de recuperação bare-metal:

  • Um script de redefinição de partição, que é um script DiskPart modificado que redefine o layout de partição personalizado.
  • Um arquivo de configuração de redefinição de botão de ação (ResetConfig XML) que identifica as partições do Windows e Windows RE.

Observação

No Windows 10, versão 1607 e posterior, os aplicativos da área de trabalho e as configurações capturados em pacotes de provisionamento em silos não serão restaurados usando essa mídia. Os pacotes de personalizações regulares (.ppkg) capturados usando a ferramenta ScanState não são afetados por esse problema.

Criando arquivos de configuração

Script de redefinição de partição

  1. No Bloco de Notas, crie um arquivo de configuração que particione o disco rígido após a redefinição do disco rígido. Esse script deve ser o mesmo que o script usado para criar partições no disco rígido, com as seguintes exceções:

    • O script não deve conter comandos para selecionar ou limpo a unidade. O Windows identifica a unidade do sistema automaticamente. Para saber mais, confira Identificando a unidade do sistema mais adiante neste tópico.

    • O script deve atribuir letras à partição do sistema, à partição do Windows e à partição Windows RE ferramentas.

Observação

Ao usar um layout de partição personalizado, o tamanho da partição de ferramentas de Windows RE deve ter espaço livre suficiente para permitir um tamanho maior no futuro. O tamanho recomendado da partição de ferramentas de Windows RE é de 990 MB com um mínimo de 250 MB gratuitos.

Exemplos:

UEFI (com base em partições de disco rígido baseadas em UEFI/GPT):

rem == ResetPartitions-UEFI.txt ==
rem == These commands are used with DiskPart to
rem    reset the drive and recreate five partitions
rem    for a UEFI/GPT-based computer.
rem    Adjust the partition sizes to fill the drive
rem    as necessary. ==
rem == The differences between this file and
rem    CreatePartitions-UEFI.txt
rem    are noted in parenthesis.
rem       (NOT USED: select disk 0)
rem       (NOT USED: clean)
convert gpt
rem == 1. System partition =========================
create partition efi size=100
rem    ** NOTE: For Advanced Format 4Kn drives,
rem               change this value to size = 260 **
format quick fs=fat32 label="System"
assign letter="S"
rem == 2. Microsoft Reserved (MSR) partition =======
create partition msr size=128
rem == 3. Windows partition ========================
rem ==    a. Create the Windows partition ==========
create partition primary
rem ==    b. Create space for the recovery tools ===
shrink minimum=500
rem       ** Update this size to match the size of
rem          the recovery tools (winre.wim)
rem          plus some free space.
rem
rem ==    c. Prepare the Windows partition =========
format quick fs=ntfs label="Windows"
assign letter="W"
rem === 4. Recovery tools partition ================
create partition primary
format quick fs=ntfs label="Recovery tools"
assign letter="R"
set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac"
gpt attributes=0x8000000000000001
list volume

BIOS (com base em partições de disco rígido baseadas em BIOS/MBR):

rem == ResetPartitions-BIOS.txt ==
rem == These commands are used with DiskPart to
rem    reset the drive and create three partitions
rem    for a BIOS/MBR-based computer.
rem    Adjust the partition sizes to fill the drive
rem    as necessary. ==
rem == The differences between this file and
rem    CreatePartitions-BIOS.txt
rem    are noted in parenthesis.
rem       (NOT USED: select disk 0 )
rem       (NOT USED: clean )
rem == 1. System partition ======================
create partition primary size=100
format quick fs=ntfs label="System"
assign letter="S"
active
rem == 2. Windows partition =====================
rem ==    a. Create the Windows partition =======
create partition primary
rem ==    b. Create space for the recovery tools  
shrink minimum=500
rem       ** Update this size to match the size of
rem          the recovery tools (winre.wim)
rem          plus some free space.
rem ==    c. Prepare the Windows partition ======
format quick fs=ntfs label="Windows"
assign letter="W"
rem == 3. Recovery tools partition ==============
create partition primary
format quick fs=ntfs label="Recovery"
assign letter="R"
set id=27
list volume
  1. Salve o arquivo, por exemplo, E:\Recovery\RecoveryImage\ResetPartitions-UEFI.txt.

Arquivo de configuração de redefinição de botão de ação (ResetConfig.xml)

  1. No Bloco de Notas, crie um arquivo de configuração que aponte para o script de partição de redefinição de botão de ação.

    Para obter informações sobre como configurar esse arquivo, consulte Referência de XML ResetConfig.

UEFI:

    <?xml version="1.0" encoding="utf-8"?>
    <!-- ResetConfig.xml for UEFI -->
    <Reset>
        <!-- May be combined with custom scripts – insert Run Phase elements here -->
        <SystemDisk>
            <DiskpartScriptPath>ResetPartitions-UEFI.txt</DiskpartScriptPath>
            <MinSize>75000</MinSize>
            <WindowsREPartition>4</WindowsREPartition>
            <WindowsREPath>Recovery\WindowsRE</WindowsREPath>
            <OSPartition>3</OSPartition>
        </SystemDisk>
    </Reset>

BIOS:

    <?xml version="1.0" encoding="utf-8"?>
    <!-- ResetConfig.xml for BIOS -->
    <Reset>
        <!-- May be combined with custom scripts – insert Run Phase elements here -->
        <SystemDisk>
            <DiskpartScriptPath>ResetPartitions-BIOS.txt</DiskpartScriptPath>
            <MinSize>75000</MinSize>
            <WindowsREPartition>3</WindowsREPartition>
            <WindowsREPath>Recovery\WindowsRE</WindowsREPath>
            <OSPartition>2</OSPartition>
        </SystemDisk>
    </Reset>

  1. Salve o arquivo usando o formato de arquivo UTF-8:

    Clique em Arquivo e em Salvar como. Na caixa Codificação , selecione UTF-8 e salve esse arquivo como E:\Recovery\RecoveryImage\ResetConfig.xml.

Permitir que os usuários criem mídia

Os usuários podem usar essa opção para criar mídia de recuperação quando necessário.

Etapa 1: Adicionar os arquivos de configuração ao computador de destino

  1. No computador de destino, insira a unidade flash USB com os arquivos de configuração.

  2. Copie os arquivos de configuração para o computador de destino:

    Copy E:\Recovery\RecoveryImage\* R:\RecoveryImage\*

em que E é a letra da unidade flash USB e R é a letra da unidade da partição de imagem de recuperação.

Etapa 2: Testar se o Windows pode criar mídia de recuperação

  1. Reinicie o computador de destino e conclua a OOBE (Experiência Pronta para Uso).

  2. Clique em Iniciar, digite criar uma unidade de recuperação, selecione Criar uma unidade de recuperação e clique em Sim no prompt do UAC.

  3. Insira uma unidade flash USB.

  4. Selecione Copiar a partição de recuperação do computador para a unidade> de recuperaçãoAvançar>Próxima>Criação.

Etapa 3: Testar a mídia de recuperação

  1. Em um computador sem sistema operacional, insira a mídia de recuperação.
  2. Inicie o computador, pressione uma tecla para abrir os menus de inicialização do firmware e selecione o dispositivo de inicialização apropriado.
  3. Nos menus Ferramentas do Windows RE, selecione um layout de teclado, por exemplo, EUA.
  4. Clique em Solucionar> ProblemasRemover tudo>Avançar. Se for solicitado que você limpo a unidade, selecione Sim.
  5. Selecione Sim, reparticionar as unidades>Apenas remover meus arquivos>Redefinir.

Solução de problemas

  • Verifique se ResetConfig.xml está salvo como um arquivo UTF-8.
  • Verifique se o nome do arquivo listado no <elemento DiskpartScriptPath> do arquivo ResetConfig.xml corresponde ao nome do arquivo no script Diskpart.
  • Verifique se o script Diskpart não inclui comandos para selecionar a unidade ou limpo a unidade (select disk 0, clean).

Identificando a unidade do sistema

O Windows identifica a unidade do sistema usando os seguintes métodos:

Computadores baseados em BIOS: a unidade do sistema relatada pelo BIOS é usada.

Computadores baseados em UEFI: quando Windows RE é habilitado usando o comando , o reagentc /setreimage Windows grava o caminho de localização do adaptador e o GUID do disco do sistema em uma variável UEFI. Essa etapa só é executada quando as partições do sistema e do sistema operacional estão na unidade do sistema. A variável é atualizada, se necessário, quando Windows RE é desabilitada e habilitada novamente.

Se várias unidades locais forem detectadas, o Windows identificará a unidade do sistema pesquisando na ordem a seguir

  1. O Windows procura uma unidade com um GUID que corresponda ao valor armazenado no firmware.

  2. O Windows procura uma unidade com um caminho de local que corresponda ao valor armazenado no firmware.

  3. O Windows procura uma unidade com um ESP existente.

    Se várias unidades com ESP forem encontradas, o processo de recuperação não continuará.

  4. O Windows procura um disco não inicializado (bruto).

    Se vários discos não inicializados forem encontrados, o processo de recuperação não continuará.

Visão geral da restauração por botão de comando

Referência XML de ResetConfig

Redefinição/recuperação de bare-metal: criar mídia de recuperação ao implantar novos dispositivos

Partições de disco rígido baseadas em UEFI/GGT

Partições de disco rígido baseadas em BIOS/MBR