sp_posttracertoken (Transact-SQL)

  • Artigo

Aplica-se: SQL Server

Esse procedimento envia um token de rastreamento para um log de transações no Publicador e inicia o processo de rastreamento de estatística de latência.

As informações são registradas:

  • quando o token de rastreamento é gravado no log de transações;
  • quando o Log Reader Agent o seleciona; e
  • quando o Agente de Distribuição o aplica.

Esse procedimento armazenado é executado no Publicador, no banco de dados publicador. Para obter mais informações, consulte Medir a latência e validar as conexões para a replicação transacional.

Convenções de sintaxe de Transact-SQL

Sintaxe

sp_posttracertoken
    [ @publication = ] N'publication'
    [ , [ @tracer_token_id = ] tracer_token_id OUTPUT ]
    [ , [ @publisher = ] N'publisher' ]
[ ; ]

Argumentos

@publication [ = ] N'publicação'

O nome da publicação para a qual a latência está sendo medida. @publication é sysname, sem padrão.

@tracer_token_id [ = ] tracer_token_id SAÍDA

A ID do token de rastreamento inserido. @tracer_token_id é um parâmetro OUTPUT do tipo int. Esse valor pode ser usado para executar sp_helptracertokenhistory ou sp_deletetracertokenhistory sem primeiro executar sp_helptracertokens.

@publisher [ = ] N'editor'

Especifica um Publicador não-SQL Server. @publisher é sysname, com um padrão de NULL. Esse parâmetro não deve ser especificado para um Publicador do SQL Server.

Valores do código de retorno

0 (sucesso) ou 1 (falha).

Comentários

sp_posttracertoken é usado na replicação transacional.

Exemplos

DECLARE @publication AS sysname;
DECLARE @tokenID AS int;
SET @publication = N'AdvWorksProductTran'; 

USE [AdventureWorks2022]

-- Insert a new tracer token in the publication database.
EXEC sys.sp_posttracertoken 
  @publication = @publication,
  @tracer_token_id = @tokenID OUTPUT;
SELECT 'The ID of the new tracer token is ''' + 
    CONVERT(varchar,@tokenID) + '''.'
GO

-- Wait 10 seconds for the token to make it to the Subscriber.
WAITFOR DELAY '00:00:10';
GO

-- Get latency information for the last inserted token.
DECLARE @publication AS sysname;
DECLARE @tokenID AS int;
SET @publication = N'AdvWorksProductTran'; 

CREATE TABLE #tokens (tracer_id int, publisher_commit datetime)

-- Return tracer token information to a temp table.
INSERT #tokens (tracer_id, publisher_commit)
EXEC sys.sp_helptracertokens @publication = @publication;
SET @tokenID = (SELECT TOP 1 tracer_id FROM #tokens
ORDER BY publisher_commit DESC)
DROP TABLE #tokens

-- Get history for the tracer token.
EXEC sys.sp_helptracertokenhistory 
  @publication = @publication, 
  @tracer_id = @tokenID;
GO

Permissões

Somente membros da função de servidor fixa sysadmin ou da função de banco de dados fixa db_owner podem executar sp_posttracertokeno .

Conteúdo relacionado