Exemplo de consultas do Azure Resource Graph para acessar dados de operações do Azure Update Manager

  • Artigo

A seguir estão algumas consultas de exemplo para ajudá-lo a começar a consultar as informações de atualização, avaliação e implantação coletadas de suas máquinas gerenciadas. Para obter mais informações sobre logs criados a partir de operações como avaliações de atualização e instalações, consulte Visão geral dos logs de consulta.

Listar atualizações disponíveis para todas as suas máquinas agrupadas por categoria de atualização

A consulta a seguir retorna uma lista de atualizações pendentes para sua máquina com o tempo em que a avaliação foi realizada, o ID do recurso para a avaliação, o tipo de sistema operacional na máquina e as atualizações do sistema operacional disponíveis com base na classificação de atualização.

patchassessmentresources
| where type !has "softwarepatches"
| extend prop = parse_json(properties)
| extend lastTime = properties.lastModifiedDateTime
| extend updateRollupCount = prop.availablePatchCountByClassification.updateRollup, featurePackCount = prop.availablePatchCountByClassification.featurePack, servicePackCount = prop.availablePatchCountByClassification.servicePack, definitionCount = prop.availablePatchCountByClassification.definition, securityCount = prop.availablePatchCountByClassification.security, criticalCount = prop.availablePatchCountByClassification.critical, updatesCount = prop.availablePatchCountByClassification.updates, toolsCount = prop.availablePatchCountByClassification.tools, otherCount = prop.availablePatchCountByClassification.other, OS = prop.osType
| project lastTime, id, OS, updateRollupCount, featurePackCount, servicePackCount, definitionCount, securityCount, criticalCount, updatesCount, toolsCount, otherCount

Contagem de instalações de atualização

A consulta a seguir retorna uma lista de instalações de atualização com seu status para suas máquinas dos últimos sete dias. Os resultados incluem a hora em que a implantação da atualização foi executada, o ID do recurso da instalação, os detalhes da máquina e a contagem de atualizações do sistema operacional instaladas com base em seu status e sua seleção.

patchinstallationresources
| where type !has "softwarepatches"
| extend machineName = tostring(split(id, "/", 8)), resourceType = tostring(split(type, "/", 0)), tostring(rgName = split(id, "/", 4))
| extend prop = parse_json(properties)
| extend lTime = todatetime(prop.lastModifiedDateTime), OS = tostring(prop.osType), installedPatchCount = tostring(prop.installedPatchCount), failedPatchCount = tostring(prop.failedPatchCount), pendingPatchCount = tostring(prop.pendingPatchCount), excludedPatchCount = tostring(prop.excludedPatchCount), notSelectedPatchCount = tostring(prop.notSelectedPatchCount)
| where lTime > ago(7d)
| project lTime, RunID=name,machineName, rgName, resourceType, OS, installedPatchCount, failedPatchCount, pendingPatchCount, excludedPatchCount, notSelectedPatchCount

Lista de instalações de atualização do sistema operacional Windows Server

A consulta a seguir retorna uma lista de instalações de atualização para o Windows Server com seu status para suas máquinas dos últimos sete dias. Os resultados incluem a hora em que a implantação da atualização foi executada, a ID do recurso da instalação, os detalhes da máquina e outros detalhes de implantação relacionados.

patchinstallationresources
| where type has "softwarepatches" and isnull(properties.version)
| extend machineName = tostring(split(id, "/", 8)), resourceType = tostring(split(type, "/", 0)), tostring(rgName = split(id, "/", 4)), tostring(RunID = split(id, "/", 10))
| extend prop = parse_json(properties)
| extend lTime = todatetime(prop.lastModifiedDateTime), patchName = tostring(prop.patchName), kbId = tostring(prop.kbId), installationState = tostring(prop.installationState), classifications = tostring(prop.classifications)
| where lTime > ago(7d)
| project lTime, RunID, machineName, rgName, resourceType, patchName, kbId, classifications, installationState
| sort by RunID

Lista de instalações de atualização do sistema operacional Linux

A consulta a seguir retorna uma lista de instalações de atualização para Linux com seu status para suas máquinas dos últimos sete dias. Os resultados incluem a hora em que a implantação da atualização foi executada, a ID do recurso da instalação, os detalhes da máquina e outros detalhes de implantação relacionados.

patchinstallationresources
| where type has "softwarepatches" and isnotnull(properties.version) and isnull(properties.kbId)
| extend machineName = tostring(split(id, "/", 8)), resourceType = tostring(split(type, "/", 0)), tostring(rgName = split(id, "/", 4)), tostring(RunID = split(id, "/", 10))
| extend prop = parse_json(properties)
| extend lTime = todatetime(prop.lastModifiedDateTime), patchName = tostring(prop.patchName), version = tostring(prop.version), installationState = tostring(prop.installationState), classifications = tostring(prop.classifications)
| where lTime > ago(7d)
| project lTime, RunID, machineName, rgName, resourceType, patchName, version, classifications, installationState
| sort by RunID

Lista de registros de execução de manutenção no nível da VM

A consulta a seguir retorna uma lista de todos os registros de execução de manutenção para uma VM

maintenanceresources 
| where ['id'] contains "/subscriptions/<subscription-id>/resourcegroups/<resource-group>/providers/microsoft.compute/virtualmachines/<vm-name>" //VM Id here
| where ['type'] == "microsoft.maintenance/applyupdates" 
| where properties.maintenanceScope == "InGuestPatch"

Próximos passos

  • Revise os logs e os resultados da pesquisa do Update Manager no Azure usando o Azure Resource Graph.
  • Solucione problemas no Update Manager, consulte a Solução de problemas.