Como: Consultar uma ArrayList com LINQ (Visual Basic)

  • Artigo

Ao usar o LINQ para consultar coleções não genéricas IEnumerable , como ArrayList, você deve declarar explicitamente o tipo da variável range para refletir o tipo específico dos objetos na coleção. Por exemplo, se você tiver um ArrayList dos Student objetos, sua cláusula From deve ter esta aparência:

Dim query = From student As Student In arrList
'...

Ao especificar o tipo da variável de intervalo, você está convertendo cada item no ArrayList para um Student.

O uso de uma variável de intervalo explicitamente tipada em uma expressão de consulta é equivalente a chamar o Cast método. Cast lança uma exceção se o elenco especificado não puder ser executado. Cast e OfType são os dois métodos Standard Query Operator que operam em tipos não genéricos IEnumerable . No Visual Basic, você deve chamar explicitamente o Cast método na fonte de dados para garantir um tipo de variável de intervalo específico. Para obter mais informações, consulte Relações de tipo em operações de consulta (Visual Basic).

Exemplo

O exemplo a seguir mostra uma consulta simples sobre um ArrayListarquivo . Observe que este exemplo usa inicializadores de objeto quando o código chama o Add método, mas isso não é um requisito.

Imports System.Collections
Imports System.Linq

Module Module1

    Public Class Student
        Public Property FirstName As String
        Public Property LastName As String
        Public Property Scores As Integer()
    End Class

    Sub Main()

        Dim student1 As New Student With {.FirstName = "Svetlana",
                                     .LastName = "Omelchenko",
                                     .Scores = New Integer() {98, 92, 81, 60}}
        Dim student2 As New Student With {.FirstName = "Claire",
                                    .LastName = "O'Donnell",
                                    .Scores = New Integer() {75, 84, 91, 39}}
        Dim student3 As New Student With {.FirstName = "Cesar",
                                    .LastName = "Garcia",
                                    .Scores = New Integer() {97, 89, 85, 82}}
        Dim student4 As New Student With {.FirstName = "Sven",
                                    .LastName = "Mortensen",
                                    .Scores = New Integer() {88, 94, 65, 91}}

        Dim arrList As New ArrayList()
        arrList.Add(student1)
        arrList.Add(student2)
        arrList.Add(student3)
        arrList.Add(student4)

        ' Use an explicit type for non-generic collections
        Dim query = From student As Student In arrList
                    Where student.Scores(0) > 95
                    Select student

        For Each student As Student In query
            Console.WriteLine(student.LastName & ": " & student.Scores(0))
        Next
        ' Keep the console window open in debug mode.
        Console.WriteLine("Press any key to exit.")
        Console.ReadKey()
    End Sub

End Module
' Output:
'   Omelchenko: 98
'   Garcia: 97

Consulte também