Exemplo de gatilho de registro (script)

Este exemplo de script mostra como criar uma tarefa agendada para executar o Bloco de Notas quando uma tarefa é registrada. A tarefa contém um gatilho de registro que especifica um limite inicial e um limite final para a tarefa. O limite inicial especifica quando o gatilho é ativado. A tarefa também contém uma ação que especifica a tarefa para executar o Bloco de Notas.

O procedimento a seguir descreve como agendar um executável, como o Bloco de Notas, para iniciar quando uma tarefa é registrada.

Para agendar o Bloco de Notas para iniciar quando uma tarefa é registrada

1. Crie um objeto TaskService . Esse objeto permite que você crie a tarefa em uma pasta especificada.
2. Obtenha uma pasta de tarefas e crie uma tarefa. Use o método TaskService.GetFolder para obter a pasta em que a tarefa está armazenada e o método TaskService.NewTask para criar o objeto TaskDefinition que representa a tarefa.
3. Defina informações sobre a tarefa usando o objeto TaskDefinition . Use a propriedade TaskDefinition.Settings para definir as configurações que determinam como o serviço Agendador de Tarefas executa a tarefa e a propriedade TaskDefinition.RegistrationInfo para definir as informações que descrevem a tarefa.
4. Crie um gatilho de registro usando a propriedade TaskDefinition.Triggers . Essa propriedade fornece acesso ao objeto TriggerCollection . Use o método TriggerCollection.Create (especificando o tipo de gatilho que você deseja criar) para criar um gatilho de registro.
5. Crie uma ação para a tarefa a ser executada usando a propriedade TaskDefinition.Actions . Essa propriedade fornece acesso ao objeto ActionCollection . Use o método ActionCollection.Create para especificar o tipo de ação que você deseja criar. Este exemplo usa um objeto ExecAction , que representa uma ação que inicia um executável.
6. Registre a tarefa usando o método TaskFolder.RegisterTaskDefinition .

O exemplo de VBScript a seguir mostra como criar uma tarefa que agenda o Bloco de Notas a ser executada quando a tarefa é registrada.

'---------------------------------------------------------
' This sample schedules a task to start notepad.exe when
' the task is registered.
'---------------------------------------------------------

' A constant that specifies a registration trigger.
const TriggerTypeRegistration = 7
' A constant that specifies an executable action.
const ActionTypeExecutable = 0   


'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")

' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 

'********************************************************
' Define information about the task.

' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Start Notepad when the task is registered."
regInfo.Author = "Author Name"

' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.StartWhenAvailable = True

'********************************************************
' Create a registration trigger.
Dim triggers
Set triggers = taskDefinition.Triggers

Dim trigger
Set trigger = triggers.Create(TriggerTypeRegistration)

trigger.ExecutionTimeLimit = "PT5M"    'Five minutes
trigger.Id = "RegistrationTriggerId"   

'***********************************************************
' Create the action for the task to execute.

' Add an action to the task. The action executes Notepad.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExecutable )
Action.Path = "C:\Windows\System32\notepad.exe"

WScript.Echo "Task definition created. About to submit the task..."

'***********************************************************
' Register (create) the task.

call rootFolder.RegisterTaskDefinition( _
    "Test Registration Trigger", taskDefinition, 6, , , 3)

WScript.Echo "Task submitted."

Tópicos relacionados

Usando o Agendador de Tarefas