Düşünceler ion Kullanarak Özniteliklere Erişme (Visual Basic)

  • Makale

Özel öznitelikleri tanımlayıp kaynak kodunuza yerleştirebilmeniz, bu bilgileri alıp üzerinde hareket etmenin bir yolu olmadan çok az değerli olacaktır. Yansıma kullanarak, özel özniteliklerle tanımlanan bilgileri alabilirsiniz. Anahtar yöntemi, GetCustomAttributeskaynak kod özniteliklerinin çalışma zamanı eşdeğerleri olan bir nesne dizisi döndüren yöntemidir. Bu yöntemin birkaç aşırı yüklenmiş sürümü vardır. Daha fazla bilgi için bkz. Attribute.

Öznitelik belirtimi:

<Author("P. Ackerman", Version:=1.1)>
Class SampleClass
    ' P. Ackerman's code goes here...
End Class

kavramsal olarak şuna eşdeğerdir:

Dim anonymousAuthorObject As Author = New Author("P. Ackerman")
anonymousAuthorObject.version = 1.1

Ancak, öznitelikler için sorgulanana kadar SampleClass kod yürütülür. çağrısı GetCustomAttributesSampleClass , bir Author nesnenin yukarıdaki gibi oluşturulup başlatılmasına neden olur. Sınıfın başka öznitelikleri varsa, diğer öznitelik nesneleri benzer şekilde oluşturulur. GetCustomAttributes ardından bir dizideki Author nesneyi ve diğer öznitelik nesnelerini döndürür. Daha sonra bu dizi üzerinde yineleme yapabilir, her dizi öğesinin türüne göre hangi özniteliklerin uygulandığını belirleyebilir ve öznitelik nesnelerinden bilgi ayıklayabilirsiniz.

Örnek

Tam bir örnek aşağıda verilmiştir. Özel bir öznitelik tanımlanır, çeşitli varlıklara uygulanır ve yansıma yoluyla alınır.

' Multiuse attribute
<System.AttributeUsage(System.AttributeTargets.Class Or
                       System.AttributeTargets.Struct,
                       AllowMultiple:=True)>
Public Class Author
    Inherits System.Attribute
    Private name As String
    Public version As Double
    Sub New(ByVal authorName As String)
        name = authorName

        ' Default value
        version = 1.0
    End Sub

    Function GetName() As String
        Return name
    End Function
End Class

' Class with the Author attribute
<Author("P. Ackerman")>
Public Class FirstClass
End Class

' Class without the Author attribute
Public Class SecondClass
End Class

' Class with multiple Author attributes.
<Author("P. Ackerman"), Author("R. Koch", Version:=2.0)>
Public Class ThirdClass
End Class

Class TestAuthorAttribute
    Sub Main()
        PrintAuthorInfo(GetType(FirstClass))
        PrintAuthorInfo(GetType(SecondClass))
        PrintAuthorInfo(GetType(ThirdClass))
    End Sub

    Private Shared Sub PrintAuthorInfo(ByVal t As System.Type)
        System.Console.WriteLine("Author information for {0}", t)

        ' Using reflection
        Dim attrs() As System.Attribute = System.Attribute.GetCustomAttributes(t)

        ' Displaying output
        For Each attr In attrs
            Dim a As Author = CType(attr, Author)
            System.Console.WriteLine("   {0}, version {1:f}", a.GetName(), a.version)
        Next
    End Sub

    ' Output:
    '   Author information for FirstClass
    '     P. Ackerman, version 1.00
    ' Author information for SecondClass
    ' Author information for ThirdClass
    '  R. Koch, version 2.00
    '  P. Ackerman, version 1.00

End Class

Ayrıca bkz.