Adicionar uma medida de tempo no estado ao seu relatório do Power BI

Azure DevOps Services | Azure DevOps Server 2022 - Azure DevOps Server 2019

O tempo que um item de trabalho passa em um estado específico do fluxo de trabalho ou em uma série de estados é um aspeto importante para entender a eficiência. Os widgets Cycle Time e Lead Time Analytics fornecem algumas medidas de time-in-state. No entanto, esses widgets podem não ter o nível de detalhe desejado.

Este artigo fornece receitas usando DAX (Data Analysis Expressions) para avaliar o tempo gasto por itens de trabalho em uma combinação de estados. Especificamente, você aprende a adicionar as seguintes colunas calculadas e de medida aos seus relatórios do Power BI e usá-las para gerar vários gráficos de tendência. Todos os campos são colunas calculadas, exceto o primeiro listado.

Pré-requisitos

• Acesso: Ser membro de um projeto com pelo menos acesso Básico .
• Permissões: por predefinição, os membros do projeto têm permissão para consultar o Analytics e criar vistas.
• Para obter mais informações sobre outros pré-requisitos relacionados com a ativação de serviços e funcionalidades e atividades gerais de monitorização de dados, consulte Permissões e pré-requisitos para aceder ao Analytics.

Adicionar uma medida de Contagem de Itens de Trabalho

Para simplificar a geração rápida de relatórios, projetamos modos de exibição do Google Analytics para trabalhar com agregações padrão no Power BI. Para ilustrar a diferença entre uma agregação padrão e uma medida, começamos com uma medida simples de contagem de itens de trabalho.

1. Carregue a vista do Google Analytics no Power BI Desktop. Para obter detalhes, consulte Conectar-se com o Power BI Data Connector, Conectar-se a um modo de exibição do Google Analytics.

2. Selecione a tabela de dados e, na guia Ferramentas de tabela, seção Cálculos da faixa de opções, escolha Nova medida.

   

3. Substitua o texto padrão pelo código a seguir e selecione a marca de seleção.

   Work Items Count=CALCULATE(COUNTROWS ('View Name'),LASTDATE ('View Name'[Date]))
   

   A medida de contagem de itens de trabalho usa as CALCULATEfunções , COUNTROWSe LASTDATE DAX que são descritas com mais detalhes posteriormente neste artigo.

   Nota

   Lembre-se de substituir View Name pelo nome da tabela para a visualização do Google Analytics. Por exemplo, aqui substituímos View Name por Ative bugs.

   

Qual é a diferença entre uma medida e uma coluna calculada

Uma medida sempre avalia a tabela inteira onde uma coluna calculada é específica para uma única linha. Para obter mais informações, consulte Colunas calculadas e medidas no DAX.

Compare a medida de Contagem de Itens de Trabalho com a agregação de contagem padrão com base na ID do Item de Trabalho. A imagem a seguir é criada adicionando o visual do cartão e a medida de contagem de itens de trabalho ao primeiro cartão e a propriedade ID do item de trabalho ao segundo cartão.

Para obter a contagem correta usando uma agregação padrão, aplique o filtro É atual é igual a 'Verdadeiro'. Esse padrão de aplicação de filtros a uma agregação padrão é a base para muitos dos exemplos fornecidos neste artigo.

Adicionar ordem de classificação de estado

Por padrão, o Power BI mostra estados classificados alfabeticamente em uma visualização. Pode ser enganoso quando você deseja visualizar o tempo no estado e Proposto aparece depois de Em andamento. As etapas a seguir ajudam a resolver esse problema.

1. Verifique se o campo Categoria do Estado está incluído na visualização Análise. Este campo está incluído em todas as vistas partilhadas predefinidas.

2. Selecione a tabela de dados e, na guia Ferramentas de tabela, seção Cálculos da faixa de opções, escolha Nova coluna.

   

