Frågor för tabellen StorageBlobLogs

  • Artikel

Information om hur du använder dessa frågor i Azure Portal finns i Log Analytics-självstudien. Information om REST-API:et finns i Fråga.

De vanligaste felen

Lista 10 vanligaste fel under de senaste 3 dagarna.

StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText !contains "Success"
| summarize count() by StatusText
| top 10 by count_ desc

Åtgärder som orsakar de flesta fel

Lista de 10 vanligaste åtgärderna som orsakar flest fel under de senaste 3 dagarna.

StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText !contains "Success"
| summarize count() by OperationName
| top 10 by count_ desc

Åtgärder med högsta svarstid

Lista de 10 främsta åtgärderna med den längsta svarstiden från slutpunkt till slutpunkt under de senaste 3 dagarna.

StorageBlobLogs
| where TimeGenerated > ago(3d)
| top 10 by DurationMs desc
| project TimeGenerated, OperationName, DurationMs, ServerLatencyMs, ClientLatencyMs = DurationMs - ServerLatencyMs

Åtgärder som orsakar begränsning på serversidan

Visa en lista över alla åtgärder som orsakar begränsningsfel på serversidan under de senaste tre dagarna.

// To create an alert for this query, click '+ New alert rule'
StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText contains "ServerBusy"
| project TimeGenerated, OperationName, StatusCode, StatusText, _ResourceId

Visa anonyma begäranden

Visa en lista över alla begäranden med anonym åtkomst under de senaste tre dagarna.

// To create an alert for this query, click '+ New alert rule'
StorageBlobLogs
| where TimeGenerated > ago(3d) and AuthenticationType == "Anonymous"
| project TimeGenerated, OperationName, AuthenticationType, Uri, _ResourceId

Diagram över frekventa åtgärder

Ett cirkeldiagram över åtgärder som använts under de senaste tre dagarna.

StorageBlobLogs
| where TimeGenerated > ago(3d)
| summarize count() by OperationName
| sort by count_ desc 
| render piechart