Hızlı Başlangıç: Bicep dosyası kullanarak Batch hesabı oluşturma

Depolama alanı da dahil olmak üzere bir Batch hesabı oluşturmak için Bicep dosyası kullanarak Azure Batch'i kullanmaya başlayın. İşlem kaynakları (işlem düğümleri havuzları) ve Batch işleri oluşturmak için bir Batch hesabına ihtiyacınız vardır. Uygulamaları dağıtmak ve çoğu gerçek iş yükü için giriş ve çıkış verilerini depolamak için yararlı olan Batch hesabınızla bir Azure Depolama hesabı bağlayabilirsiniz.

Bu hızlı başlangıcı tamamladıktan sonra Batch hizmetinin temel kavramlarını anlayacak ve daha büyük ölçekte daha gerçekçi iş yükleriyle Batch'i denemeye hazır olacaksınız.

Bicep, Azure kaynaklarını dağıtmak için bildirim temelli söz dizimi kullanan, etki alanına özgü bir dildir (DSL). Kısa sözdizimi, güvenilir tür güvenliği ve kod yeniden kullanımı için destek sağlar. Bicep, Azure'daki kod olarak altyapı çözümleriniz için en iyi yazma deneyimini sunar.

Önkoşullar

Etkin bir Azure aboneliğiniz olmalıdır.

• Azure aboneliğiniz yoksa başlamadan önce birücretsiz Azure hesabı oluşturun.

Bicep dosyasını gözden geçirme

Bu hızlı başlangıçta kullanılan Bicep dosyası Azure Hızlı Başlangıç Şablonları'ndan alınmıştı.

@description('Batch Account Name')
param batchAccountName string = '${toLower(uniqueString(resourceGroup().id))}batch'

@description('Storage Account type')
@allowed([
  'Standard_LRS'
  'Standard_GRS'
  'Standard_ZRS'
  'Premium_LRS'
])
param storageAccountsku string = 'Standard_LRS'

@description('Location for all resources.')
param location string = resourceGroup().location

var storageAccountName = '${uniqueString(resourceGroup().id)}storage'

resource storageAccount 'Microsoft.Storage/storageAccounts@2023-01-01' = {
  name: storageAccountName
  location: location
  sku: {
    name: storageAccountsku
  }
  kind: 'StorageV2'
  tags: {
    ObjectName: storageAccountName
  }
  properties: {
    minimumTlsVersion: 'TLS1_2'
    allowBlobPublicAccess: false
    networkAcls: {
      defaultAction: 'Deny'
    }
    supportsHttpsTrafficOnly: true
  }
}

resource batchAccount 'Microsoft.Batch/batchAccounts@2024-02-01' = {
  name: batchAccountName
  location: location
  tags: {
    ObjectName: batchAccountName
  }
  properties: {
    autoStorage: {
      storageAccountId: storageAccount.id
    }
  }
}

output storageAccountName string = storageAccount.name
output batchAccountName string = batchAccount.name
output location string = location
output resourceGroupName string = resourceGroup().name
output resourceId string = batchAccount.id

Bicep dosyasında iki Azure kaynağı tanımlanır:

• Microsoft.Storage/storageAccounts: Bir depolama hesabı oluşturur.
• Microsoft.Batch/batchAccounts: Batch hesabı oluşturur.

Bicep dosyasını dağıtma

1. Bicep dosyasını main.bicep olarak yerel bilgisayarınıza kaydedin.

2. Azure CLI veya Azure PowerShell kullanarak Bicep dosyasını dağıtın.

   • CLI
   • PowerShell

   az group create --name exampleRG --location eastus
   az deployment group create --resource-group exampleRG --template-file main.bicep
   

   Dağıtım tamamlandığında, dağıtımın başarılı olduğunu belirten bir ileti görmeniz gerekir.

Dağıtımı doğrulama

Kaynak grubundaki dağıtılan kaynakları listelemek için Azure portalını, Azure CLI'yı veya Azure PowerShell'i kullanın.

az resource list --resource-group exampleRG

Get-AzResource -ResourceGroupName exampleRG

Kaynakları temizleme

Öğreticilerimizden daha fazlasıyla devam etmek istiyorsanız, bu kaynakları yerinde bırakmak isteyebilirsiniz. Artık gerekli olmadığında, kaynak grubunu ve tüm kaynaklarını silmek için Azure portalı, Azure CLI veya Azure PowerShell'i kullanın.

az group delete --name exampleRG

Remove-AzResourceGroup -Name exampleRG

Sonraki adımlar

Bu hızlı başlangıçta, Bicep kullanarak bir Batch hesabı ve bir depolama hesabı oluşturdunuz. Azure Batch hakkında daha fazla bilgi için Azure Batch öğreticilerine devam edin.