backupmediaset (Transact-SQL)

  • Статья

Область применения: SQL Server Управляемый экземпляр SQL Azure

Содержит по одной строке для каждого резервного набора носителей. Эта таблица хранится в базе данных msdb.

Имя столбца Тип данных Description
media_set_id int Уникальный идентификационный номер набора носителей. Удостоверение, первичный ключ.
media_uuid uniqueidentifier UUID набора носителей. Все наборы носителей Microsoft SQL Server имеют идентификатор UUID.

Однако в более ранних версиях SQL Server, если набор носителей содержит только одно семейство носителей, столбец media_uuid может иметь значение NULL (media_family_count равно 1).
media_family_count tinyint Число семейств носителей в наборе носителей. Может иметь значение NULL.
name nvarchar(128) Имя набора носителей. Может иметь значение NULL.

Дополнительные сведения см. в разделе MEDIANAME и MEDIADESCRIPTION в BACKUP (Transact-SQL).
описание nvarchar(255) Текстовое описание набора носителей. Может иметь значение NULL.

Дополнительные сведения см. в разделе MEDIANAME и MEDIADESCRIPTION в BACKUP (Transact-SQL).
software_name nvarchar(128) Имя программного обеспечения резервного копирования, которое записало метку носителя. Может иметь значение NULL.
software_vendor_id int Идентификационный номер поставщика программного обеспечения, которое записало метку носителя резервной копии. Может иметь значение NULL.

Значением microsoft SQL Server является шестнадцатеричное 0x1200.
MTF_major_version tinyint Основной номер версии формата ленты Microsoft, используемый для создания этого набора носителей. Может иметь значение NULL.
mirror_count tinyint Число зеркальных отображений в наборе носителей.
is_password_protected bit Защищен ли набор носителей паролем.

0 = не защищен

1 = защищен
is_compressed bit Указывает, является ли резервная копия сжатой:

0 = не сжатая

1 = сжатая

Во время обновления msdb это значение равно NULL. Это означает резервное копирование без сжатия.
is_encrypted Bit Указывает, шифруется ли резервная копия.

0 = не зашифрована

1 = зашифрована

Замечания

RESTORE VERIFYONLY FROM backup_device WITH LOADHISTORY заполняет столбцы таблицы backupmediaset соответствующими значениями из заголовка набора носителей.

Чтобы сократить число строк в этой таблице и в других резервных таблицах и таблицах журнала, выполните хранимую процедуру sp_delete_backuphistory.

Примеры

Журнал резервного копирования запросов

Следующий запрос возвращает данные об успешном резервном копировании за последние 2 месяца.

SELECT bs.database_name,
	backuptype = CASE
			WHEN bs.type = 'D'
			AND bs.is_copy_only = 0 THEN 'Full Database'
			WHEN bs.type = 'D'
			AND bs.is_copy_only = 1 THEN 'Full Copy-Only Database'
			WHEN bs.type = 'I' THEN 'Differential database backup'
			WHEN bs.type = 'L' THEN 'Transaction Log'
			WHEN bs.type = 'F' THEN 'File or filegroup'
			WHEN bs.type = 'G' THEN 'Differential file'
			WHEN bs.type = 'P' THEN 'Partial'
			WHEN bs.type = 'Q' THEN 'Differential partial'
		END + ' Backup',
	CASE bf.device_type
			WHEN 2 THEN 'Disk'
			WHEN 5 THEN 'Tape'
			WHEN 7 THEN 'Virtual device'
			WHEN 9 THEN 'Azure Storage'
			WHEN 105 THEN 'A permanent backup device'
			ELSE 'Other Device'
		END AS DeviceType,
	bms.software_name AS backup_software,
	bs.recovery_model,
	bs.compatibility_level,
	BackupStartDate = bs.Backup_Start_Date,
	BackupFinishDate = bs.Backup_Finish_Date,
	LatestBackupLocation = bf.physical_device_name,
	backup_size_mb = CONVERT(decimal(10, 2), bs.backup_size/1024./1024.),
	compressed_backup_size_mb = CONVERT(decimal(10, 2), bs.compressed_backup_size/1024./1024.),
	database_backup_lsn, -- For tlog and differential backups, this is the checkpoint_lsn of the FULL backup it is based on.
	checkpoint_lsn,
	begins_log_chain,
	bms.is_password_protected
FROM msdb.dbo.backupset bs
LEFT OUTER JOIN msdb.dbo.backupmediafamily bf ON bs.[media_set_id] = bf.[media_set_id]
INNER JOIN msdb.dbo.backupmediaset bms ON bs.[media_set_id] = bms.[media_set_id]
WHERE bs.backup_start_date > DATEADD(MONTH, -2, sysdatetime()) --only look at last two months
ORDER BY bs.database_name ASC, bs.Backup_Start_Date DESC;

См. также

Таблицы резервного копирования и восстановления (Transact-SQL)
backupfile (Transact-SQL)
backupfilegroup (Transact-SQL)
backupmediafamily (Transact-SQL)
backupset (Transact-SQL)
Системные таблицы (Transact-SQL)