Hızlı Başlangıç: Visual Studio Code ile Bicep dosyaları oluşturma

Makale
09/20/2024

Bu hızlı başlangıç, Visual Studio Code ile Bicep dosyası oluşturma adımları boyunca size yol gösterir. Bir depolama hesabı ve sanal ağ oluşturursunuz. Ayrıca tür güvenliği, söz dizimi doğrulaması ve otomatik tamamlama sağlayarak Bicep uzantısının geliştirmeyi nasıl kolaylaştırdığı hakkında bilgi edinebilirsiniz.

Benzer yazma deneyimi Visual Studio'da da desteklenir. Bkz . Hızlı Başlangıç: Visual Studio ile Bicep dosyaları oluşturma.

Önkoşullar

Azure aboneliğiniz yoksa başlamadan önce ücretsiz bir hesap oluşturun.

Ortamınızı Bicep geliştirme için ayarlamak için bkz . Bicep araçlarını yükleme. Bu adımları tamamladıktan sonra Visual Studio Code ve Bicep uzantısına sahip olacaksınız. Ayrıca en son Azure CLI veya en son Azure PowerShell modülüne de sahipsiniz.

Kaynak parçacığı ekleme

Bicep uzantısına sahip VS Code, önceden tanımlanmış kod parçacıkları sağlayarak geliştirmeyi kolaylaştırır. Bu hızlı başlangıçta, sanal ağ oluşturan bir kod parçacığı ekleyebilirsiniz.

Visual Studio Code'u başlatın ve main.bicep adlı yeni bir dosya oluşturun.

main.bicep'e vnet yazın ve listeden res-vnet öğesini seçin ve [SEKME] veya [ENTER] tuşlarına basın.

Sanal ağ için kod parçacığı ekleme ekran görüntüsü.

İpucu

VS Code'da bu IntelliSense seçeneklerini görmüyorsanız, Önkoşullar bölümünde belirtildiği gibi Bicep uzantısını yüklediğinizden emin olun. Uzantıyı yüklediyseniz Bicep dil hizmetine Bicep dosyanızı açtıktan sonra başlaması için biraz zaman tanıyın. Genellikle hızlı bir şekilde başlar, ancak başlayana kadar IntelliSense seçenekleriniz yoktur. Sağ alt köşedeki bildirim, hizmetin başlatıldığını gösterir. Bu bildirim kaybolduğunda hizmet çalışır durumda olur.

Bicep dosyanız artık aşağıdaki kodu içerir:

resource virtualNetwork 'Microsoft.Network/virtualNetworks@2019-11-01' = {
  name: 'name'
  location: location
  properties: {
    addressSpace: {
      addressPrefixes: [
        '10.0.0.0/16'
      ]
    }
    subnets: [
      {
        name: 'Subnet-1'
        properties: {
          addressPrefix: '10.0.0.0/24'
        }
      }
      {
        name: 'Subnet-2'
        properties: {
          addressPrefix: '10.0.1.0/24'
        }
      }
    ]
  }
}

Bu kod parçacığında, bir sanal ağ tanımlamak için gerekli tüm değerleri bulursunuz. İki kıvrımlı alt çizgi fark edebilirsiniz. Sarı bir değer, eski API sürümüyle ilgili bir uyarıyı belirtirken, kırmızı kıvrımlı alt çizgi eksik parametre tanımının neden olduğu bir hataya işaret eder.

öğesini kaldırın @2019-11-01ve ile @değiştirin. En son API sürümünü seçin.

API sürümünü güncelleştirme ekran görüntüsü.

Sonraki bölümde eksik parametre tanımı hatasını düzelteceksiniz.

Bu kodu gereksinimlerinizi karşılayacak şekilde de değiştirebilirsiniz. Örneğin, name sanal ağ için harika bir ad değildir. özelliğini olarak name examplevnetdeğiştirin.

name: 'exampleVNet'

Parametre ekleme

Son bölümde eklediğiniz kod parçacığı bir parametre tanımını kaçırır.

Dosyanın en üstüne şunları ekleyin:

param location