3. Substitua o texto padrão pelo código a seguir e selecione a marca de seleção.

   State Sort Order =  
   SWITCH (  
       'View Name'[State Category],  
       "Proposed", 1,  
       "InProgress", 2,  
       "Resolved", 3,  
       4  
   )  
   

   Veja o seguinte exemplo:

   

   Nota

   Talvez seja necessário revisar a definição se precisar de mais granularidade do que a Categoria de Estado fornece. Categoria de Estado fornece classificação correta em todos os tipos de item de trabalho, independentemente de quaisquer personalizações de Estado .

4. Abra a visualização Dados e selecione a coluna Estado .

5. Na guia Ferramentas de Coluna, escolha Classificar por Coluna e selecione o campo Ordem de Classificação de Estado.

   

Adicionar Data Anterior

A próxima etapa para calcular o tempo no estado requer o mapeamento do intervalo anterior (dia, semana, mês) para cada linha de dados no conjunto de dados. É um cálculo simples usando uma coluna calculada. Normalmente, você definiria essa coluna como mostrada.

Date Previous  = 
PREVIOUSDAY ( 'View Name'[Date] )

No entanto, esta abordagem tem dois problemas principais:

• Funciona apenas por períodos diários.
• Ele não lida com lacunas nos dados. Por exemplo, se um item de trabalho é movido entre projetos.

Para resolver esses problemas, a coluna calculada deve encontrar o dia anterior verificando o campo Data .

Para adicionar a coluna calculada Data Anterior , na guia Ferramentas de tabela, escolha Nova Coluna e, em seguida, substitua o texto padrão pelo código a seguir e selecione a marca de seleção.

Date Previous =
CALCULATE (
    MAX ( 'View Name'[Date] ),
        ALLEXCEPT ( 'View Name', 'View Name'[Work Item Id] ),
        'View Name'[Date] < EARLIER ( 'View Name'[Date] )
)

A coluna calculada Data anterior usa três funções DAX, MAX, ALLEXCEPT, e , descritas com mais detalhes mais adiante EARLIERneste artigo. Como a coluna é calculada, ela é executada para cada linha da tabela e, cada vez que é executada, ela tem o contexto dessa linha específica.

Adicionar diferença de data em dias

Data Anterior calcula a diferença entre a data anterior e a data atual para cada linha. Com Data Diff em Dias, calculamos uma contagem de dias entre cada um desses períodos. Para a maioria das linhas em um instantâneo diário, o valor é igual a 1. No entanto, para muitos itens de trabalho que têm lacunas no conjunto de dados, o valor é maior que 1.

É importante considerar o primeiro dia do conjunto de dados em que Data Anterior está em branco. Neste exemplo, damos a essa linha um valor padrão de 1 para manter o cálculo consistente.

Na guia Modelagem, escolha Nova Coluna e, em seguida, substitua o texto padrão pelo código a seguir e selecione a marca de seleção.

Date Diff in Days =
IF (
    ISBLANK ( 'View Name'[Date Previous] ),
    1,
    DATEDIFF (
        'View Name'[Date Previous],
        'View Name'[Date],
        DAY
    )
)

Esta coluna calculada usa as ISBLANK funções e DATEDIFF DAX descritas posteriormente neste artigo.

Adicionar é o último dia no estado

Nesta próxima etapa, calculamos se uma determinada linha representa o último dia em que um item de trabalho específico esteve em um estado. Ele dá suporte a agregações padrão no Power BI que adicionamos na próxima seção onde adicionamos a coluna Tempo de Estado em Dias .

Na guia Modelagem, escolha Nova Coluna e, em seguida, substitua o texto padrão pelo código a seguir e selecione a marca de seleção.

Is Last Day in State = 
ISBLANK (CALCULATE (
    COUNTROWS ( 'View Name' ),
        ALLEXCEPT ( 'View Name', 'View Name'[Work Item Id] ),
        'View Name'[Date] > EARLIER ( 'View Name'[Date] ),
        'View Name'[State] = EARLIER ( 'View Name'[State] )
))

Adicionar Hora do Estado em Dias

