Объект ResourceLocator

Объект , предоставляющий путь к ресурсу. Объект ResourceLocator можно использовать вместо URI ресурса в операциях объекта Session , таких как Session.Get, Session.Put или Session.Enumerate.

Этот объект позволяет:

• Добавьте один или несколько селекторов , определяющих конкретный экземпляр ресурса. Это аналогично указанию значения ключа в URI ресурса для ресурса, использующего ключи. Дополнительные сведения см. в разделе ResourceLocator.AddSelector. Аналогичную операцию можно выполнить с помощью параметра фильтра в вызове Session.Enumerate.
• Укажите путь к фрагменту и диалект, чтобы получить только одно свойство ресурса. Можно также указать один или все элементы свойства массива, указав индекс массива. Дополнительные сведения см. в разделе ResourceLocator.FragmentPath.
• Добавьте один или несколько параметров , которые могут потребоваться источнику данных для обработки запроса. Дополнительные сведения см. в разделе ResourceLocator.AddOption.

Дополнительные сведения см. в разделе Запросы для конкретных экземпляров ресурса.

Элементы

Объект ResourceLocator имеет следующие типы элементов:

• Методы
• Свойства

Методы

Объект ResourceLocator содержит следующие методы.

Свойства

Объект ResourceLocator имеет следующие свойства.

Комментарии

Объект ResourceLocator соответствует интерфейсу IWSManResourceLocator .

Примеры

Следующий пример кода VBScript получает свойства NumberOfLogicalProcessors и NumberOfCores из определенного экземпляра Win32_Processor.

Option Explicit
Dim strUri
strUri = "http://schemas.microsoft.com/wbem/wsman/1/" _
    & "wmi/root/cimv2/Win32_Processor"
Const FragmentDialect = _
    "https://www.w3.org/TR/1999/REC-xpath-19991116"

Dim WSMan
Set WSMan = CreateObject("WSMan.Automation")

Dim Session
Set Session = WSMan.CreateSession

Dim Locator
Set Locator = WSMan.CreateResourceLocator(strUri)

Locator.AddSelector "DeviceID", "CPU0"

Dim NumberOfCores_XML
Locator.FragmentPath = "NumberOfCores"
Locator.FragmentDialect = FragmentDialect
NumberOfCores_XML = Session.Get(Locator)
DisplayOutput NumberOfCores_XML

Dim NumberOfLogicalProcessors_XML
Locator.FragmentPath = "NumberOfLogicalProcessors"
Locator.FragmentDialect = FragmentDialect
NumberOfLogicalProcessors_XML = Session.Get(Locator)

DisplayOutput NumberOfLogicalProcessors_XML

'****************************************************
' Displays WinRM XML message using built-in XSL
'****************************************************

Sub DisplayOutput( strWinRMXml )
    Dim xmlFile, xslFile
    Set xmlFile = CreateObject( "MSXml2.DOMDocument.3.0" )    
    Set xslFile = CreateObject( "MSXml2.DOMDocument.3.0" )
    xmlFile.LoadXml( strWinRMXml )
    xslFile.Load( "WsmTxt.xsl" )
    Wscript.Echo xmlFile.TransformNode( xslFile )           
End Sub

Требования

См. также раздел

API скриптов WinRM