Краткое руководство. Создание пространства имен служебной шины и очереди с помощью файла Bicep

  • Статья

В этой статье показывается, как использовать файл Bicep, который создает пространство имен служебной шины и очередь в нем. Здесь объясняется, как указать развертываемые ресурсы и определить параметры, указываемые при развертывании. Этот файл Bicep можно использовать для собственных развертываний или изменить его в соответствии с вашими требованиями.

Bicep — это предметно-ориентированный язык (DSL), который использует декларативный синтаксис для развертывания ресурсов Azure. Он обеспечивает краткий синтаксис, надежную безопасность типов и поддержку повторного использования кода. Bicep предлагает лучшие возможности для разработки решений Azure типа "инфраструктура как код".

Необходимые компоненты

Если у вас нет подписки Azure, создайте бесплатную учетную запись, прежде чем приступить к работе.

Проверка BICEP-файла

Файл Bicep, используемый в этом кратком руководстве, взят из шаблонов быстрого запуска Azure.

@description('Name of the Service Bus namespace')
param serviceBusNamespaceName string

@description('Name of the Queue')
param serviceBusQueueName string

@description('Location for all resources.')
param location string = resourceGroup().location

resource serviceBusNamespace 'Microsoft.ServiceBus/namespaces@2022-01-01-preview' = {
  name: serviceBusNamespaceName
  location: location
  sku: {
    name: 'Standard'
  }
  properties: {}
}

resource serviceBusQueue 'Microsoft.ServiceBus/namespaces/queues@2022-01-01-preview' = {
  parent: serviceBusNamespace
  name: serviceBusQueueName
  properties: {
    lockDuration: 'PT5M'
    maxSizeInMegabytes: 1024
    requiresDuplicateDetection: false
    requiresSession: false
    defaultMessageTimeToLive: 'P10675199DT2H48M5.4775807S'
    deadLetteringOnMessageExpiration: false
    duplicateDetectionHistoryTimeWindow: 'PT10M'
    maxDeliveryCount: 10
    autoDeleteOnIdle: 'P10675199DT2H48M5.4775807S'
    enablePartitioning: false
    enableExpress: false
  }
}

Ресурсы, определенные в файле Bicep, включают:

Примечание.

Для загрузки и развертывания доступны следующие шаблоны ARM.

Другие шаблоны Bicep и ARM можно найти на странице Шаблоны быстрого запуска Azure.

Развертывание BICEP-файла

С помощью файла Bicep вы развернете пространство имен служебной шины с очередью.

Очереди служебной шины доставляют сообщения конкурирующим получателям по типу FIFO (в порядке очереди).

  1. Сохраните файл Bicep с именем main.bicep на локальном компьютере.

  2. Разверните файл Bicep с помощью Azure CLI или Azure PowerShell.

    az group create --name exampleRG --location eastus
az deployment group create --resource-group exampleRG --template-file main.bicep

    Появится подсказка для ввода значений следующих параметров:

    • serviceBusNamespaceName: имя пространства имен служебной шины;
    • serviceBusQueueName: имя очереди.

    После завершения развертывания должно отобразиться сообщение о том, что развертывание успешно выполнено.

Проверка развертывания

Используйте портал Azure, Azure CLI или Azure PowerShell для получения списка ресурсов, развернутых в группе ресурсов.

az resource list --resource-group exampleRG

Очистка ресурсов

Чтобы удалить виртуальную машину и ресурсы в группе ресурсов, которые вам больше не нужны, используйте портал Azure, Azure CLI или Azure PowerShell.

az group delete --name exampleRG

Следующие шаги

См. следующий раздел, в котором показано, как создать правило авторизации для пространства имен или очереди:

Создание правила авторизации служебной шины для пространства имен и очереди с помощью шаблона ARM

Узнайте, как управлять этими ресурсами, просмотрев следующие статьи: