Hızlı Başlangıç: Bicep dosyası kullanarak Azure Ağ İzleyicisi NSG akış günlüklerini yapılandırma

Bu hızlı başlangıçta, bicep dosyası kullanarak NSG akış günlüklerini etkinleştirmeyi öğreneceksiniz.

Bicep, Azure kaynaklarını dağıtmak için bildirim temelli söz dizimi kullanan, etki alanına özgü bir dildir (DSL). Kısa sözdizimi, güvenilir tür güvenliği ve kod yeniden kullanımı için destek sağlar. Bicep, Azure'daki kod olarak altyapı çözümleriniz için en iyi yazma deneyimini sunar.

Önkoşullar

• Etkin aboneliği olan bir Azure hesabı. Aboneliğiniz yoksa başlamadan önce ücretsiz bir hesap oluşturun.

• Azure CLI veya PowerShell yüklü olan Bicep dosyalarını dağıtmak için.

  • Azure CLI
  • PowerShell

  1. Komutları çalıştırmak için Azure CLI'yi yerel olarak yükleyin.

  2. az login komutunu kullanarak Azure'da oturum açın .

Bicep dosyasını gözden geçirme

Bu hızlı başlangıçta Azure Hızlı Başlangıç Şablonları'ndan NSG akış günlükleri oluşturma Bicep şablonu kullanılır.

@description('Name of the Network Watcher attached to your subscription. Format: NetworkWatcher_<region_name>')
param networkWatcherName string = 'NetworkWatcher_${location}'

@description('Name of your Flow log resource')
param flowLogName string = 'FlowLog1'

@description('Region where you resources are located')
param location string = resourceGroup().location

@description('Resource ID of the target NSG')
param existingNSG string

@description('Retention period in days. Default is zero which stands for permanent retention. Can be any Integer from 0 to 365')
@minValue(0)
@maxValue(365)
param retentionDays int = 0

@description('FlowLogs Version. Correct values are 1 or 2 (default)')
@allowed([
  1
  2
])
param flowLogsVersion int = 2

@description('Storage Account type')
@allowed([
  'Standard_LRS'
  'Standard_GRS'
  'Standard_ZRS'
])
param storageAccountType string = 'Standard_LRS'

var storageAccountName = 'flowlogs${uniqueString(resourceGroup().id)}'

resource storageAccount 'Microsoft.Storage/storageAccounts@2021-09-01' = {
  name: storageAccountName
  location: location
  sku: {
    name: storageAccountType
  }
  kind: 'StorageV2'
  properties: {}
}

resource networkWatcher 'Microsoft.Network/networkWatchers@2022-01-01' = {
  name: networkWatcherName
  location: location
  properties: {}
}

resource flowLog 'Microsoft.Network/networkWatchers/flowLogs@2022-01-01' = {
  name: '${networkWatcherName}/${flowLogName}'
  location: location
  properties: {
    targetResourceId: existingNSG
    storageId: storageAccount.id
    enabled: true
    retentionPolicy: {
      days: retentionDays
      enabled: true
    }
    format: {
      type: 'JSON'
      version: flowLogsVersion
    }
  }
}

Aşağıdaki kaynaklar Bicep dosyasında tanımlanır:

• Microsoft.Storage/storageAccounts
• Microsoft.Network networkWatchers
• Microsoft.Network networkWatchers/flowLogs

Yukarıdaki örnekte vurgulanan kod bir NSG akış günlüğü kaynak tanımını gösterir.

Bicep dosyasını dağıtma

Bu hızlı başlangıçta, akış günlüğünü etkinleştirebileceğiniz bir ağ güvenlik grubunuz olduğu varsayılır.

1. Bicep dosyasını main.bicep olarak yerel bilgisayarınıza kaydedin.

2. Azure CLI veya Azure PowerShell kullanarak Bicep dosyasını dağıtın.

   • Azure CLI
   • PowerShell

   az group create --name exampleRG --location eastus
   az deployment group create --resource-group exampleRG --template-file main.bicep
   

   Mevcut ağ güvenlik grubunun kaynak kimliğini girmeniz istenir. Ağ güvenlik grubu kaynak kimliğinin söz dizimi şöyledir:

   "/subscriptions/<subscription-id>/resourceGroups/<resource-group-name>/providers/Microsoft.Network/networkSecurityGroups/<network-security-group-name>"
   

Dağıtım tamamlandığında, dağıtımın başarılı olduğunu belirten bir ileti görmeniz gerekir.

Dağıtımı doğrulama

Dağıtımınızın başarılı olup olmadığını görmek için iki seçeneğiniz vardır:

• Konsolunuz olarak SucceededgösterilirProvisioningState.
• Değişikliklerinizi onaylamak için NSG akış günlükleri portalı sayfasına gidin.

Dağıtımla ilgili sorunlar varsa bkz . Azure Resource Manager ile ilgili yaygın Azure dağıtım hatalarını giderme.

Kaynakları temizleme

Tam dağıtım modunu kullanarak Azure kaynaklarını silebilirsiniz. Akış günlükleri kaynağını silmek için, silmek istediğiniz kaynağı eklemeden tam modda bir dağıtım belirtin. Tam dağıtım modu hakkında daha fazla bilgi edinin.

Ayrıca Azure portalında bir NSG akış günlüğünü devre dışı bırakabilirsiniz:

1. Azure Portal’ında oturum açın.

2. Portalın üst kısmındaki arama kutusuna ağ izleyicisi yazın. Arama sonuçlarından Ağ İzleyicisi seçin.

3. Günlükler'in altında Akış günlükleri'ne tıklayın.

4. Akış günlükleri listesinde, devre dışı bırakmak istediğiniz akış günlüğünü seçin.

5. Devre Dışı Bırak'ı seçin.

İlgili içerik

NSG akış günlükleri verilerinizi görselleştirmeyi öğrenmek için bkz:

• Power BI kullanarak NSG akış günlüklerini görselleştirme.
• açık kaynak araçlarını kullanarak NSG akış günlüklerini görselleştirme.
• Trafik Analizi.