Exemplo de gatilho diário (scripts)

  • Artigo

Este exemplo de script mostra como criar uma tarefa que executa o Bloco de Notas às 8h todos os dias. A tarefa contém um gatilho diário que especifica um limite inicial para ativar o gatilho e especificar a hora do dia em que a tarefa é executada, um intervalo de gatilho para especificar que a tarefa é executada todos os dias e um limite final para desativar o gatilho. O exemplo também mostra como definir um padrão de repetição para o gatilho repetir a tarefa. A tarefa também contém uma ação executável que executa o Bloco de Notas.

O procedimento a seguir descreve como agendar uma tarefa para iniciar um executável às 8h todos os dias. (Essas etapas correspondem aos comentários de código incluídos no código de exemplo.)

Para agendar o Bloco de Notas para começar às 8h todos os dias

  1. Crie um objeto TaskService . Esse objeto permite que você crie a tarefa em uma pasta especificada.
  2. Obtenha uma pasta de tarefa e crie uma tarefa. Use o método TaskService.GetFolder para obter a pasta em que a tarefa é armazenada e o método TaskService.NewTask para criar o objeto TaskDefinition que representa a tarefa.
  3. Defina informações sobre a tarefa usando o objeto TaskDefinition . Use a propriedade TaskDefinition.Settings para definir as configurações que determinam como o serviço Agendador de Tarefas executa a tarefa e a propriedade TaskDefinition.RegistrationInfo para definir as informações que descrevem a tarefa.
  4. Crie um gatilho diário usando a propriedade TaskDefinition.Triggers . Essa propriedade fornece acesso ao objeto TriggerCollection usado para criar o gatilho. Use o método TriggerCollection.Create (especificando o tipo de gatilho que você deseja criar) para criar um gatilho diário. Ao criar o gatilho, defina o limite inicial para ativar o gatilho e especifique a hora do dia em que a tarefa é executada, o intervalo entre os dias e o limite final para desativar o gatilho. O exemplo a seguir mostra como definir um padrão de repetição para o gatilho repetir a tarefa.
  5. Crie uma ação para a tarefa a ser executada usando a propriedade TaskDefinition.Actions . Essa propriedade fornece acesso ao objeto ActionCollection usado para criar a ação. Use o método ActionCollection.Create para especificar o tipo de ação que você deseja criar. Este exemplo usa um objeto ExecAction , que representa uma ação que executa uma operação de linha de comando.
  6. Registre a tarefa usando o método TaskFolder.RegisterTaskDefinition . Para este exemplo, a tarefa iniciará o Bloco de Notas às 8h todos os dias.

O exemplo VBScript a seguir mostra como agendar uma tarefa para executar o Bloco de Notas todos os dias às 8h.

'------------------------------------------------------------------
' This sample schedules a task to start on a daily basis.
'------------------------------------------------------------------

' A constant that specifies a daily trigger.
const TriggerTypeDaily = 2
' A constant that specifies an executable action.
const ActionTypeExec = 0

'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")

' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 

'********************************************************
' Define information about the task.

' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Start notepad at 8:00AM daily"
regInfo.Author = "Administrator"

' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.Enabled = True
settings.StartWhenAvailable = True
settings.Hidden = False

'********************************************************
' Create a daily trigger. Note that the start boundary 
' specifies the time of day that the task starts and the 
' interval specifies what days the task is run.
Dim triggers
Set triggers = taskDefinition.Triggers

Dim trigger
Set trigger = triggers.Create(TriggerTypeDaily)

' Trigger variables that define when the trigger is active 
' and the time of day that the task is run. The format of 
' this time is YYYY-MM-DDTHH:MM:SS
Dim startTime, endTime

Dim time
startTime = "2006-05-02T08:00:00"  'Task runs at 8:00 AM
endTime = "2015-05-02T08:00:00"

WScript.Echo "startTime :" & startTime
WScript.Echo "endTime :" & endTime

trigger.StartBoundary = startTime
trigger.EndBoundary = endTime
trigger.DaysInterval = 1    'Task runs every day.
trigger.Id = "DailyTriggerId"
trigger.Enabled = True

' Set the task repetition pattern for the task.
' This will repeat the task 5 times.
Dim repetitionPattern
Set repetitionPattern = trigger.Repetition
repetitionPattern.Duration = "PT4M"
repetitionPattern.Interval = "PT1M"

'***********************************************************
' Create the action for the task to execute.

' Add an action to the task to run notepad.exe.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExec )
Action.Path = "C:\Windows\System32\notepad.exe"

WScript.Echo "Task definition created. About to submit the task..."

'***********************************************************
' Register (create) the task.

call rootFolder.RegisterTaskDefinition( _
    "Test Daily Trigger", taskDefinition, 6, , , 3)

WScript.Echo "Task submitted."

Usando o Agendador de Tarefas