O tempo que um item de trabalho passou em um estado específico agora pode ser calculado somando a Comparação de Data em Dias para cada item de trabalho. Esse cálculo inclui todo o tempo gasto em um estado específico, mesmo que ele tenha alternado entre estados várias vezes. É possível avaliar cada linha como uma tendência usando Data ou as informações mais recentes usando É o último dia no estado.

Na guia Modelagem, escolha Nova Coluna e, em seguida, substitua o texto padrão pelo código a seguir e selecione a marca de seleção.

State Time in Days = 
CALCULATE (
    SUM ( 'View Name'[Date Diff in Days] ),
    ALLEXCEPT ( 'View Name', 'View Name'[Work Item Id] ),
    'View Name'[Date] <= EARLIER ( 'View Name'[Date] ),
    'View Name'[State] = EARLIER ( 'View Name'[State] )
) + 0

Crie gráficos de tendência de colunas empilhadas com base na Hora do Estado em Dias

Para demonstrar a coluna Tempo de Estado em Dias , os seguintes gráficos de colunas empilhadas são criados. O primeiro gráfico mostra a contagem de itens de trabalho em cada estado ao longo do tempo.

O segundo gráfico ilustra a tendência da média de dias em que os itens de trabalho ativos estão em um determinado estado.

Adicionar Hora do Estado em Dias - Mais Recente (É o Último Dia no Estado)

Ao avaliar o tempo no estado para cada item de trabalho em uma tabela ou quando filtrado por um campo como Caminho de Área, não use a coluna Tempo de Estado em Dias em uma agregação. A agregação usa o valor para cada dia em que o item de trabalho estava no estado. Por exemplo, se um item de trabalho estava em andamento na segunda-feira e movido para Concluído na quinta-feira, o tempo no estado é de três dias, mas a soma da coluna Hora do Estado em dias é de seis dias, 1+2+3o que está incorreto.

Para resolver esse problema, use Hora de Estado em Dias e aplique o filtro É Último Dia no Estado é igual a 'Verdadeiro'. Ele elimina todos os dados históricos necessários para uma tendência e se concentra apenas no valor mais recente para cada estado.

Adicionar Hora do Estado em Dias - Em Progresso

Nos exemplos anteriores, o Tempo de Estado em Dias para um determinado item de trabalho só é contado quando o item de trabalho estava nesse estado específico. Se o seu objetivo é fazer com que o tempo no estado de um determinado item de trabalho conte para uma média continuamente, você deve alterar o cálculo. Por exemplo, se quisermos acompanhar o estado "Em andamento", adicionamos a coluna calculada Tempo do Estado em Dias - Em Andamento .

Na guia Modelagem, escolha Nova Coluna e, em seguida, substitua o texto padrão pelo código a seguir e selecione a marca de seleção.

State Time in Days - In Progress = 
CALCULATE (
    SUM ( 'View Name'[Date Diff in Days] ),
    ALLEXCEPT ( 'View Name', 'View Name'[Work Item Id] ),
   'View Name'[Date] <= EARLIER('View Name'[Date]),
   'View Name'[State] = "In Progress"
) + 0

A imagem a seguir mostra o efeito de considerar todo o tempo no estado para cada item de trabalho existente (mostrado à esquerda) versus apenas os itens de trabalho em um estado específico em um determinado dia (mostrado à direita).

Tendência de tempo de estado em dias de vários estados

Analisar o desempenho em vários estados também é possível usando o padrão "Contínuo". No entanto, essa abordagem só funciona com um gráfico de tendência.

Na guia Modelagem, escolha Nova Coluna e, em seguida, substitua o texto padrão pelo código a seguir e selecione a marca de seleção.

State Time in Days - Working States = 
CALCULATE (
    SUM ( 'View Name'[Date Diff in Days] ),
    ALLEXCEPT ( 'View Name', 'View Name'[Work Item Id] ),
   'View Name'[Date] <= EARLIER('View Name'[Date]),
   'View Name'[State] IN { "Committed", "In Progress" }
) + 0

O gráfico da esquerda mostra a média combinada, enquanto o lado direito mostra cada estado individual.

