Förbereda din miljö för en länk – Azure SQL Managed Instance

Följ dessa steg för att testa nätverksanslutningen mellan SQL Server och SQL Managed Instance i SSMS:

1. Anslut till den instans som ska vara den primära repliken i SSMS.

2. I Object Explorer expanderar du databaser och högerklickar på den databas som du vill länka till den sekundära. Välj Uppgifter>Azure SQL Managed Instance-länken>Testa Anslut ion för att öppna guiden Nätverkskontroll:

   

3. Välj Nästa på sidan Introduktion i guiden Nätverkskontroll .

4. Om alla krav uppfylls på sidan Förutsättningar väljer du Nästa. Lös annars eventuella ouppfyllda krav och välj sedan Kör validering igen.

5. På sidan Inloggning väljer du Logga in för att ansluta till den andra instansen som ska vara den sekundära repliken. Välj Nästa.

6. Kontrollera informationen på sidan Ange nätverksalternativ och ange en IP-adress om det behövs. Välj Nästa.

7. På sidan Sammanfattning granskar du de åtgärder som guiden vidtar och väljer sedan Slutför för att testa anslutningen mellan de två replikerna.

8. Granska sidan Resultat för att verifiera att anslutningen finns mellan de två replikerna och välj sedan Stäng för att slutföra.

Om du vill använda T-SQL för att testa anslutningen måste du kontrollera anslutningen i båda riktningarna. Testa först anslutningen från SQL Server till SQL Managed Instance och testa sedan anslutningen från SQL Managed Instance till SQL Server.

Testa anslutningen från SQL Server till SQL Managed Instance

Använd SQL Server Agent på SQL Server för att köra anslutningstester från SQL Server till SQL Managed Instance.

