Sorgudan alma (.set, .append, .set-or-append, .set-or-replace)

Şunlar için geçerlidir: ✅Microsoft Fabric✅Azure Veri Gezgini

Bu komutlar bir sorgu veya yönetim komutu yürütür ve sorgunun sonuçlarını bir tabloya alır. Bu komutlar arasındaki fark, mevcut veya var olmayan tablo ve verilere nasıl davrandıklarıdır.

Sorgu komutundan alma işlemini iptal etmek için bkz cancel operation. .

İzinler

Tabloda farklı eylemler gerçekleştirmek için belirli izinler gereklidir:

• komutunu kullanarak .append var olan bir tabloya satır eklemek için en az Tablo Alma iznine sahip olmanız gerekir.
• Çeşitli .set komutları kullanarak yeni bir tablo oluşturmak için en az Veritabanı Kullanıcısı izinlerine sahip olmanız gerekir.
• Komutunu kullanarak .set-or-replace var olan bir tablodaki satırları değiştirmek için en az Tablo Yöneticisi izinlerine sahip olmanız gerekir.

İzinler hakkında daha fazla bilgi için bkz . Kusto rol tabanlı erişim denetimi.

Sözdizimi

(.set.set-or-append.set-or-replace | | .append | ) [async] tableName [with( propertyName = propertyValue [, ...]] <| )queryOrCommand

Söz dizimi kuralları hakkında daha fazla bilgi edinin.

Parametreler

Performans ipuçları

• distributed Sorgu tarafından üretilen veri miktarı büyükse, 1 GB'ı aşarsa ve serileştirme gerektirmezse özelliğini true olarak ayarlayın. Ardından, birden çok düğüm paralel olarak çıkış üretebilir. Sorgu sonuçları küçük olduğunda bu bayrağı kullanmayın, çünkü gerek duymadan çok sayıda küçük veri parçası oluşturabilir.
• Veri alımı, sorgu çalıştırma da dahil olmak üzere veritabanındaki eşzamanlı etkinlikleri etkileyebilecek yoğun kaynak kullanan bir işlemdir. Aynı anda çok fazla alma komutu çalıştırmaktan kaçının.
• Veri alımı için verileri alma işlemi başına 1 GB'tan azla sınırlayın. Gerekirse, birden çok alma komutu kullanın.

Desteklenen alma özellikleri

Şemayla ilgili dikkat edilmesi gerekenler

• .set-or-replaceveya recreate_schema alma özelliklerinden biri extend_schema olarak ayarlanmadığı sürece şemayı truekorur.
• .set-or-appendve .append komutları, alma özelliği olarak ayarlanmadığı truesürece şemayı extend_schema korur.
• Sonuç kümesi şemasını hedef tablonun şemasıyla eşleştirmek sütun türlerini temel alır. Sütun adlarının eşleşmesi yok. Sorgu sonucu şema sütunlarının tabloyla aynı sırada olduğundan emin olun; aksi takdirde veriler yanlış sütunlara alınır.

Karakter sınırlaması

Sorgu karakteriyle $ bir varlık adı oluşturursa komut başarısız olur. Varlık adları adlandırma kurallarına uymalıdır, bu nedenle alma komutunun $ başarılı olması için karakterin kaldırılması gerekir.

Örneğin, aşağıdaki sorguda search işleç bir sütun $tableoluşturur. Sorgu sonuçlarını depolamak için project-rename komutunu kullanarak sütunu yeniden adlandırın.

.set Texas <| search State has 'Texas' | project-rename tableName=$table

Örnekler

Veritabanında adı geçen saatle aynı şemaya LogsTable sahip ve tüm hata kayıtlarını tutan adlı RecentErrors yeni bir tablo oluşturun.

.set RecentErrors <|
   LogsTable
   | where Level == "Error" and Timestamp > now() - time(1h)

Veritabanında "ExtentId" adlı tek bir sütuna sahip olan ve veritabanında 30 günden fazla önce oluşturulan tüm kapsamların kapsam kimliklerini tutan "OldExtents" adlı yeni bir tablo oluşturun. Veritabanında "MyExtents" adlı bir tablo var. Veri kümesinin 1 GB'tan büyük olması beklendiğinden (yaklaşık 1 milyon satırdan fazla) dağıtılmış bayrağını kullanın

.set async OldExtents with(distributed=true) <|
   MyExtents 
   | where CreatedOn < now() - time(30d)
   | project ExtentId

Geçerli veritabanında "ExtentId" adlı tek bir sütuna sahip olan ve veritabanında 30 günden daha önce oluşturulmuş tüm kapsamların kapsam kimliklerini tutan "OldExtents" adlı mevcut bir tabloya veri ekleyin. "MyExtents" adlı mevcut bir tabloyu temel alarak yeni kapsamı ve tagBetiketleriyle tagA işaretleyin.

.append OldExtents with(tags='["TagA","TagB"]') <| 
   MyExtents 
   | where CreatedOn < now() - time(30d) 
   | project ExtentId

Geçerli veritabanındaki "OldExtents" tablosuna veri ekleyin veya henüz yoksa tabloyu oluşturun. Yeni kapsamı ile etiketleyin ingest-by:myTag. Bunu yalnızca tabloda "MyExtents" adlı mevcut bir tablo temelinde ile ingest-by:myTagetiketlenmiş bir uzantı yoksa yapabilirsiniz.

.set-or-append async OldExtents with(tags='["ingest-by:myTag"]', ingestIfNotExists='["myTag"]') <|
   MyExtents
   | where CreatedOn < now() - time(30d)
   | project ExtentId

Geçerli veritabanındaki "OldExtents" tablosundaki verileri değiştirin veya henüz yoksa tabloyu oluşturun. Yeni kapsamı ile etiketleyin ingest-by:myTag.

.set-or-replace async OldExtents with(tags='["ingest-by:myTag"]', ingestIfNotExists='["myTag"]') <| 
   MyExtents 
   | where CreatedOn < now() - time(30d) 
   | project ExtentId

Verileri geçerli veritabanındaki "OldExtents" tablosuna eklerken, kapsam oluşturma zamanını geçmişteki belirli bir tarih saatine ayarlayın.

.append async OldExtents with(creationTime='2017-02-13T11:09:36.7992775Z') <| 
   MyExtents 
   | where CreatedOn < now() - time(30d) 
   | project ExtentId     

Çıkış döndür

veya .append komutu nedeniyle .set oluşturulan kapsamlarla ilgili bilgileri döndürür.

Örnek çıkış