Konumdan sonra bir alan eklediğinizde IntelliSense'in parametresi için kullanılabilen veri türlerini sunduğuna dikkat edin. Dizeyi seçin.

Parametreye dize türü ekleme ekran görüntüsü.

Parametresine varsayılan bir değer verin:

param location string = resourceGroup().location

Varsayılan değerde kullanılan işlev hakkında daha fazla bilgi için bkz . resourceGroup().

Depolama hesabı adı için varsayılan değere sahip başka bir parametre ekleyin:

param storageAccountName string = 'store${uniqueString(resourceGroup().id)}'

Daha fazla bilgi için bkz . İlişkilendirme ve uniqueString().

Bu parametre düzgün çalışır, ancak depolama hesaplarının adın uzunluğuyla ilgili sınırları vardır. Adın en az üç karakteri ve en fazla 24 karakteri olmalıdır. Parametresine dekoratör ekleyerek bu gereksinimleri belirtebilirsiniz.

parametresinin üzerine bir satır ekleyin ve yazın @. Kullanılabilir dekoratörleri görürsünüz. hem minLength hem de maxLength için dekoratörler olduğuna dikkat edin.

parametresine dekoratör ekleme ekran görüntüsü.

Her iki dekoratör de ekleyin ve karakter sınırlarını belirtin:

@minLength(3)
@maxLength(24)
param storageAccountName string = 'store${uniqueString(resourceGroup().id)}'

Parametresi için bir açıklama da ekleyebilirsiniz. Bicep dosyasını dağıtan kişilerin hangi değeri sağlayabileceklerini anlamasına yardımcı olacak bilgiler ekleyin.

@minLength(3)
@maxLength(24)
@description('Provide a name for the storage account. Use only lower case letters and numbers. The name must be unique across Azure.')
param storageAccountName string = 'store${uniqueString(resourceGroup().id)}'

Parametreleriniz kullanıma hazır.

Kaynak ekle

Depolama hesabını tanımlamak için bir kod parçacığı kullanmak yerine, değerleri ayarlamak için IntelliSense kullanırsınız. IntelliSense bu adımı, değerleri el ile yazmaktan daha kolay hale getirir.

Kaynak tanımlamak için anahtar sözcüğünü resource kullanın. Sanal ağınızın altına kaynak örneğiStorage yazın:

resource exampleStorage

exampleStorage , dağıttığınız kaynağın sembolik adıdır. Bu adı, Bicep dosyanızın diğer bölümlerindeki kaynağa başvurmak için kullanabilirsiniz.

Simge adından sonra bir boşluk eklediğinizde, kaynak türlerinin listesi görüntülenir. Kullanılabilir seçenekler arasından seçene kadar storageacc yazmaya devam edin.

Kaynak türü için depolama hesaplarını seçme işleminin ekran görüntüsü.

Microsoft.Storage/storageAccounts'ı seçtikten sonra kullanılabilir API sürümleri sunulur. En son sürümü seçin. Aşağıdaki ekran görüntüsü için 2023-05-01 şeklindedir.

Kaynak türü için api sürümünü seçmenin ekran görüntüsü.

Kaynak türü için tek tırnak işaretinden sonra bir boşluk ekleyin = . Kaynağa özellik ekleme seçenekleri sunulur. Gerekli özellikler'i seçin.

Gerekli özellikleri ekleme ekran görüntüsü.

Bu seçenek, dağıtım için gereken kaynak türünün tüm özelliklerini ekler. Bu seçeneği seçtikten sonra depolama hesabınız aşağıdaki özelliklere sahiptir:

resource exampleStorage 'Microsoft.Storage/storageAccounts@2023-05-01' = {
  name:
  location:
  sku: {
    name:
  }
  kind:
}

Neredeyse bitti. Yalnızca bu özellikler için değerler sağlayın.

IntelliSense de size yardımcı olur. storageAccountNameolarak ayarlayınname. Bu, depolama hesabı için bir ad içeren parametredir. için locationdeğerini locationolarak ayarlayın. Bu, daha önce oluşturduğunuz bir parametredir. ve kindeklerken sku.name IntelliSense geçerli seçenekleri sunar.

