@@ error (Transact-SQL)
Son hata numarasını döndürür Transact-SQL deyim yürütüldü.
Sözdizimi
@@ERROR
Dönüş Türleri
integer
Açıklamalar
Döndürür, önceki Transact-SQL deyim herhangi bir hata ile karşılaştı.
Önceki deyim bir sorunla karşılaştı hata numarasını döndürür.Hata sys.messages katalog görünümünde hatalardan biri ise, @@ hata bu hata için sys.messages.message_id sütun değeri içerir.Sys.messages bir @@ error hata numarasıyla ilişkili metin görüntüleyebilirsiniz.
@@ error temizlenir ve yürütülen her deyim sıfırlamak için Doğrulanmakta olan deyim hemen teslim veya daha denetlenebilir bir yerel değişken kaydedin.
İçin try...Hataları işlemek için yapı catch.try...catch yapı @@ ERROR'den daha fazla hata bilgisi veren ek sistem işlevleri (ERROR_LINE, error_message, error_procedure, ERROR_SEVERITY ve error_state) de destekler.DENEYİN...catch hata oluşturan hemen deyim deyim hata numarasını döndürerek için sınırlı bir error_number işlev de destekler.Daha fazla bilgi için, bkz. TRY...CATCH (Transact-SQL).
Örnekler
A.algılamak için belirli bir hata @@ error kullanma
Aşağıdaki örnek @@ERROR bir onay kısıtlama ihlali (hata # 547) denetlemek için bir UPDATE deyim.
USE AdventureWorks2008R2;
GO
UPDATE HumanResources.EmployeePayHistory
SET PayFrequency = 4
WHERE BusinessEntityID = 1;
IF @@ERROR = 547
PRINT N'A check constraint violation occurred.';
GO
B.Koşullu bir yordam çıkmak için @@ error kullanma
Aşağıdaki örnekler kullanır IF...ELSE sınamak için ifadeleri @@ERROR sonra bir INSERT saklı yordamdeyim . Değeri @@ERROR değişkeni belirler dönüş kodu gönderilen çağıran program gösteren başarı veya başarısızlık yordamı.
USE AdventureWorks2008R2;
GO
-- Drop the procedure if it already exists.
IF OBJECT_ID(N'HumanResources.usp_DeleteCandidate', N'P') IS NOT NULL
DROP PROCEDURE HumanResources.usp_DeleteCandidate;
GO
-- Create the procedure.
CREATE PROCEDURE HumanResources.usp_DeleteCandidate
(
@CandidateID INT
)
AS
-- Execute the DELETE statement.
DELETE FROM HumanResources.JobCandidate
WHERE JobCandidateID = @CandidateID;
-- Test the error value.
IF @@ERROR <> 0
BEGIN
-- Return 99 to the calling program to indicate failure.
PRINT N'An error occurred deleting the candidate information.';
RETURN 99;
END
ELSE
BEGIN
-- Return 0 to the calling program to indicate success.
PRINT N'The job candidate has been deleted.';
RETURN 0;
END;
GO
C.@@ error @@ rowcount ile kullanma
Aşağıdaki örnek @@ERROR ile @@ROWCOUNT işlemini doğrulamak için bir UPDATE deyim.Değeri @@ERROR bir hata haberi için denetlenir ve @@ROWCOUNT güncelleştirme tablobir satıra başarıyla uygulandığından emin olmak için kullanılır.
USE AdventureWorks2008R2;
GO
IF OBJECT_ID(N'Purchasing.usp_ChangePurchaseOrderHeader',N'P')IS NOT NULL
DROP PROCEDURE Purchasing.usp_ChangePurchaseOrderHeader;
GO
CREATE PROCEDURE Purchasing.usp_ChangePurchaseOrderHeader
(
@PurchaseOrderID INT
,@BusinessEntityID INT
)
AS
-- Declare variables used in error checking.
DECLARE @ErrorVar INT;
DECLARE @RowCountVar INT;
-- Execute the UPDATE statement.
UPDATE PurchaseOrderHeader
SET BusinessEntityID = @BusinessEntityID
WHERE PurchaseOrderID = @PurchaseOrderID;
-- Save the @@ERROR and @@ROWCOUNT values in local
-- variables before they are cleared.
SELECT @ErrorVar = @@ERROR
,@RowCountVar = @@ROWCOUNT;
-- Check for errors. If an invalid @BusinessEntityID was specified,
-- the UPDATE statement returns a foreign key violation error #547.
IF @ErrorVar <> 0
BEGIN
IF @ErrorVar = 547
BEGIN
PRINT N'ERROR: Invalid ID specified for new employee.';
RETURN 1;
END
ELSE
BEGIN
PRINT N'ERROR: error '
+ RTRIM(CAST(@ErrorVar AS NVARCHAR(10)))
+ N' occurred.';
RETURN 2;
END
END
-- Check the row count. @RowCountVar is set to 0
-- if an invalid @PurchaseOrderID was specified.
IF @RowCountVar = 0
BEGIN
PRINT 'Warning: The BusinessEntityID specified is not valid';
RETURN 1;
END
ELSE
BEGIN
PRINT 'Purchase order updated with the new employee';
RETURN 0;
END;
GO
Ayrıca bkz.