Obtenha a hora do estado em dias - mais recente para vários estados

Use a coluna Tempo de Estado em Dias - Último calculado ao criar uma tendência. Com um filtro sobre os estados, a coluna Hora do Estado em Dias e É o Último Dia no Estado fornece uma maneira simples de obter o tempo total que qualquer item de trabalho ou grupo de itens de trabalho gasto em um conjunto de estados.

Adicionar Estado Anterior

A coluna Data Anterior calculada também pode ser usada para pesquisar valores passados, como o estado anterior, para cada item de trabalho.

Na guia Modelagem, escolha Nova Coluna e, em seguida, substitua o texto padrão pelo código a seguir e selecione a marca de seleção.

State Previous =
LOOKUPVALUE (
    'View Name'[State],
    'View Name'[Work Item Id], 'View Name'[Work Item Id],
    'View Name'[Date], 'View Name'[Date Previous]
)

Esta coluna calculada usa o LOOKUPVALUE, descrito mais adiante neste artigo.

O primeiro LOOKUPVALUE parâmetro, 'View Name'[State], especifica para retornar o valor de [State].

O próximo parâmetro, 'View Name'[Work Item Id], 'View Name'[Work Item Id], especifica que apenas as linhas com um ID de item de trabalho correspondente como a linha atual devem ser consideradas.

E, o último parâmetro, 'View Name'[Date], 'View Name'[Date Previous], especifica que a data da linha que está sendo retornada deve ter uma [Data] que corresponda à [Data Anterior] da linha atual. Em um instantâneo, apenas uma linha pode atender a esse critério.

Adicionar estado alterado

Usando a coluna Estado Anterior , podemos sinalizar as linhas para cada item de trabalho onde ocorreu uma transição de estado. A coluna calculada Estágio alterado tem duas considerações especiais:

• Valores em branco de *State Previous, que definimos como a Data de Criação do item de trabalho
• A criação de um item de trabalho é considerada uma transição de estado

Na guia Modelagem, escolha Nova Coluna e, em seguida, substitua o texto padrão pelo código a seguir e selecione a marca de seleção.

State Changed =
IF (
    ISBLANK ( 'View Name'[State Previous] ),
    'View Name'[Created Date].[Date] = 'View Name'[Date],
    'View Name'[State Previous] <> 'View Name'[State]
)

A coluna calculada é um valor booleano que identifica se a linha é uma transição de estado. Usando o Not Equal To operador, você captura corretamente as linhas em que o estado anterior não corresponde ao estado atual, o que significa que a comparação retorna True conforme o esperado.

Adicionar fluxo de estado

Com as colunas calculadas Estado Anterior e Estado Alterado, você pode criar uma coluna que ilustre o Fluxo de Estado para um determinado item de trabalho. A criação desta coluna é opcional para os fins deste artigo.

Na guia Modelagem, escolha Nova Coluna e, em seguida, substitua o texto padrão pelo código a seguir e selecione a marca de seleção.

State Flow = 
IF([State Changed], [State Previous], [State]) & " => " & [State]

Adicionar contagem de alterações de estado

À medida que avançamos para as medidas mais complicadas, precisamos ter uma representação do número total de alterações de estado para comparar as linhas de um dado para um determinado item de trabalho. Obtemos a representação adicionando uma coluna calculada de Contagem de Alterações de Estado.

Na guia Modelagem, escolha Nova Coluna e, em seguida, substitua o texto padrão pelo código a seguir e selecione a marca de seleção.

State Change Count = 
CALCULATE (
    COUNTROWS ( 'View Name' ),
    ALLEXCEPT ( 'View Name', 'View Name'[Work Item Id] ),
    'View Name'[Date] <= EARLIER ( 'View Name'[Date] ),
    'View Name'[State Changed]
) + 0

Adicionar contagem de alterações de estado - última proposta e tempo de reinicialização do estado em dias

O Tempo de Reinicialização do Estado em Dias é um cálculo bastante complexo. O primeiro passo é encontrar a última vez que um item de trabalho esteve em um estado proposto. Adicione a coluna Contagem de Alteração de Estado - Última Proposta calculada.

