sp_helptracertokenhistory (Transact-SQL)

  • Artigo

Aplica-se a: Instância Gerenciada de SQL do Azure do SQL Server

Retorna informações de latência detalhada por tokens de rastreamento especificados, com uma linha retornada para cada Assinante. Esse procedimento armazenado é executado no Publicador, no banco de dados de publicação, ou no Distribuidor, no banco de dados de distribuição.

Convenções de sintaxe de Transact-SQL

Sintaxe

sp_helptracertokenhistory
    [ @publication = ] N'publication'
    , [ @tracer_id = ] tracer_id
    [ , [ @publisher = ] N'publisher' ]
    [ , [ @publisher_db = ] N'publisher_db' ]
[ ; ]

Argumentos

@publication [ = ] N'publicação'

O nome da publicação na qual o token de rastreamento foi inserido. @publication é sysname, sem padrão.

@tracer_id [ = ] tracer_id

A ID do token de rastreamento na tabela MStracer_tokens, para a qual as informações do histórico são retornadas. @tracer_id é int, sem padrão.

@publisher [ = ] N'editor'

O nome do Editor. @publisher é sysname, com um padrão de NULL.

@publisher só devem ser especificados para Publicadores não SQL Server.

@publisher_db [ = ] N'publisher_db'

O nome do banco de dados de publicação. @publisher_db é sysname, com um padrão de NULL. Esse parâmetro será ignorado se o procedimento armazenado for executado no Publicador.

Conjunto de resultados

Nome da coluna Tipo de dados Descrição
distributor_latency bigint Número de segundos entre o registro de token de rastreamento sendo aplicado no Publicador e o registro sendo aplicado no Distribuidor.
subscriber sysname Nome do Assinante que recebeu o token de rastreamento.
subscriber_db sysname Nome do banco de dados de assinatura no qual o registro de token de rastreamento foi inserido.
subscriber_latency bigint Número de segundos entre o registro de token de rastreamento aplicado no Distribuidor e o registro aplicado no Assinante.
overall_latency bigint Número de segundos entre o registro de token de rastreamento aplicado no Publicador e o registro de token aplicado no Assinante.

Valores do código de retorno

0 (sucesso) ou 1 (falha).

Comentários

sp_helptracertokenhistory é usado na replicação transacional.

Execute sp_helptracertokens para obter uma lista de tokens de rastreamento para a publicação.

Um valor de no conjunto de resultados significa que as estatísticas de NULL latência não podem ser calculadas. Isso ocorre porque o token de rastreamento não foi recebido no Distribuidor ou em um dos Assinantes.

Exemplos

DECLARE @publication AS sysname;
DECLARE @tokenID AS int;
SET @publication = N'AdvWorksProductTran'; 

USE [AdventureWorks2022]

-- Insert a new tracer token in the publication database.
EXEC sys.sp_posttracertoken 
  @publication = @publication,
  @tracer_token_id = @tokenID OUTPUT;
SELECT 'The ID of the new tracer token is ''' + 
    CONVERT(varchar,@tokenID) + '''.'
GO

-- Wait 10 seconds for the token to make it to the Subscriber.
WAITFOR DELAY '00:00:10';
GO

-- Get latency information for the last inserted token.
DECLARE @publication AS sysname;
DECLARE @tokenID AS int;
SET @publication = N'AdvWorksProductTran'; 

CREATE TABLE #tokens (tracer_id int, publisher_commit datetime)

-- Return tracer token information to a temp table.
INSERT #tokens (tracer_id, publisher_commit)
EXEC sys.sp_helptracertokens @publication = @publication;
SET @tokenID = (SELECT TOP 1 tracer_id FROM #tokens
ORDER BY publisher_commit DESC)
DROP TABLE #tokens

-- Get history for the tracer token.
EXEC sys.sp_helptracertokenhistory 
  @publication = @publication, 
  @tracer_id = @tokenID;
GO

Permissões

Somente membros da função de servidor fixa sysadmin, da função de banco de dados fixa db_owner no banco de dados de publicação ou db_owner funções fixas de banco de dados ou replmonitor no banco de dados de distribuição podem executar sp_helptracertokenhistory.

Conteúdo relacionado