Frågor för tabellen ApiManagementGatewayLogs

  • Artikel

Information om hur du använder dessa frågor i Azure Portal finns i Log Analytics-självstudien. Information om REST-API:et finns i Fråga.

Antal begäranden

Räkna det totala antalet anrop för alla API:er under de senaste 24 timmarna.

//Total number of call per resource
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| summarize count(CorrelationId) by _ResourceId

Loggar för de senaste 100 anropen

Hämta loggarna för de senaste 100 anropen under de senaste 24 timmarna.

ApiManagementGatewayLogs
| top 100 by TimeGenerated desc

Antal anrop per API:er

Visa antalet anrop per API under de senaste 24 timmarna.

//Calls by API ID
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| summarize count(CorrelationId) by ApiId

Förbrukad bandbredd

Total bandbredd som förbrukats under de senaste 24 timmarna.

// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| extend bandwidth = RequestSize + ResponseSize 
| summarize sum(bandwidth) by bin(TimeGenerated, 15m), _ResourceId 
| render timechart

Begärandestorlekar

Statistik över begärandestorlekar under de senaste 24 timmarna.

// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| summarize Average=avg(RequestSize), Median=percentile(RequestSize, 50), 90th_Percentile=percentile(RequestSize, 90) by bin(TimeGenerated, 5m) 
| render timechart

Svarsstorlekar

Statistik över svarsstorlekar under de senaste 24 timmarna.

// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| summarize Average=avg(ResponseSize), Median=percentile(ResponseSize, 50), 90th_Percentile=percentile(ResponseSize, 90) by bin(TimeGenerated, 5m) 
| render timechart

Klient-TLS-versioner

Uppdelning av klient-TLS-versioner under de senaste 24 timmarna.

ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| summarize count(CorrelationId) by ClientTlsVersion, _ResourceId

Felorsaksuppdelning

Uppdelning av alla felorsaker under de senaste 24 timmarna.

// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| where IsRequestSuccess == false
| summarize count(CorrelationId) by LastErrorReason, _ResourceId

Senaste 100 misslyckade begäranden

Hämta loggarna för de senaste 100 misslyckade begärandena.

ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| where IsRequestSuccess == false
| top 100 by TimeGenerated desc| where ResponseCode >= 400

Hämta loggarna för misslyckade begäranden på grund av serverdelsproblem.

// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| where IsRequestSuccess == false
| where BackendResponseCode >= 400

Hämta loggarna för misslyckade begäranden på grund av problem som inte är relaterade till serverdelen (t.ex. konfiguration av API-hanteringsprinciper, överskriden hastighetsgräns, klientfrånkoppling).

// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| where IsRequestSuccess == false
| where isnull(BackendResponseCode) or BackendResponseCode < 400
| where ResponseCode >= 400

Övergripande svarstid

Statistik över den övergripande svarstiden (i miliseconds) mellan den tidpunkt då API Mangement börjar ta emot en begäran och den tid då API Management slutför sändningen av svaret tillbaka till klienten.

// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| summarize Average=avg(TotalTime), Median=percentile(TotalTime, 50), 90th_Percentile=percentile(TotalTime, 90) by bin(TimeGenerated, 15m) 
| render timechart

Svarstid för serverdel

Statistik över tid (i miliseconds) som spenderas i serverdels-I/O.

// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| summarize Average=avg(BackendTime), Median=percentile(BackendTime, 50), 90th_Percentile=percentile(BackendTime, 90) by bin(TimeGenerated, 15m) 
| render timechart

Klientfördröjning

Statistik över tid (i miliseconds) som spenderas i klient-I/O.

// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| summarize Average=avg(ClientTime), Median=percentile(ClientTime, 50), 90th_Percentile=percentile(ClientTime, 90) by bin(TimeGenerated, 15m) 
| render timechart

Cacheträffförhållande

Statistik för cachens träff/miss-förhållande.

// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| summarize Cache_Miss=countif(Cache  == "miss"), Cache_Hit=countif(Cache == "hit") by bin(TimeGenerated, 15m)
| extend Ratio=Cache_Hit / (Cache_Hit + Cache_Miss)
| project-away Cache_Hit , Cache_Miss 
| render timechart