Na guia Modelagem, escolha Nova coluna e, em seguida, substitua o texto padrão pelo código a seguir e selecione a marca de seleção.

State Change Count - Last Proposed = 
CALCULATE (
    MAX ( 'View Name'[State Change Count] ),
    ALLEXCEPT ( 'View Name', 'View Name'[Work Item Id] ),
    'View Name'[Date] <= EARLIER ( 'View Name'[Date] ),
    'View Name'[State] = "Proposed"
)

Então, olhe mais para o passado e veja se havia alguns estados ativos antes desse estado proposto. Por fim, resuma todos os dias em que o item de trabalho estava em estado ativo antes da última proposta.

Na guia Modelagem, escolha Nova Coluna e, em seguida, substitua o texto padrão pelo código a seguir e selecione a marca de seleção.

State Restart Time in Days = 
CALCULATE (
    SUM ( 'View Name'[Date Diff in Days] ),
    ALLEXCEPT ( 'View Name', 'View Name'[Work Item Id] ),
    'View Name'[Date] <= EARLIER ( 'View Name'[Date] ),
    'View Name'[State Change Count] < EARLIER('View Name'[State Change Count - Last Proposed] ),
    'View Name'[State] <"Proposed"
) + 0

Como o Tempo de Reinicialização de Estado em Dias é atualizado para cada linha de dados, você pode criar uma tendência para avaliar o retrabalho em sprints específicos ou examinar o retrabalho para itens de trabalho individuais usando É Atual.

Adicionar tempo de retrabalho de estado em dias

Semelhante ao Tempo de Reinicialização do Estado em Dias, o Tempo de Retrabalho do Estado em Dias procura pela primeira vez que um item de trabalho estava na categoria Estado Concluído. Após esse tempo, cada dia que um item de trabalho passa em um estado diferente de Concluído, conta como retrabalho.

1. Crie a coluna "Contagem de alterações de estado - primeira concluída". Esta coluna controla o número de vezes que um item de trabalho transita para o estado Concluído a partir de qualquer outro estado.

   State Change Count - First Completed =
   VAR CompletedState = "Completed"
   RETURN
   CALCULATE(
      COUNTROWS('YourTable'),
      FILTER(
          'YourTable',
          'YourTable'[State] = CompletedState
          && 'YourTable'[State Change Date] = MIN('YourTable'[State Change Date])
      )
   )
   

2. Na guia Modelagem, escolha Nova Coluna e, em seguida, substitua o texto padrão pelo código a seguir e selecione a marca de seleção.

   State Rework Time in Days = 
   IF (
       ISBLANK ( 'View Name'[State Change Count - First Completed] ),
       0,
       CALCULATE (
           SUM ( 'View Name'[Date Diff in Days] ),
           ALLEXCEPT ( 'View Name', 'View Name'[Work Item Id] ),
           'View Name'[Date] <= EARLIER ( 'View Name'[Date] ),
           'View Name'[State Change Count] <= EARLIER ( 'View Name'[State Change Count - First Completed] ),
           'View Name'[State] IN {"Completed", "Closed", "Cut" } = FALSE()
       ) + 0
   )
   

   Nota

   Talvez seja necessário revisar a definição anterior com base nos estados do fluxo de trabalho usados pelo seu projeto. Por exemplo, se o seu projeto usa Concluído no lugar de Fechado e assim por diante.

Funções DAX

Informações adicionais são fornecidas nesta seção para as funções DAX usadas para criar as colunas calculadas e a medida adicionada neste artigo. Consulte também DAX, Funções de inteligência de tempo.

Artigos relacionados

• Obter informações sobre a integração do Power BI
• Criar visualizações do Google Analytics
• Introdução ao Power BI Desktop
• Projetar conjuntos de dados para o Power BI Connector
• Compreender os estados e as categorias de estado do fluxo de trabalho
• Explore o modelo de dados para o Google Analytics