Exemplo de gatilho de logon (script)

  • Artigo

Este exemplo de script mostra como criar uma tarefa agendada para executar o Bloco de Notas quando um usuário faz logon. A tarefa contém um gatilho de logon que especifica um limite inicial para a tarefa iniciar e um identificador de usuário que especifica o usuário. A tarefa é registrada usando o grupo Administradores como um contexto de segurança para executar a tarefa.

O procedimento a seguir descreve como agendar um executável, como o Bloco de Notas, para iniciar quando um usuário especificado fizer logon.

Para agendar o Bloco de Notas para iniciar quando um usuário fizer logon

  1. Crie um objeto TaskService . Esse objeto permite que você crie a tarefa em uma pasta especificada.
  2. Obtenha uma pasta de tarefas e crie uma tarefa. Use o método TaskService.GetFolder para obter a pasta em que a tarefa está armazenada e o método TaskService.NewTask para criar o objeto TaskDefinition que representa a tarefa.
  3. Defina informações sobre a tarefa usando o objeto TaskDefinition . Use a propriedade TaskDefinition.Settings para definir as configurações que determinam como o serviço Agendador de Tarefas executa a tarefa e a propriedade TaskDefinition.RegistrationInfo para definir as informações que descrevem a tarefa.
  4. Crie um gatilho de logon usando a propriedade TaskDefinition.Triggers . Essa propriedade fornece acesso ao objeto TriggerCollection . Use o método TriggerCollection.Create (especificando o tipo de gatilho que você deseja criar) para criar um gatilho de logon. Ao criar o gatilho, defina o limite inicial e o limite final do gatilho para ativar e desativar o gatilho. Você deve definir a propriedade UserId para o gatilho para que as ações da tarefa sejam agendadas para serem executadas quando o usuário especificado fizer logon após o limite de início.
  5. Crie uma ação para a tarefa a ser executada usando a propriedade TaskDefinition.Actions . Essa propriedade fornece acesso ao objeto ActionCollection . Use o método ActionCollection.Create para especificar o tipo de ação que você deseja criar. Este exemplo usa um objeto ExecAction , que representa uma ação que inicia um executável.
  6. Registre a tarefa usando o método TaskFolder.RegisterTaskDefinition . Este exemplo registra a tarefa para que ela use o grupo Administradores como um contexto de segurança para executar a tarefa.

O exemplo de VBScript a seguir mostra como agendar uma tarefa para executar o Bloco de Notas quando um usuário faz logon.

'---------------------------------------------------------
' This sample schedules a task to start notepad.exe when a user logs on.
'---------------------------------------------------------

' A constant that specifies a logon trigger.
const TriggerTypeLogon = 9
' A constant that specifies an executable action.
const ActionTypeExecutable = 0   

'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")

' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 

'********************************************************
' Define information about the task.

' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Task will execute Notepad when a " & _
    "specified user logs on."
regInfo.Author = "Author Name"

' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.StartWhenAvailable = True

'********************************************************
' Create a logon trigger.
Dim triggers
Set triggers = taskDefinition.Triggers

Dim trigger
Set trigger = triggers.Create(TriggerTypeLogon)

' Trigger variables that define when the trigger is active.
Dim startTime, endTime
startTime = "2006-05-02T10:49:02"
endTime = "2006-05-02T10:52:02"

WScript.Echo "startTime :" & startTime
WScript.Echo "endTime :" & endTime

trigger.StartBoundary = startTime
trigger.EndBoundary = endTime
trigger.ExecutionTimeLimit = "PT5M"    ' Five minutes
trigger.Id = "LogonTriggerId"
trigger.UserId = "DOMAIN\UserName"   ' Must be a valid user account   

'***********************************************************
' Create the action for the task to execute.

' Add an action to the task. The action executes notepad.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExecutable )
Action.Path = "C:\Windows\System32\notepad.exe"

WScript.Echo "Task definition created. About to submit the task..."

'***********************************************************
' Register (create) the task.
const createOrUpdateTask = 6
call rootFolder.RegisterTaskDefinition( _
    "Test Logon Trigger", taskDefinition, createOrUpdateTask, _
    "Builtin\Administrators", , 4)

WScript.Echo "Task submitted."

Usando o Agendador de Tarefas