Guia de início rápido: implantar a Pesquisa de IA do Azure usando o Bicep

  • Artigo

Este artigo orienta você pelo processo de uso de um arquivo Bicep para implantar um recurso de Pesquisa de IA do Azure no portal do Azure.

O Bicep é uma linguagem específica do domínio que utiliza sintaxe declarativa para implementar recursos do Azure. Fornece sintaxe concisa, segurança de tipos fiável e suporte para reutilização de código. O Bicep oferece a melhor experiência de criação para suas soluções de infraestrutura como código no Azure.

Somente as propriedades incluídas no modelo são usadas na implantação. Se for necessária mais personalização, como configurar a segurança da rede, você poderá atualizar o serviço como uma tarefa pós-implantação. Para personalizar um serviço existente com o menor número de etapas, use a CLI do Azure ou o Azure PowerShell. Se você estiver avaliando recursos de visualização, use a API REST de gerenciamento.

Gorjeta

Para obter um modelo Bicep alternativo que implanta o Azure AI Search com um indexador pré-configurado no Cosmos DB para NoSQL, consulte Implantação do Bicep do Azure AI Search. Não há suporte de modelo bicep para operações de plano de dados do Azure AI Search, como a criação de um índice, mas você pode adicionar um módulo que chama APIs REST. O exemplo inclui um módulo que cria um índice, conector de fonte de dados e um indexador que atualiza do Cosmos DB em intervalos de 5 minutos.

Pré-requisitos

Se não tiver uma subscrição do Azure, crie uma conta gratuita antes de começar.

Revise o arquivo Bicep

O arquivo Bicep usado neste início rápido é de Modelos de Início Rápido do Azure.

@description('Service name must only contain lowercase letters, digits or dashes, cannot use dash as the first two or last one characters, cannot contain consecutive dashes, and is limited between 2 and 60 characters in length.')
@minLength(2)
@maxLength(60)
param name string

@allowed([
  'free'
  'basic'
  'standard'
  'standard2'
  'standard3'
  'storage_optimized_l1'
  'storage_optimized_l2'
])
@description('The pricing tier of the search service you want to create (for example, basic or standard).')
param sku string = 'standard'

@description('Replicas distribute search workloads across the service. You need at least two replicas to support high availability of query workloads (not applicable to the free tier).')
@minValue(1)
@maxValue(12)
param replicaCount int = 1

@description('Partitions allow for scaling of document count as well as faster indexing by sharding your index over multiple search units.')
@allowed([
  1
  2
  3
  4
  6
  12
])
param partitionCount int = 1

@description('Applicable only for SKUs set to standard3. You can set this property to enable a single, high density partition that allows up to 1000 indexes, which is much higher than the maximum indexes allowed for any other SKU.')
@allowed([
  'default'
  'highDensity'
])
param hostingMode string = 'default'

@description('Location for all resources.')
param location string = resourceGroup().location

resource search 'Microsoft.Search/searchServices@2020-08-01' = {
  name: name
  location: location
  sku: {
    name: sku
  }
  properties: {
    replicaCount: replicaCount
    partitionCount: partitionCount
    hostingMode: hostingMode
  }
}

O recurso do Azure definido neste arquivo Bicep:

Implantar o arquivo Bicep

  1. Salve o arquivo Bicep como main.bicep em seu computador local.

  2. Implante o arquivo Bicep usando a CLI do Azure ou o Azure PowerShell.

    az group create --name exampleRG --location eastus
az deployment group create --resource-group exampleRG --template-file main.bicep --parameters serviceName=<service-name>

    Nota

    Substitua <service-name> pelo nome do serviço de Pesquisa. O nome do serviço deve conter apenas letras minúsculas, dígitos ou traços. Você não pode usar um traço como os dois primeiros caracteres ou o último caractere. O nome tem um comprimento mínimo de 2 caracteres e um comprimento máximo de 60 caracteres.

    Quando a implantação terminar, você verá uma mensagem indicando que a implantação foi bem-sucedida.

Rever os recursos implementados

Use o portal do Azure, a CLI do Azure ou o Azure PowerShell para listar os recursos implantados no grupo de recursos.

az resource list --resource-group exampleRG

Clean up resources (Limpar recursos)

O Azure AI Search é um recurso faturável. Se já não for necessário, elimine-o da sua subscrição para evitar cobranças. Você pode usar o portal do Azure, a CLI do Azure ou o Azure PowerShell para excluir o grupo de recursos e seus recursos.

az group delete --name exampleRG

Próximos passos

Neste início rápido, você criou um serviço Azure AI Search usando um arquivo Bicep e, em seguida, validou a implantação. Para saber mais sobre o Azure AI Search e o Azure Resource Manager, continue nos artigos.