Visão geral do provedor Terraform AzAPI

O provedor AzAPI é uma camada fina sobre as APIs REST do Azure ARM. Ele permite que você gerencie qualquer tipo de recurso do Azure usando qualquer versão da API, permitindo que você utilize a funcionalidade mais recente no Azure. AzAPI é um provedor de primeira classe projetado para ser usado sozinho ou em conjunto com o provedor AzureRM.

Recursos

Para permitir que você gerencie todos os recursos e recursos do Azure sem exigir atualizações, o provedor AzAPI inclui os seguintes recursos genéricos:

Hierarquia de uso

No geral, o uso deve seguir estas etapas:

1. É sempre recomendável começar com a realização do maior número possível de operações dentro azapi_resourcedo .
2. Se o tipo de recurso não existir azapi_resource , mas se enquadrar em um dos tipos suportados pelo azapi_data_plane_resource, use-o.
3. Se o recurso já existir no AzureRM ou tiver uma propriedade que não pode ser acessada no azapi_resource, use azapi_update_resource para acessar essas propriedades específicas. Os recursos que azapi_resource não suportam ou azapi_data_plane_resource não podem ser atualizados através deste recurso.
4. Se você estiver tentando executar uma ação que não se baseia em um recurso compatível com CRUD do Azure, é menos simplesazapi_update_resource, azapi_resource_action mas mais flexível.

Exemplos de configuração de recursos

O trecho de código a seguir configura um recurso que não existe atualmente no provedor AzureRM:

resource "azapi_resource" "publicip" {
  type      = "Microsoft.Network/Customipprefixes@2021-03-01"
  name      = "exfullrange"
  parent_id = azurerm_resource_group.example.id
  location  = "westus2"

  body = {
    properties = {
      cidr          = "10.0.0.0/24"
      signedMessage = "Sample Message for WAN"
    }
  }
}

O trecho de código a seguir configura uma propriedade de visualização para um recurso existente do AzureRM:

resource "azapi_update_resource" "test" {
  type        = "Microsoft.ContainerRegistry/registries@2020-11-01-preview"
  resource_id = azurerm_container_registry.acr.id

  body = {
    properties = {
      anonymousPullEnabled = var.bool_anonymous_pull
    }
  }
}

O trecho de código a seguir configura uma ação de recurso em um recurso existente do AzureRM:

resource "azapi_resource_action" "vm_shutdown" {
  type = "Microsoft.Compute/virtualMachines@2023-07-01"
  resource_id = azurerm_linux_virtual_machine.example.id
  action = "powerOff”
}

O trecho de código a seguir configura um recurso que não existe atualmente no provedor AzureRM devido a ser provisionado no plano de dados:

resource "azapi_data_plane_resource" "dataset" {
  type      = "Microsoft.Synapse/workspaces/datasets@2020-12-01"
  parent_id = trimprefix(data.azurerm_synapse_workspace.example.connectivity_endpoints.dev, "https://")
  name      = "example-dataset"
  body = {
    properties = {
      type = "AzureBlob",
      typeProperties = {
        folderPath = {
          value = "@dataset().MyFolderPath"
          type  = "Expression"
        }
        fileName = {
          value = "@dataset().MyFileName"
          type  = "Expression"
        }
        format = {
          type = "TextFormat"
        }
      }
      parameters = {
        MyFolderPath = {
          type = "String"
        }
        MyFileName = {
          type = "String"
        }
      }
    }
  }
}

Autenticação usando o provedor AzAPI

O provedor AzAPI habilita os mesmos métodos de autenticação que o provedor AzureRM. Para obter mais informações sobre opções de autenticação, consulte Autenticar Terraform no Azure.

Benefícios de usar o provedor AzAPI

O provedor AzAPI apresenta os seguintes benefícios:

• Suporta todos os serviços de plano de controlo do Azure:
  • Pré-visualizar serviços e funcionalidades
  • Todas as versões da API
• Fidelidade total do arquivo de estado Terraform
  • As propriedades e os valores são salvos no estado
• Sem dependência do Swagger
• Autenticação comum e consistente do Azure
• Extensão robusta do VS Code

Experiência e ciclo de vida do fornecedor AzAPI

Esta seção descreve algumas ferramentas para ajudá-lo a usar o provedor AzAPI.

Extensão VS Code e Language Server

A extensão AzAPI VS Code fornece uma rica experiência de criação com os seguintes benefícios:

• Liste todos os tipos de recursos e versões de API disponíveis.
• Preenchimento automático das propriedades e valores permitidos para qualquer recurso.
• Mostrar dicas ao passar o mouse sobre um estabelecimento.
• Validação de sintaxe
• Preenchimento automático com exemplos de código.

Ferramenta de migração AzAPI2AzureRM

O provedor AzureRM fornece a experiência Terraform mais integrada para gerenciar recursos do Azure. Portanto, o uso recomendado dos provedores AzAPI e AzureRM é o seguinte:

1. Enquanto o serviço ou recurso estiver em visualização, use o provedor AzAPI.
2. assim que o serviço for lançado oficialmente, use o provedor AzureRM.

A ferramenta AzAPI2AzureRM foi projetada para ajudar a migrar do provedor AzAPI para o provedor AzureRM.

AzAPI2AzureRM é uma ferramenta de código aberto que automatiza o processo de conversão de recursos AzAPI em recursos AzureRM.

AzAPI2AzureRM tem dois modos: planejar e migrar:

• Plan exibe os recursos AzAPI que podem ser migrados.
• Migrar migra os recursos AzAPI para recursos do AzureRM nos arquivos HCL e no estado.

AzAPI2AzureRM garante após a migração que sua configuração e estado Terraform estejam alinhados com seu estado real. Você pode validar a atualização para o estado executando terraform plan depois de concluir a migração para ver que nada mudou.

Usando o provedor AzAPI

1. Instalar a extensão VS Code

2. Adicione o provedor AzAPI à sua configuração do Terraform.

   terraform {
     required_providers {
       azapi = {
         source  = "Azure/azapi"
       }
     }
   }
   
   provider "azapi" {
     # More information on the authentication methods supported by
     # the AzureRM Provider can be found here:
     # https://registry.terraform.io/providers/hashicorp/azurerm/latest/docs
   
     # subscription_id = "..."
     # client_id       = "..."
     # client_secret   = "..."
     # tenant_id       = "..."
   }
   

3. Declare um ou mais recursos AzAPI, conforme mostrado no código de exemplo a seguir:

   resource "azapi_resource" "example" {
     name = "example"
     parent_id = data.azurerm_machine_learning_workspace.existing.id
     type = "Microsoft.MachineLearningServices/workspaces/computes@2021-07-01"
   
     location = "eastus"
     body = {
       properties = {
         computeType      = "ComputeInstance"
         disableLocalAuth = true
         properties = {
           vmSize = "STANDARD_NC6"
         }
       }
     }
   }
   
   

Próximos passos

• Implante seu primeiro recurso com o provedor AzAPI
• Implante seu primeiro recurso de atualização com o provedor AzAPI
• Implante sua primeira ação de recurso com o provedor AzAPI