1. Anslut till SQL Managed Instance och kör följande skript för att generera parametrar som du behöver senare:

   SELECT 'DECLARE @serverName NVARCHAR(512) = N''' + value + ''''
   FROM sys.dm_hadr_fabric_config_parameters
   WHERE parameter_name = 'DnsRecordName'
   
   UNION
   
   SELECT 'DECLARE @node NVARCHAR(512) = N''' + NodeName + '.' + Cluster + ''''
   FROM (
       SELECT SUBSTRING(replica_address, 0, CHARINDEX('\', replica_address)) AS NodeName,
           RIGHT(service_name, CHARINDEX('/', REVERSE(service_name)) - 1) AppName,
           JoinCol = 1
       FROM sys.dm_hadr_fabric_partitions fp
       INNER JOIN sys.dm_hadr_fabric_replicas fr
           ON fp.partition_id = fr.partition_id
       INNER JOIN sys.dm_hadr_fabric_nodes fn
           ON fr.node_name = fn.node_name
       WHERE service_name LIKE '%ManagedServer%'
           AND replica_role = 2
   ) t1
   LEFT JOIN (
       SELECT value AS Cluster,
           JoinCol = 1
       FROM sys.dm_hadr_fabric_config_parameters
       WHERE parameter_name = 'ClusterName'
       ) t2
       ON (t1.JoinCol = t2.JoinCol)
   INNER JOIN (
       SELECT [value] AS AppName
       FROM sys.dm_hadr_fabric_config_parameters
       WHERE section_name = 'SQL'
           AND parameter_name = 'InstanceName'
       ) t3
       ON (t1.AppName = t3.AppName)
   
   UNION
   
   SELECT 'DECLARE @port NVARCHAR(512) = N''' + value + ''''
   FROM sys.dm_hadr_fabric_config_parameters
   WHERE parameter_name = 'HadrPort';
   

   Resultaten bör se ut som i följande exempel:

   

   Spara resultatet om du vill använda nästa steg. Eftersom dessa parametrar kan ändras efter en redundansväxling måste du generera dem igen, om det behövs.

2. Anslut till SQL Server.

3. Öppna ett nytt frågefönster och klistra in följande skript:

   --START
   -- Parameters section
   DECLARE @node NVARCHAR(512) = N''
   DECLARE @port NVARCHAR(512) = N''
   DECLARE @serverName NVARCHAR(512) = N''
   
   --Script section
   IF EXISTS (
           SELECT job_id
           FROM msdb.dbo.sysjobs_view
           WHERE name = N'TestMILinkConnection'
           )
       EXEC msdb.dbo.sp_delete_job @job_name = N'TestMILinkConnection',
           @delete_unused_schedule = 1
   
   DECLARE @jobId BINARY (16),
       @cmd NVARCHAR(MAX)
   
   EXEC msdb.dbo.sp_add_job @job_name = N'TestMILinkConnection',
       @enabled = 1,
       @job_id = @jobId OUTPUT
   
   SET @cmd = (N'tnc ' + @serverName + N' -port 5022 | select ComputerName, RemoteAddress, TcpTestSucceeded | Format-List')
   
   EXEC msdb.dbo.sp_add_jobstep @job_id = @jobId,
       @step_name = N'Test Port 5022',
       @step_id = 1,
       @cmdexec_success_code = 0,
       @on_success_action = 3,
       @on_fail_action = 3,
       @subsystem = N'PowerShell',
       @command = @cmd,
       @database_name = N'master'
   
   SET @cmd = (N'tnc ' + @node + N' -port ' + @port + ' | select ComputerName, RemoteAddress, TcpTestSucceeded | Format-List')
   
   EXEC msdb.dbo.sp_add_jobstep @job_id = @jobId,
       @step_name = N'Test HADR Port',
       @step_id = 2,
       @cmdexec_success_code = 0,
       @subsystem = N'PowerShell',
       @command = @cmd,
       @database_name = N'master'
   
   EXEC msdb.dbo.sp_add_jobserver @job_id = @jobId,
       @server_name = N'(local)'
   GO
   
   EXEC msdb.dbo.sp_start_job @job_name = N'TestMILinkConnection'
   GO
   
   --Check status every 5 seconds
   DECLARE @RunStatus INT
   
   SET @RunStatus = 10
   
   WHILE (@RunStatus >= 4)
   BEGIN
       SELECT DISTINCT @RunStatus = run_status
       FROM [msdb].[dbo].[sysjobhistory] JH
       INNER JOIN [msdb].[dbo].[sysjobs] J
           ON JH.job_id = J.job_id
       WHERE J.name = N'TestMILinkConnection'
           AND step_id = 0
   
       WAITFOR DELAY '00:00:05';
   END
   
   --Get logs once job completes
   SELECT [step_name],
       SUBSTRING([message], CHARINDEX('TcpTestSucceeded', [message]), CHARINDEX('Process Exit', [message]) - CHARINDEX('TcpTestSucceeded', [message])) AS    TcpTestResult,
       SUBSTRING([message], CHARINDEX('RemoteAddress', [message]), CHARINDEX('TcpTestSucceeded', [message]) - CHARINDEX('RemoteAddress', [message])) AS    RemoteAddressResult,
       [run_status],
       [run_duration],
       [message]
   FROM [msdb].[dbo].[sysjobhistory] JH
   INNER JOIN [msdb].[dbo].[sysjobs] J
       ON JH.job_id = J.job_id
   WHERE J.name = N'TestMILinkConnection'
       AND step_id <> 0
       --END
   

4. Ersätt parametrarna @node, @portoch @serverName med de värden som du fick från det första steget.

5. Kör skriptet och kontrollera resultatet. Du bör se resultat, till exempel följande exempel:

   

6. Kontrollera resultatet:

   • Resultatet av varje test vid TcpTestSucceeded bör vara TcpTestSucceeded : True.
   • RemoteAddresses ska tillhöra IP-intervallet för undernätet SQL Managed Instance.

   Om svaret misslyckas kontrollerar du följande nätverksinställningar:

   • Det finns regler i både nätverksbrandväggen och SQL Server-värdoperativsystemets brandvägg (Windows/Linux) som tillåter trafik till hela undernätets IP-intervall för SQL Managed Instance.
   • Det finns en NSG-regel som tillåter kommunikation på port 5022 för det virtuella nätverk som är värd för SQL Managed Instance.

Testa anslutningen från SQL Managed Instance till SQL Server

Om du vill kontrollera att SQL Managed Instance kan nå SQL Server skapar du först en testslutpunkt. Sedan använder du SQL Server-agenten för att köra ett PowerShell-skript med tnc kommandot pinga SQL Server på port 5022 från den SQL-hanterade instansen.

Om du vill skapa en testslutpunkt ansluter du till SQL Server och kör följande T-SQL-skript:

-- Run on SQL Server
-- Create the certificate needed for the test endpoint
USE MASTER
CREATE CERTIFICATE TEST_CERT
WITH SUBJECT = N'Certificate for SQL Server',
EXPIRY_DATE = N'3/30/2051'
GO

-- Create the test endpoint on SQL Server
USE MASTER
CREATE ENDPOINT TEST_ENDPOINT
    STATE=STARTED
    AS TCP (LISTENER_PORT=5022, LISTENER_IP = ALL)
    FOR DATABASE_MIRRORING (
        ROLE=ALL,
        AUTHENTICATION = CERTIFICATE TEST_CERT,
        ENCRYPTION = REQUIRED ALGORITHM AES
    )

Kontrollera att SQL Server-slutpunkten tar emot anslutningar på port 5022 genom att köra följande PowerShell-kommando på värdoperativsystemet för SQL Server-instansen:

tnc localhost -port 5022

Ett lyckat test visar TcpTestSucceeded : True. Du kan sedan fortsätta att skapa ett SQL Server Agent-jobb på den SQL-hanterade instansen för att testa SQL Server-testslutpunkten på port 5022 från den SQL-hanterade instansen.

Skapa sedan ett SQL Server Agent-jobb på den SQL-hanterade instansen som anropas NetHelper genom att köra följande T-SQL-skript på den SQL-hanterade instansen. Ersätta:

• <SQL_SERVER_IP_ADDRESS> med IP-adressen för SQL Server som kan nås från EN SQL-hanterad instans.

-- Run on SQL managed instance
-- SQL_SERVER_IP_ADDRESS should be an IP address that could be accessed from the SQL Managed Instance host machine.
DECLARE @SQLServerIpAddress NVARCHAR(MAX) = '<SQL_SERVER_IP_ADDRESS>'; -- insert your SQL Server IP address in here
DECLARE @tncCommand NVARCHAR(MAX) = 'tnc ' + @SQLServerIpAddress + ' -port 5022 -InformationLevel Quiet';
DECLARE @jobId BINARY(16);

IF EXISTS (
        SELECT *
        FROM msdb.dbo.sysjobs
        WHERE name = 'NetHelper'
        ) THROW 70000,
    'Agent job NetHelper already exists. Please rename the job, or drop the existing job before creating it again.',
    1
    -- To delete NetHelper job run: EXEC msdb.dbo.sp_delete_job @job_name=N'NetHelper'
    EXEC msdb.dbo.sp_add_job @job_name = N'NetHelper',
        @enabled = 1,
        @description = N'Test SQL Managed Instance to SQL Server network connectivity on port 5022.',
        @category_name = N'[Uncategorized (Local)]',
        @owner_login_name = N'sa',
        @job_id = @jobId OUTPUT;

EXEC msdb.dbo.sp_add_jobstep @job_id = @jobId,
    @step_name = N'TNC network probe from SQL MI to SQL Server',
    @step_id = 1,
    @os_run_priority = 0,
    @subsystem = N'PowerShell',
    @command = @tncCommand,
    @database_name = N'master',
    @flags = 40;

EXEC msdb.dbo.sp_update_job @job_id = @jobId,
    @start_step_id = 1;

EXEC msdb.dbo.sp_add_jobserver @job_id = @jobId,
    @server_name = N'(local)';

Skapa sedan en lagrad procedur ExecuteNetHelper som hjälper dig att köra jobbet och hämta resultat från nätverksavsökningen. Kör följande T-SQL-skript på SQL-hanterad instans:

-- Run on managed instance
IF EXISTS(SELECT * FROM sys.objects WHERE name = 'ExecuteNetHelper')
    THROW 70001, 'Stored procedure ExecuteNetHelper already exists. Rename or drop the existing procedure before creating it again.', 1
GO
CREATE PROCEDURE ExecuteNetHelper AS
-- To delete the procedure run: DROP PROCEDURE ExecuteNetHelper
BEGIN
    -- Start the job.
    DECLARE @NetHelperstartTimeUtc DATETIME = GETUTCDATE();
    DECLARE @stop_exec_date DATETIME = NULL;

    EXEC msdb.dbo.sp_start_job @job_name = N'NetHelper';

    -- Wait for job to complete and then see the outcome.
    WHILE (@stop_exec_date IS NULL)
    BEGIN
        -- Wait and see if the job has completed.
        WAITFOR DELAY '00:00:01'

        SELECT @stop_exec_date = sja.stop_execution_date
        FROM msdb.dbo.sysjobs sj
        INNER JOIN msdb.dbo.sysjobactivity sja
            ON sj.job_id = sja.job_id
        WHERE sj.name = 'NetHelper'

        -- If job has completed, get the outcome of the network test.
        IF (@stop_exec_date IS NOT NULL)
        BEGIN
            SELECT sj.name JobName,
                sjsl.date_modified AS 'Date executed',
                sjs.step_name AS 'Step executed',
                sjsl.log AS 'Connectivity status'
            FROM msdb.dbo.sysjobs sj
            LEFT JOIN msdb.dbo.sysjobsteps sjs
                ON sj.job_id = sjs.job_id
            LEFT JOIN msdb.dbo.sysjobstepslogs sjsl
                ON sjs.step_uid = sjsl.step_uid
            WHERE sj.name = 'NetHelper'
        END

        -- In case of operation timeout (90 seconds), print timeout message.
        IF (datediff(second, @NetHelperstartTimeUtc, getutcdate()) > 90)
        BEGIN
            SELECT 'NetHelper timed out during the network check. Please investigate SQL Agent logs for more information.'

            BREAK;
        END
    END
END;

Kör följande fråga på sql-hanterad instans för att köra den lagrade proceduren som ska köra NetHelper-agentjobbet och visa den resulterande loggen:

-- Run on managed instance
EXEC ExecuteNetHelper;

Om anslutningen lyckades visar Trueloggen . Om anslutningen misslyckades visar Falseloggen .

Om anslutningen misslyckades kontrollerar du följande:

• Brandväggen på SQL Server-värdinstansen tillåter inkommande och utgående kommunikation på port 5022.
• En NSG-regel för det virtuella nätverket som är värd för SQL Managed Instance tillåter kommunikation på port 5022.
• Om SQL Server-instansen finns på en virtuell Azure-dator tillåter en NSG-regel kommunikation på port 5022 i det virtuella nätverk som är värd för den virtuella datorn.
• SQL Server körs.
• Det finns en testslutpunkt på SQL Server.

När du har löst problem kör du NetHelper-nätverksavsökningen igen genom att köra EXEC ExecuteNetHelper på en hanterad instans.

När nätverkstestet har slutförts släpper du slutligen testslutpunkten och certifikatet på SQL Server med hjälp av följande T-SQL-kommandon:

-- Run on SQL Server
DROP ENDPOINT TEST_ENDPOINT;
GO
DROP CERTIFICATE TEST_CERT;
GO