Gerekli özelliklerin yanı sıra isteğe bağlı özellikler eklemek için imleci istediğiniz konuma getirin ve Ctrl Ara Çubuğu'na+ basın. IntelliSense, aşağıdaki ekran görüntüsünde gösterildiği gibi kullanılmayan özellikler önerir:

Ek özellikler ekleme ekran görüntüsü.

İşiniz bittiğinde şunları elde etmiş olacaksınız:

@minLength(3)
@maxLength(24)
param storageAccountName string = 'store${uniqueString(resourceGroup().id)}'
param location string = resourceGroup().location

resource virtualNetwork 'Microsoft.Network/virtualNetworks@2024-01-01' = {
  name: 'exampleVNet'
  location: resourceGroup().location
  properties: {
    addressSpace: {
      addressPrefixes: [
        '10.0.0.0/16'
      ]
    }
    subnets: [
      {
        name: 'Subnet-1'
        properties: {
          addressPrefix: '10.0.0.0/24'
        }
      }
      {
        name: 'Subnet-2'
        properties: {
          addressPrefix: '10.0.1.0/24'
        }
      }
    ]
  }
}

resource exampleStorage 'Microsoft.Storage/storageAccounts@2023-05-01' = {
  name: storageAccountName
  location: 'eastus'
  sku: {
    name: 'Standard_LRS'
  }
  kind: 'StorageV2'
}

Bicep söz dizimi hakkında daha fazla bilgi için bkz . Bicep yapısı.

Kaynakları görselleştirme

Dosyanızdaki kaynakların bir gösterimini görüntüleyebilirsiniz.

Sağ üst köşeden görselleştirici düğmesini seçerek Bicep Görselleştiricisi'ni açın.

Bicep Görselleştiricisi'nin ekran görüntüsü.

Görselleştirici, Kaynak bağımlılığı bilgileriyle Bicep dosyasında tanımlanan kaynakları gösterir. Bu hızlı başlangıçta tanımlanan iki kaynak bağımlılık ilişkisine sahip olmadığından iki kaynak arasında bağlayıcı görmezsiniz.

Bicep Görselleştiricisi diyagramının ekran görüntüsü.

Bicep dosyasını dağıtma

VS Code içinde Bicep dosyasına sağ tıklayın ve ardından Bicep dosyasını dağıt'ı seçin.
Lütfen dağıtım için ad girin metin kutusuna deployStorageAndVNet yazın ve [ENTER] tuşuna basın.
Üstteki Kaynak Grubu Seç liste kutusundan Yeni Kaynak Grubu Oluştur'u seçin.
Kaynak grubu adı olarak exampleRG yazın ve [ENTER] tuşuna basın.
Kaynak grubu için bir konum seçin, Orta ABD'yi veya seçtiğiniz bir konumu seçin ve [ENTER] tuşuna basın.
Parametre dosyası seç'ten Yok'a tıklayın.

Kaynakların oluşturulması birkaç dakika sürer. Daha fazla bilgi için bkz . Visual Studio Code ile Bicep dosyalarını dağıtma.

Bicep dosyasını Azure CLI veya Azure PowerShell kullanarak da dağıtabilirsiniz:

CLI
PowerShell

az group create --name exampleRG --location eastus

az deployment group create --resource-group exampleRG --template-file main.bicep --parameters storageAccountName=uniquename

New-AzResourceGroup -Name exampleRG -Location eastus

New-AzResourceGroupDeployment -ResourceGroupName exampleRG -TemplateFile ./main.bicep -storageAccountName "uniquename"

Dağıtım tamamlandığında, dağıtımın başarılı olduğunu belirten bir ileti görmeniz gerekir.

Kaynakları temizleme

Azure kaynaklarına artık gerek kalmadığında, hızlı başlangıç kaynak grubunu silmek için Azure CLI veya Azure PowerShell modülünü kullanın.

CLI
PowerShell

az group delete --name exampleRG

Remove-AzResourceGroup -Name exampleRG

Sonraki adımlar

Bicep için modülleri öğrenme

Aracılığıyla paylaş