Запросы для таблицы WVDConnectionNetworkData

Статья
07/31/2024

Сведения об использовании этих запросов в портал Azure см. в руководстве по Log Analytics. Сведения о REST API см. в разделе "Запрос".

Среднее время круговой поездки с течением времени

Отображение графа времени кругового пути (в миллисекундах) во всех соединениях в 10 мин интервалов в 10-м, 50-м и 90-м процентилях.

WVDConnectionNetworkData
| summarize percentiles(EstRoundTripTimeInMs, 90, 50, 10) by bin(TimeGenerated,10m)
| render timechart

Среднее значение BW для всех подключений

Отображает график пропускной способности (в килобайтах в секунду) для всех подключений более 10 мин интервалов в 10-м, 50-м и 90-м процентилях.

WVDConnectionNetworkData
| summarize percentiles(EstAvailableBandwidthKBps, 90, 50, 10) by bin(TimeGenerated,10m)
| render timechart

Лучшие 10 пользователей с самым высоким временем круговой поездки

Возвращает список лучших 10 пользователей с наибольшим средним временем круговой поездки (в миллисекундах).

WVDConnectionNetworkData
| join kind=leftouter 
(
    WVDConnections
    | where State == "Completed"
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgRTT=round(avg(EstRoundTripTimeInMs)), RTT_P95=percentile(EstRoundTripTimeInMs, 95) by UserName
| top 10 by AvgRTT desc

Лучшие 10 пользователей с наименьшей пропускной способностью

Возвращает список лучших 10 пользователей с наименьшей средней пропускной способностью (в Килобайтах в секунду).

WVDConnectionNetworkData
| join kind=inner 
(
    WVDConnections
    | where State == "Completed"
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgBW=avg(EstAvailableBandwidthKBps), BW_P95=percentile(EstAvailableBandwidthKBps,95) by UserName
| top 10 by AvgBW asc

Сводка времени кругового пути и пропускной способности

Возвращает 90-й процентиль для времени кругового пути (в миллисекундах) и пропускной способности (в Килобайтах) для каждого подключения вместе с дополнительными сведениями о подключении.

WVDConnectionNetworkData
| summarize RTTP90=percentile(EstRoundTripTimeInMs,90), BWP90=percentile(EstAvailableBandwidthKBps,90), StartTime=min(TimeGenerated), EndTime=max(TimeGenerated) by CorrelationId
| join kind=inner
(
    WVDConnections
    | where State == "Connected"
    | extend Protocol = iif(UdpUse in ("0", "<>"), "TCP", "UDP")
) on CorrelationId
| project CorrelationId, StartTime, EndTime, UserName, SessionHostName, RTTP90, BWP90, Protocol, ClientOS, ClientType, ClientVersion, ConnectionType, ResourceAlias, SessionHostSxSStackVersion

Поделиться через