Genel Arabirimlerde Varyans (Visual Basic)

  • Makale

.NET Framework 4, çeşitli mevcut genel arabirimler için varyans desteği sunar. Varyans desteği, bu arabirimleri uygulayan sınıfların örtük olarak dönüştürülmesi sağlar. Aşağıdaki arabirimler artık değişkendir:

Kovaryans, bir yöntemin arabirimin genel tür parametresi tarafından tanımlanandan daha türetilmiş bir dönüş türüne sahip olmasına izin verir. Kovaryans özelliğini göstermek için şu genel arabirimleri göz önünde bulundurun: IEnumerable(Of Object) ve IEnumerable(Of String). Arabirim IEnumerable(Of String) , arabirimi devralmıyor IEnumerable(Of Object) . Ancak, String tür türü devralır Object ve bazı durumlarda bu arabirimlerin nesnelerini birbirine atamak isteyebilirsiniz. Bu, aşağıdaki kod örneğinde gösterilmiştir.

Dim strings As IEnumerable(Of String) = New List(Of String)
Dim objects As IEnumerable(Of Object) = strings

.NET Framework'ün önceki sürümlerinde, bu kod ile Option Strict OnVisual Basic'te bir derleme hatasına neden olur. Ancak artık önceki örnekte gösterildiği gibi yerine objectskullanabilirsiniz strings çünkü IEnumerable<T> arabirim birlikte değişkendir.

Contravariance, bir yöntemin arabiriminin genel parametresi tarafından belirtilenden daha az türetilmiş bağımsız değişken türlerine sahip olmasına izin verir. Karşıtlık değişkenini göstermek için, sınıfın örneklerini karşılaştırmak için bir BaseComparer sınıf oluşturduğunuzu BaseClass varsayalım. BaseComparer sınıfı, IEqualityComparer(Of BaseClass) arabirimini uygular. IEqualityComparer<T> Arabirim artık değişkensiz olduğundan, sınıfı devralan BaseClass sınıfların örneklerini karşılaştırmak için kullanabilirsinizBaseComparer. Bu, aşağıdaki kod örneğinde gösterilmiştir.

' Simple hierarchy of classes.
Class BaseClass
End Class

Class DerivedClass
    Inherits BaseClass
End Class

' Comparer class.
Class BaseComparer
    Implements IEqualityComparer(Of BaseClass)

    Public Function Equals1(ByVal x As BaseClass,
                            ByVal y As BaseClass) As Boolean _
                            Implements IEqualityComparer(Of BaseClass).Equals
        Return (x.Equals(y))
    End Function

    Public Function GetHashCode1(ByVal obj As BaseClass) As Integer _
        Implements IEqualityComparer(Of BaseClass).GetHashCode
        Return obj.GetHashCode
    End Function
End Class
Sub Test()
    Dim baseComparer As IEqualityComparer(Of BaseClass) = New BaseComparer
    ' Implicit conversion of IEqualityComparer(Of BaseClass) to
    ' IEqualityComparer(Of DerivedClass).
    Dim childComparer As IEqualityComparer(Of DerivedClass) = baseComparer
End Sub

Daha fazla örnek için bkz . Genel Koleksiyonlar için Arabirimlerde Varyansı Kullanma (Visual Basic)...

Genel arabirimlerdeki varyans yalnızca başvuru türleri için desteklenir. Değer türleri varyansı desteklemez. Örneğin, IEnumerable(Of Integer) tamsayılar bir değer türüyle temsil edildiğinden örtük olarak öğesine dönüştürülemez IEnumerable(Of Object).

Dim integers As IEnumerable(Of Integer) = New List(Of Integer)
' The following statement generates a compiler error
' with Option Strict On, because Integer is a value type.
' Dim objects As IEnumerable(Of Object) = integers

Değişken arabirimleri uygulayan sınıfların hala sabit olduğunu unutmamak da önemlidir. Örneğin, birlikte değişken arabirimini uygulasa daList<T>, örtük olarak öğesine List(Of String)dönüştüremezsinizList(Of Object).IEnumerable<T> Bu, aşağıdaki kod örneğinde gösterilmiştir.

' The following statement generates a compiler error
' because classes are invariant.
' Dim list As List(Of Object) = New List(Of String)

' You can use the interface object instead.
Dim listObjects As IEnumerable(Of Object) = New List(Of String)

Ayrıca bkz.